会计凭证FB05清账POSTING_INTERFACE_CLEARING

Message SAP咨询了清账相关的BAPI，SAP回复，还未向客户release清账相关的BAPI，清账函数POSTING_INTERFACE_CLEARING只是SAP内部使用，本质上还是BDC录屏清账。
1、可以实现F-32、F-44，清客户、供应商账
2、只能按照凭证编号+会计年度+凭证行项目清账，不能部分清账，部分清账参考：https://www.591sap.com/thread-985-1-1.html
3、支持收款并清账，一步到位，即做凭证并清账

POSTING_INTERFACE_CLEARING中I_AUGLV = T041A-AUGLV

• AUSGZAHL        付款
• EINGZAHL        收款
• GUTSCHRI        贷方凭证
• UMBUCHNG        转帐并清帐
  

程序代码

1. *&---------------------------------------------------------------------*
   
2. *& 程序名: ZFIFM016                                                    *
   
3. *&                                                                     *
   
4. *&---------------------------------------------------------------------*
   
5. *& 抬头     : 过账并清账FB05                                            *
   
6. *& 模块     : FI                                                       *
   
7. *& 作者     : Twilight                                                 *
   
8. *& 创建日期 : 2018/12/04                                               *
   
9. *& 接口类型 : RFC 、BDC                                                *
   
10. *& 消息类   : 00                                                       *
    
11. *&                                                                     *
    
12. *& 修改记录 :                                                          *
    
13. *& 日期        修改人           修改内容                                *
    
14. *& YYYY/MM/DD  修改人员名       说明                                    *
    
15. *&---------------------------------------------------------------------*
    
16. FUNCTION ZFIFM016.
    
17. *"----------------------------------------------------------------------
    
18. *"*"本地接口：
    
19. *"  IMPORTING
    
20. *"     VALUE(I_HEADER) TYPE  ZFIS018
    
21. *"     VALUE(I_MODE) TYPE  RFPDO-ALLGAZMD DEFAULT 'N'
    
22. *"  EXPORTING
    
23. *"     VALUE(E_MESSAGE) TYPE  ZOTS001
    
24. *"     VALUE(E_BUKRS) TYPE  BUKRS
    
25. *"     VALUE(E_BELNR) TYPE  BELNR_D
    
26. *"     VALUE(E_GJAHR) TYPE  GJAHR
    
27. *"  TABLES
    
28. *"      T_FPITEM STRUCTURE  ZFIS019 OPTIONAL
    
29. *"      T_FCITEM STRUCTURE  ZFIS021
    
30. *"----------------------------------------------------------------------
    
31.   DATA: lt_blntab  TYPE TABLE OF blntab  WITH HEADER LINE,
    
32.         lt_ftclear TYPE TABLE OF ftclear WITH HEADER LINE,
    
33.         lt_ftpost  TYPE TABLE OF ftpost  WITH HEADER LINE,
    
34.         lt_fttax   TYPE TABLE OF fttax   WITH HEADER LINE.
    
35.   DATA:ls_syst TYPE syst.
    
36.   DATA:lv_monat    TYPE bkpf-monat.
    
37.   DATA:lv_gjahr    TYPE bkpf-gjahr.
    
38.   DATA:lv_posnr    TYPE i.
    
39.   DATA:lv_wrbtr    TYPE char20.
    
40.   DATA:lv_datum    TYPE string.
    
41.   DATA:lv_belnr    TYPE string.
    
42. 
    
43.   DEFINE populate_ftpost.
    
44.     lt_ftpost-stype = &1.
    
45.     lt_ftpost-count = &2.
    
46.     lt_ftpost-fnam  = &3.
    
47.     lt_ftpost-fval  = &4.
    
48.     APPEND lt_ftpost.
    
49.   END-OF-DEFINITION.
    
50.   DEFINE populate_ftclear.
    
