外向交货单创建、拣配和发货过账

程序代码：

FUNCTION zsdfm012.
*"----------------------------------------------------------------------
*"*"本地接口：
*" IMPORTING
*" VALUE(I_INPUT) TYPE ZSDS116 OPTIONAL
*" EXPORTING
*" VALUE(E_MESSAGE) TYPE ZOTS001
*" VALUE(E_VBELN_VL) TYPE VBELN_VL
*" TABLES
*" T_VBAP STRUCTURE ZSDS111 OPTIONAL
*"----------------------------------------------------------------------
FIELD-SYMBOLS:<fs_vbap> TYPE zsds111.
DATA:lv_delivery TYPE vbeln_vl.
DATA:lv_dlv_qty TYPE lfimg.
DATA:lt_return TYPE TABLE OF bapiret2 WITH HEADER LINE.
DATA:lt_items TYPE TABLE OF bapidlvreftosalesorder WITH HEADER LINE.
DATA:lt_created_items TYPE TABLE OF bapidlvitemcreated WITH HEADER LINE.
DATA:BEGIN OF lt_matnr OCCURS 0,
matnr TYPE mara-matnr,
END OF lt_matnr.
IF i_input-bolnr IS INITIAL.
e_message-type = 'E'.
e_message-message = '提单号必填'.
EXIT.
ENDIF.
CHECK t_vbap[] IS NOT INITIAL.
LOOP AT t_vbap ASSIGNING <fs_vbap>.
PERFORM frm_inputsap_vbeln CHANGING <fs_vbap>-vbeln.
PERFORM frm_inputsap_vbeln CHANGING <fs_vbap>-vbeln_vl.
PERFORM frm_inputsap_vrkme CHANGING <fs_vbap>-vrkme.
lt_items-ref_doc = <fs_vbap>-vbeln.
lt_items-ref_item = <fs_vbap>-posnr.
lt_items-dlv_qty = <fs_vbap>-lfimg.
lt_items-sales_unit = <fs_vbap>-vrkme.
APPEND lt_items.
ENDLOOP.
*-->检查物理是否被锁定，否则生成交货单交货数量=0
SELECT matnr
INTO TABLE lt_matnr
FROM vbap
FOR ALL ENTRIES IN t_vbap
WHERE vbeln = t_vbap-vbeln
AND posnr = t_vbap-posnr.
IF lt_matnr[] IS NOT INITIAL.
SORT lt_matnr BY matnr.
DELETE ADJACENT DUPLICATES FROM lt_matnr COMPARING matnr.
LOOP AT lt_matnr.
CALL FUNCTION 'ENQUEUE_EMMARAE'
EXPORTING
mode_mara = 'E'
mandt = sy-mandt
matnr = lt_matnr-matnr
EXCEPTIONS
foreign_lock = 1
system_failure = 2
OTHERS = 3.
IF sy-subrc <> 0.
e_message-type = 'E'.
e_message-message = '物料' && lt_matnr-matnr && '被锁定'.
EXIT.
ENDIF.
ENDLOOP.
ENDIF.
CHECK e_message-type NE 'E'.
READ TABLE t_vbap ASSIGNING <fs_vbap> INDEX 1.
IF sy-subrc = 0 AND <fs_vbap>-vbeln_vl IS INITIAL.
WAIT UP TO 1 SECONDS.
*--> 创建外向交货单 MV50AFZ1
DATA:lv_zsdfm012 TYPE zsds116.
lv_zsdfm012 = i_input.
EXPORT lv_zsdfm012 TO MEMORY ID 'ABAP_ZSDFM012'. "10/20/30/40/50
CALL FUNCTION 'BAPI_OUTB_DELIVERY_CREATE_SLS'
IMPORTING
delivery = lv_delivery
TABLES
sales_order_items = lt_items
created_items = lt_created_items
return = lt_return.
LOOP AT lt_return WHERE type CA 'AEX'.
IF e_message-message IS INITIAL.
e_message-message = lt_return-message.
ELSE.
e_message-message = e_message-message && '/' && lt_return-message.
ENDIF.
ENDLOOP.
IF sy-subrc = 0.
e_message-type = 'E'.
CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK'.
* EXIT.
ELSE.
*-->判断交货单创建后交货数量是否 = 需要交货的数量
LOOP AT t_vbap ASSIGNING <fs_vbap>.
CLEAR:lv_dlv_qty.
LOOP AT lt_created_items WHERE ref_doc = <fs_vbap>-vbeln AND ref_item = <fs_vbap>-posnr.
lv_dlv_qty = lv_dlv_qty + lt_created_items-dlv_qty.
ENDLOOP.
IF sy-subrc = 0 AND <fs_vbap>-lfimg NE lv_dlv_qty.
e_message-type = 'E'.
e_message-message = '行项目' && lt_created_items-ref_item && '物料' && lt_created_items-material && '库存不足！'.
EXIT.
ENDIF.
ENDLOOP.
IF e_message-type = 'E'.
CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK'.
ELSE.
CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
EXPORTING
wait = 'X'.
"提单号没有会导致发货过账失败
PERFORM frm_delivery_update USING lv_delivery
CHANGING e_message
e_vbeln_vl.
ENDIF.
ENDIF.
ELSE.
lv_delivery = <fs_vbap>-vbeln_vl.
PERFORM frm_delivery_update USING lv_delivery
CHANGING e_message
e_vbeln_vl.
ENDIF.
*解锁
LOOP AT lt_matnr.
CALL FUNCTION 'DEQUEUE_EMMARAE'
EXPORTING
mode_mara = 'E'
mandt = sy-mandt
matnr = lt_matnr-matnr.
ENDLOOP.
ENDFUNCTION.
FORM frm_inputsap_vbeln CHANGING pc_vbeln TYPE char10.
CALL FUNCTION 'CONVERSION_EXIT_ALPHA_INPUT'
EXPORTING
input = pc_vbeln
IMPORTING
output = pc_vbeln.
ENDFORM.
FORM frm_inputsap_vrkme CHANGING pc_vrkme TYPE char3.
CALL FUNCTION 'CONVERSION_EXIT_CUNIT_INPUT'
EXPORTING
input = pc_vrkme
IMPORTING
output = pc_vrkme
EXCEPTIONS
unit_not_found = 1
OTHERS = 2.
ENDFORM.
FORM frm_delivery_update USING pi_delivery TYPE vbeln_vl
CHANGING pc_message STRUCTURE zots001
pc_vbeln_vl TYPE vbeln_vl.
FIELD-SYMBOLS:<fs_vbap> TYPE zsds111.
DATA:BEGIN OF lt_lips OCCURS 0,
vbeln TYPE lips-vbeln,
posnr TYPE lips-posnr,
matnr TYPE lips-matnr,
charg TYPE lips-charg,
lfimg TYPE lips-lfimg,
lgmng TYPE lips-lgmng,
lgort TYPE lips-lgort,
vrkme TYPE lips-vrkme,
meins TYPE lips-meins,
umvkz TYPE lips-umvkz,
umvkn TYPE lips-umvkn,
vgbel TYPE lips-vgbel,
vgpos TYPE lips-vgpos,
uecha TYPE lips-uecha,
END OF lt_lips.
DATA:lt_vbpok TYPE TABLE OF vbpok WITH HEADER LINE,
lt_prot TYPE TABLE OF prott WITH HEADER LINE,
lt_verko TYPE TABLE OF verko WITH HEADER LINE,
lt_verpo TYPE TABLE OF verpo WITH HEADER LINE,
lt_vbsupcon TYPE TABLE OF vbsupcon WITH HEADER LINE.
DATA:ls_vbkok TYPE vbkok.
DATA:lv_err_anyerr TYPE c,
lv_err_itmdel TYPE c,
lv_err_podupd TYPE c,
lv_err_interf TYPE c,
lv_err_goodsi TYPE c,
lv_err_finalc TYPE c.
*---交货抬头数据
ls_vbkok-vbeln_vl = pi_delivery.
ls_vbkok-vbtyp_vl = 'J'. " Delivery Type
ls_vbkok-wabuc = 'X'. " Post good issue automatically
ls_vbkok-komue = 'X'. " update delivery qty with picking qty
ls_vbkok-wadat_ist = sy-datum.
SELECT vbeln
posnr
matnr
charg
lfimg
lgmng
lgort
vrkme
meins
umvkz
umvkn
vgbel
vgpos
uecha
INTO TABLE lt_lips
FROM lips
WHERE vbeln = pi_delivery.
LOOP AT lt_lips.
lt_vbpok-vbeln_vl = lt_lips-vbeln.
lt_vbpok-posnr_vl = lt_lips-posnr.
lt_vbpok-vbeln = lt_lips-vgbel.
lt_vbpok-posnn = lt_lips-vgpos.
lt_vbpok-matnr = lt_lips-matnr.
lt_vbpok-charg = lt_lips-charg.
lt_vbpok-lgort = lt_lips-lgort.
lt_vbpok-pikmg = lt_lips-lfimg.
lt_vbpok-lgmng = lt_lips-lgmng.
lt_vbpok-vrkme = lt_lips-vrkme.
lt_vbpok-meins = lt_lips-meins.
lt_vbpok-umvkz = lt_lips-umvkz.
lt_vbpok-umvkn = lt_lips-umvkn.
APPEND lt_vbpok.
ENDLOOP.
*--->更改拣配数量 & 发货过账
CALL FUNCTION 'WS_DELIVERY_UPDATE'
EXPORTING
vbkok_wa = ls_vbkok
* synchron = 'X'
* NO_MESSAGES_UPDATE = ' '
commit = 'X'
delivery = pi_delivery
update_picking = 'X'
* if_database_update = '1'
* IF_NO_INIT = ' '
* IF_NO_READ = ' '
* if_error_messages_send_0 = 'X'
IMPORTING
ef_error_any_0 = lv_err_anyerr
ef_error_in_item_deletion_0 = lv_err_itmdel
ef_error_in_pod_update_0 = lv_err_podupd
ef_error_in_interface_0 = lv_err_interf
ef_error_in_goods_issue_0 = lv_err_goodsi
ef_error_in_final_check_0 = lv_err_finalc
* EF_ERROR_PARTNER_UPDATE =
* EF_ERROR_SERNR_UPDATE =
TABLES
vbpok_tab = lt_vbpok
prot = lt_prot
* verko_tab = lt_verko
* verpo_tab = lt_verpo
* vbsupcon_tab = lt_vbsupcon
.
IF lv_err_anyerr IS INITIAL.
pc_message-type = 'S'.
pc_message-message = '拣配过账成功'.
pc_vbeln_vl = pi_delivery.
ELSE.
pc_message-type = 'E'.
pc_message-message = '拣配过账失败'.
pc_vbeln_vl = pi_delivery.
ENDIF.
ENDFORM.

复制代码

注意交货单字段BOLNR更新，可使用WS_DELIVERY_UPDATE_2，不需要使用ABAP内存方式相关阅读：BAPI_OUTB_DELIVERY_CHANGE拆分批次报错

[BAPI] 外向交货单创建、拣配和发货过账

相关帖子

Ta最近发表

快速回帖