设为首页收藏本站站点任务
请登陆 注册有礼
二维码
网站快捷导航

[BAPI] CO01创建生产订单BAPI_PRODORD_CREATE并下达BAPI_PRODORD_RELEASE

Twilight发表于 2018-05-04 15:54Twilight 最后回复于 2018-05-04 15:54 [复制链接] 8765 0

生产部门反应创建工单非常慢，是因为SAP创建生产订单时会检查物料，会花费大量时间，其次创建生产订单一次只能根据销售订单一个行项目创建，所以完成一个销售订单的排产就需要更长的时间。

优化建议：
1、OPJK - 关闭物料检查
ATP检查.jpg
2、OPKP - 生产订单创建并下达，一步执行
生产订单下达.jpg

程序代码：
  1. FUNCTION zppfm007.
  2. *"----------------------------------------------------------------------
  3. *"*"本地接口：
  4. *"  IMPORTING
  5. *"     VALUE(I_HEADER) TYPE  ZPPS001 OPTIONAL
  6. *"  EXPORTING
  7. *"     VALUE(E_MESSAGE) TYPE  ZOTS001
  8. *"     VALUE(E_AUFNR) TYPE  AUFNR
  9. *"  TABLES
  10. *"      T_ITEM STRUCTURE  ZPPS003
  11. *"----------------------------------------------------------------------
  12.   DATA:ls_afpo TYPE afpo.
  13.   DATA:ls_message TYPE zots001.
  14.   DATA:ls_return TYPE bapiret2.
  15.   DATA:ls_orderdata TYPE bapi_pp_order_create.
  16.   DATA:lv_objnr TYPE jsto-objnr.
  17.   DATA:lv_bsark_e  TYPE vbkd-bsark_e.
  18.   DATA:lv_order_number TYPE aufnr.
  19.   DATA:lt_status TYPE TABLE OF jstat WITH HEADER LINE,
  20.        lt_orders  TYPE TABLE OF bapi_order_key WITH HEADER LINE,
  21.        lt_detail_return        TYPE TABLE OF        bapi_order_return WITH HEADER LINE.

  23.   FIELD-SYMBOLS:<fs_item> TYPE zpps003.

  25.   PERFORM frm_inputsap_matnr CHANGING i_header-matnr.
  26.   PERFORM frm_inputsap_vbeln CHANGING i_header-sales_order.

  28.   SELECT SINGLE bsark_e INTO lv_bsark_e FROM vbkd WHERE vbeln = i_header-sales_order.
  29.   CASE lv_bsark_e.
  30.     WHEN 'A001'.
  31.       i_header-order_type = 'SG01'.
  32.     WHEN 'A005'.
  33.       i_header-order_type = 'SG03'.
  34.     WHEN 'A002'.
  35.       i_header-order_type = 'SG05'.
  36.     WHEN 'A007'.
  37.       i_header-order_type = 'SG07'.
  38.     WHEN 'A006'.
  39.       i_header-order_type = 'SG09'.
  40.     WHEN 'A012'.
  41.       i_header-order_type = 'SG11'.
  42.     WHEN 'A009'.
  43.       i_header-order_type = 'SG13'.
  44.     WHEN 'A011'.
  45.       i_header-order_type = 'SG15'.
  46.     WHEN 'A010'.
  47.       i_header-order_type = 'SG17'.
  48.     WHEN 'A013'.
  49.       i_header-order_type = 'SG19'.
  50.     WHEN 'A003'.
  51.       i_header-order_type = 'SG21'.
  52.     WHEN 'A004'.
  53.       i_header-order_type = 'SG23'.
  54.   ENDCASE.

  56.   ls_orderdata-material       = i_header-matnr.
  57.   ls_orderdata-order_type     = i_header-order_type.
  58.   ls_orderdata-plant          = i_header-plant.
  59.   ls_orderdata-planning_plant = i_header-plant.
  60.   IF i_header-basic_start_date IS NOT INITIAL .
  61.     CONCATENATE i_header-basic_start_date+0(4) i_header-basic_start_date+5(2) i_header-basic_start_date+8(2) INTO ls_orderdata-basic_start_date.
  62.   ELSE .
  63.     ls_orderdata-basic_start_date = sy-datum.
  64.   ENDIF.
  65.   IF i_header-basic_end_date IS NOT INITIAL .
  66.     CONCATENATE i_header-basic_end_date+0(4) i_header-basic_end_date+5(2) i_header-basic_end_date+8(2) INTO ls_orderdata-basic_end_date.
  67.   ELSE .
  68.     ls_orderdata-basic_end_date = sy-datum .
  69.   ENDIF .
  70.   ls_orderdata-quantity         = i_header-quantity.
  71.   ls_orderdata-sales_order      = i_header-sales_order.
  72.   ls_orderdata-sales_order_item = i_header-sales_order_item.
  73.   ls_orderdata-storage_location = i_header-storage_location.
  74.   ls_orderdata-unloading_point  = i_header-unloading_point.

  76. *-->生产订单创建
  77.   CALL FUNCTION 'BAPI_PRODORD_CREATE'
  78.     EXPORTING
  79.       orderdata    = ls_orderdata
  80.     IMPORTING
  81.       return       = ls_return
  82.       order_number = lv_order_number.

  84.   IF lv_order_number IS INITIAL.
  85.     CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK' .

  87.     e_message-type = 'E'.
  88.     e_message-message = ls_return-message.
  89.   ELSE.
  90.     CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
  91.       EXPORTING
  92.         wait = 'X'.

  94. *-->修改生产订单组建
  95.     IF t_item[] IS NOT INITIAL.
  96.       LOOP AT t_item ASSIGNING <fs_item>.
  97.         PERFORM frm_inputsap_matnr CHANGING <fs_item>-matnr.
  98.       ENDLOOP.

  100.       WAIT UP TO 1 SECONDS.
  101.       CALL FUNCTION 'ZPPFM010'
  102.         EXPORTING
  103.           i_aufnr   = lv_order_number
  104.         IMPORTING
  105.           e_message = ls_message
  106.         TABLES
  107.           t_item    = t_item[].
  108.       IF e_message-type = 'E'.
  109.         MOVE-CORRESPONDING ls_message TO e_message.
  110.         e_aufnr = lv_order_number.
  111.         EXIT.
  112.       ENDIF.
  113.     ENDIF.

  115. *-->生产订单下达
  116.     WAIT UP TO 1 SECONDS.
  117.     CLEAR:lt_orders.
  118.     lt_orders-order_number = lv_order_number.
  119.     APPEND lt_orders .

  121.     CALL FUNCTION 'BAPI_PRODORD_RELEASE'
  122. *        IMPORTING
  123. *          return        = return
  124.       TABLES
  125.         detail_return = lt_detail_return
  126.         orders        = lt_orders[].
  127.     LOOP AT lt_detail_return WHERE type CA 'AEX'.
  128.       IF e_message-message IS INITIAL.
  129.         e_message-message = lt_detail_return-message.
  130.       ELSE.
  131.         e_message-message = e_message-message && '/' && lt_detail_return-message.
  132.       ENDIF.
  133.     ENDLOOP.
  134.     IF sy-subrc = 0.
  135.       CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK' .

  137.       e_message-type = 'E'.
  138.     ELSE.
  139.       CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
  140.         EXPORTING
  141.           wait = 'X'.

  143.       e_message-type = 'S'.
  144.       e_message-message = '生产订单创建并下达成功'.
  145.       e_aufnr = lv_order_number.
  146.     ENDIF.
  147.   ENDIF.

  149. ENDFUNCTION.

  151. FORM frm_inputsap_matnr CHANGING pc_matnr TYPE char18.
  152.   CALL FUNCTION 'CONVERSION_EXIT_MATN1_INPUT'
  153.     EXPORTING
  154.       input        = pc_matnr
  155.     IMPORTING
  156.       output       = pc_matnr
  157.     EXCEPTIONS
  158.       length_error = 1
  159.       OTHERS       = 2.
  160. ENDFORM.

  162. FORM frm_inputsap_vbeln CHANGING pc_vbeln TYPE char10.
  163.   CALL FUNCTION 'CONVERSION_EXIT_ALPHA_INPUT'
  164.     EXPORTING
  165.       input  = pc_vbeln
  166.     IMPORTING
  167.       output = pc_vbeln.
  168. ENDFORM.
复制代码

最好使用STATUS_CHECK来判断生产订单的状态，更方便，更直接。
生产订单, 订单状态

相关帖子
回复

使用道具 举报

Twilight

管理员

+发表新主题
  1. 847 主题
  2. 125 回帖
  3. 11270 积分
发消息

Ta最近发表

快速回帖

本版积分规则
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册有礼

小黑屋|手机版|SAP顾问圈 ( 沪ICP备18020878号 )

GMT+8, 2024-12-23 07:34 , Processed in 0.055487 second(s), 10 queries , Gzip On, Redis On.

© 2014-2017 SAPclubDesign by Twilight.Liu®X3.5

平台客服 1204767879 无客服码

快速回复 返回顶部 返回列表