51.     lt_ftclear-agkoa  = i_header-koart. "K for vender,D for custmor, S for GL
    
52.     lt_ftclear-agbuk  = i_header-bukrs. "公司代码
    
53.     lt_ftclear-xnops  = 'X'.            "标准未清项目
    
54.     lt_ftclear-agkon  = &1.             "科目
    
55.     lt_ftclear-selfd  = &2.             "BELNR 字段固定
    
56.     lt_ftclear-selvon = &3.             "会计凭证搜索--开始上限值
    
57. *    lt_ftclear-selbis = '2'.           "会计凭证搜索--开始下限值
    
58.     APPEND lt_ftclear.
    
59.   END-OF-DEFINITION.
    
60. **********************************************************************
    
61. *过账创建凭证
    
62. **********************************************************************
    
63. *---初始化
    
64.   lv_monat = sy-datum+4(2).
    
65.   lv_gjahr = sy-datum+0(4).
    
66.   IF i_header-waers IS INITIAL.
    
67.     i_header-waers = 'CNY'.
    
68.   ENDIF.
    
69. 
    
70.   CALL FUNCTION 'CONVERT_DATE_TO_EXTERNAL'
    
71.     EXPORTING
    
72.       date_internal            = sy-datum
    
73.     IMPORTING
    
74.       date_external            = lv_datum
    
75.     EXCEPTIONS
    
76.       date_internal_is_invalid = 1
    
77.       OTHERS                   = 2.
    
78. *K-->Header,P-->Item
    
79.   populate_ftpost: 'K' 1 'BKPF-BUKRS' i_header-bukrs, "公司代码
    
80.                    'K' 1 'BKPF-BLART' i_header-blart, "凭证类型
    
81.                    'K' 1 'BKPF-BLDAT' lv_datum,       "凭证日期
    
82.                    'K' 1 'BKPF-BUDAT' lv_datum,       "过帐日期
    
83.                    'K' 1 'BKPF-MONAT' lv_monat,       "过帐期间
    
84.                    'K' 1 'BKPF-WAERS' i_header-waers,
    
85.                    'K' 1 'BKPF-XBLNR' i_header-xblnr,
    
86.                    'K' 1 'BKPF-BKTXT' i_header-bktxt.
    
87. 
    
88.   LOOP AT t_fpitem.
    
89.     lv_posnr = sy-tabix.
    
90.     lv_wrbtr = abs( t_fpitem-wrbtr ). "必须都是正值
    
91.     CONDENSE lv_wrbtr.
    
92.     populate_ftpost:'P' lv_posnr 'RF05A-NEWBS' t_fpitem-bschl,  "记账码
    
93.                     'P' lv_posnr 'RF05A-NEWKO' t_fpitem-hkont,  "记账科目
    
94.                     'P' lv_posnr 'COBL-GSBER'  t_fpitem-gsber, "业务范围3100上海
    
95.                     'P' lv_posnr 'BSEG-WRBTR'  lv_wrbtr,        "金额
    
96.                     'P' lv_posnr 'BSEG-RSTGR'  t_fpitem-rstgr.  "原因代码
    
97.   ENDLOOP.
    
98. **********************************************************************
    
99. *清账凭证
    
100. **********************************************************************
     
101.   LOOP AT t_fcitem.
     
102.     CLEAR:lv_belnr.
     
103.     lv_belnr = t_fcitem-belnr && t_fcitem-gjahr && t_fcitem-buzei.
     
104.     CASE i_header-koart.
     
105.       WHEN 'D'. "客户
     
106.         populate_ftclear: t_fcitem-kunnr 'BELNR' lv_belnr.
     
107.       WHEN 'K'. "供应商
     
108.         populate_ftclear: t_fcitem-lifnr 'BELNR' lv_belnr.
     
109.       WHEN OTHERS.
     
110.     ENDCASE.
     
111.   ENDLOOP.
     
112. **********************************************************************
     
113. *清账开始----采用剩余清帐
     
114. **********************************************************************
     
115.   CALL FUNCTION 'POSTING_INTERFACE_START'
     
116.     EXPORTING
     
117.       i_client           = sy-mandt
     
118.       i_function         = 'C' "B (batch input processing) ,C (processing with Call Transaction .. Using..)
     
119.       i_keep             = 'X' "用于已处理会话的队列删除标志.
     
120.       i_mode             = i_mode "A for step by step,N default,for background
     
121.       i_update           = 'S' "同步
     
122.       i_user             = sy-uname
     
123.     EXCEPTIONS
     
124.       client_incorrect   = 1
     
125.       function_invalid   = 2
     
126.       group_name_missing = 3
     
127.       mode_invalid       = 4
     
128.       update_invalid     = 5
     
129.       OTHERS             = 6.
     
130. 
     
131.   CALL FUNCTION 'POSTING_INTERFACE_CLEARING'
     
132.     EXPORTING
     
133.       i_auglv                    = 'UMBUCHNG'
     
134.       i_tcode                    = 'FB05'   "只支持FB05
     
135.       i_sgfunct                  = 'C'
     
136.     IMPORTING
     
137.       e_msgid                    = ls_syst-msgid
     
138.       e_msgno                    = ls_syst-msgno
     
139.       e_msgty                    = ls_syst-msgty
     
140.       e_msgv1                    = ls_syst-msgv1
     
141.       e_msgv2                    = ls_syst-msgv2
     
142.       e_msgv3                    = ls_syst-msgv3
     
143.       e_msgv4                    = ls_syst-msgv4
     
144.     TABLES
     
145.       t_blntab                   = lt_blntab
     
146.       t_ftclear                  = lt_ftclear
     
147.       t_ftpost                   = lt_ftpost
     
148.       t_fttax                    = lt_fttax
     
149.     EXCEPTIONS
     
150.       clearing_procedure_invalid = 1
     
151.       clearing_procedure_missing = 2
     
152.       table_t041a_empty          = 3
     
153.       transaction_code_invalid   = 4
     
154.       amount_format_error        = 5
     
155.       too_many_line_items        = 6
     
156.       company_code_invalid       = 7
     
157.       screen_not_found           = 8
     
158.       no_authorization           = 9
     
159.       OTHERS                     = 10.
     
160. *  IF sy-subrc = 0. "判断不准
     
161.   IF ls_syst-msgty CA 'AEX'.
     
162.     e_message-type    = 'E'.
     
163.     MESSAGE ID ls_syst-msgid TYPE ls_syst-msgty NUMBER ls_syst-msgno  WITH ls_syst-msgv1 ls_syst-msgv2 ls_syst-msgv3 ls_syst-msgv4 INTO e_message-message.
     
164.   ELSE .
     
165.     e_message-type    = 'S'.
     
166.     e_message-message = '过账并清账成功！'.
     
167. 
     
168.     READ TABLE lt_blntab INDEX 1.
     
169.     IF sy-subrc = 0.
     
170.       e_belnr = lt_blntab-belnr.
     
171.       e_bukrs = lt_blntab-bukrs.
     
172.       e_gjahr = lt_blntab-gjahr.
     
173.     ENDIF.
     
174.   ENDIF.
     
175. 
     
176.   "清账结束
     
177.   CALL FUNCTION 'POSTING_INTERFACE_END'
     
178.     EXCEPTIONS
     
179.       session_not_processable = 1
     
180.       OTHERS                  = 2.
     
181. 
     
182. ENDFUNCTION.

复制代码

清账函数汇总：

• POSTING_INTERFACE_CLEARING
• POSTING_INTERFACE_DOCUMENT
• POSTING_INTERFACE_END
• POSTING_INTERFACE_RESET_CLEAR
• POSTING_INTERFACE_REVERSE_DOC
• POSTING_INTERFACE_START