设为首页收藏本站站点任务
请登陆 注册有礼
二维码
网站快捷导航

[Rest API] SAP中用json数据格式调用http接口发送短信邮件案例

Twilight发表于 2017-04-06 09:29zhongguomao 最后回复于 2017-08-12 13:52 [复制链接] 5722 3

在系统 VL02N 交货过账后触发发送邮件、短信的功能，短信邮件接口是经过第三方系统封装，然后开发出的API接口。

请求地址: http://180.167.01.01/ns/sends
请求方式: POST
参数格式: JSON
请求参数:
  1. {
  2.     "ncode": "sapOrderSend",
  3.     "source": "订单号",
  4.     "contacts": [
  5.         {
  6.             "code": "订货人邮箱地址",
  7.             "type": "1"
  8.         },
  9.         {
  10.             "code": "订货人手机号",
  11.             "type": "2"
  12.         }
  13.     ],
  14.     "params": {
  15.         "contactName": "订货人姓名",
  16.         "contactCode": "订货人编号",
  17.         "code": "订单号",
  18.         "createDate": "订单创建时间",
  19.         "storageName": "发货仓库名称",
  20.         "shipTypeName": "发货方式名称"
  21.     }
  22. }
复制代码


RFC接口代码：
  1. FUNCTION zot_do_send_message.
  2. *"----------------------------------------------------------------------
  3. *"*"本地接口：
  4. *"  IMPORTING
  5. *"     VALUE(I_VBELN) TYPE  VBELN_VL OPTIONAL
  6. *"  EXCEPTIONS
  7. *"      URL_ERROR
  8. *"----------------------------------------------------------------------
  9.   DATA: lr_http_client TYPE REF TO if_http_client .
  10.   DATA: lv_url TYPE string,
  11.         lv_result TYPE string,
  12.         lv_post_string TYPE string,
  13.         lv_len TYPE i.

  15.   TYPES:BEGIN OF ty_contacts,
  16.           code TYPE string,
  17.           type TYPE char1,
  18.        END OF ty_contacts.
  19.   TYPES:BEGIN OF ty_params,
  20.           contactname  TYPE string,
  21.           contactcode  TYPE string,
  22.           code         TYPE string,
  23.           createdate   TYPE string,
  24.           storagename  TYPE string,
  25.           shiptypename TYPE string,
  26.       END OF ty_params.
  27.   DATA:lt_contacts TYPE TABLE OF ty_contacts.
  28.   TYPES:BEGIN OF ty_message,
  29.           ncode TYPE string,
  30.           source TYPE string,
  31.           contacts LIKE lt_contacts,
  32.           params TYPE ty_params,
  33.         END OF ty_message.
  34.   DATA:ls_message  TYPE ty_message.
  35.   DATA:ls_contacts TYPE ty_contacts.
  36.   DATA:BEGIN OF lt_vbap OCCURS 0,
  37.         vbeln TYPE vbap-vbeln,
  38.         posnr TYPE vbap-posnr,
  39.         ktgrm TYPE vbap-ktgrm,
  40.       END OF lt_vbap.

  42.   DATA:lv_vbeln_so   TYPE vbak-vbeln,
  43.        lv_tel_number TYPE adr2-tel_number,
  44.        lv_smtp_addr  TYPE adr6-smtp_addr,
  45.        lv_kunnr      TYPE kna1-kunnr,
  46.        lv_name       TYPE kna1-name1,
  47.        lv_erdat TYPE vbak-erdat,
  48.        lv_bname TYPE vbak-bname,
  49.        lv_bezei TYPE t173t-bezei,
  50.        lv_lgobe TYPE t001l-lgobe.

  52.   IF i_vbeln IS INITIAL.
  53.     EXIT.
  54.   ENDIF.

  56.   SELECT SINGLE url INTO lv_url FROM zot_message WHERE fm_name = 'ZOT_DO_SEND_MESSAGE' AND pm1 = 'URL'.
  57.   IF sy-subrc NE 0.
  58.     MESSAGE '请在表ZOT_MESSAGE配置URL参数' TYPE 'E' RAISING url_error.
  59.   ENDIF.

  61.   SELECT vbap~vbeln
  62.          vbap~posnr
  63.          vbap~ktgrm
  64.     INTO TABLE lt_vbap
  65.     FROM lips
  66.     INNER JOIN vbap ON lips~vgbel = vbap~vbeln AND vbap~abgru = ''
  67.     INNER JOIN vbak ON vbap~vbeln = vbak~vbeln AND vbak~vkorg = '3110'  "国内发短信
  68.     WHERE lips~vbeln = i_vbeln.
  69.   DELETE lt_vbap WHERE ktgrm = '02'.  "技术服务
  70.   IF lt_vbap[] IS INITIAL.
  71.     EXIT.
  72.   ENDIF.

  74.   SELECT SINGLE lips~vgbel adr2~tel_number adr6~smtp_addr kna1~kunnr kna1~name1
  75.   INTO (lv_vbeln_so,lv_tel_number,lv_smtp_addr,lv_kunnr,lv_name)
  76.   FROM lips
  77.   INNER JOIN vbpa ON lips~vgbel = vbpa~vbeln AND vbpa~posnr = space AND vbpa~parvw = 'WE'
  78.   INNER JOIN kna1 ON vbpa~kunnr = kna1~kunnr
  79.   LEFT JOIN adr2 ON kna1~adrnr = adr2~addrnumber AND adr2~persnumber = space AND adr2~r3_user = '3'
  80.   LEFT JOIN adr6 ON kna1~adrnr = adr6~addrnumber AND adr6~persnumber = space
  81.   WHERE lips~vbeln = i_vbeln.

  83.   IF lv_tel_number IS INITIAL AND lv_smtp_addr IS INITIAL.
  84.     EXIT.
  85.   ENDIF.

  87.   SELECT SINGLE
  88.   likp~erdat
  89.   vbak~bname
  90.   t173t~bezei
  91.   t001l~lgobe
  92.   INTO (lv_erdat,lv_bname,lv_bezei,lv_lgobe)
  93.   FROM likp
  94.   INNER JOIN lips ON likp~vbeln = lips~vbeln
  95.   INNER JOIN vbak ON lips~vgbel = vbak~vbeln
  96.   LEFT JOIN t173t ON t173t~spras = sy-langu AND t173t~vsart = likp~vsart
  97.   LEFT JOIN t001l ON lips~werks = t001l~werks AND lips~lgort = t001l~lgort
  98.   WHERE likp~vbeln = i_vbeln.

  100. *-->数据初始化成嵌套内表形式
  101.   ls_message-ncode = 'sapOrderSend'.
  102.   IF lv_bname IS NOT INITIAL.
  103.     ls_message-source = lv_bname.
  104.   ELSE.
  105.     ls_message-source = i_vbeln.
  106.   ENDIF.
  107.   IF lv_smtp_addr IS NOT INITIAL.
  108.     ls_contacts-code = lv_smtp_addr.
  109.     ls_contacts-type = '1'.
  110.     APPEND ls_contacts TO ls_message-contacts.
  111.   ENDIF.
  112.   IF lv_tel_number IS NOT INITIAL.
  113.     ls_contacts-code = lv_tel_number.
  114.     ls_contacts-type = '2'.
  115.     APPEND ls_contacts TO ls_message-contacts.
  116.   ENDIF.

  118.   ls_message-params-contactname = lv_name.
  119.   ls_message-params-contactcode = lv_kunnr.
  120.   IF lv_bname IS NOT INITIAL.
  121.     ls_message-params-code = lv_bname.
  122.   ELSE.
  123.     ls_message-params-code = lv_vbeln_so.
  124.   ENDIF.

  126.   IF lv_erdat IS NOT INITIAL.
  127.     CONCATENATE lv_erdat+0(4) lv_erdat+4(2) lv_erdat+6(2) INTO ls_message-params-createdate SEPARATED BY '-'.
  128.   ENDIF.
  129.   ls_message-params-storagename = lv_lgobe.
  130.   ls_message-params-shiptypename = lv_bezei.

  132. *-->内表数据转-->json格式
  133.   lv_post_string = /ui2/cl_json=>serialize( data = ls_message compress = abap_true pretty_name = abap_true ).

  135.   REPLACE ALL OCCURRENCES OF 'contactname'  IN lv_post_string WITH 'contactName'.
  136.   REPLACE ALL OCCURRENCES OF 'contactcode'  IN lv_post_string WITH 'contactCode'.
  137.   REPLACE ALL OCCURRENCES OF 'createdate'   IN lv_post_string WITH 'createDate'.
  138.   REPLACE ALL OCCURRENCES OF 'storagename'  IN lv_post_string WITH 'storageName'.
  139.   REPLACE ALL OCCURRENCES OF 'shiptypename' IN lv_post_string WITH 'shipTypeName'.

  141. *  lv_len = strlen( lv_post_string ) .
  142.   lv_len = cl_abap_list_utilities=>dynamic_output_length( lv_post_string ).

  144. *send
  145. *  lv_url = 'http://192.168.01.01:8088/ns/sends'.
  146.   CALL METHOD cl_http_client=>create_by_url
  147.     EXPORTING
  148.       url                = lv_url
  149.     IMPORTING
  150.       client             = lr_http_client
  151.     EXCEPTIONS
  152.       argument_not_found = 1
  153.       plugin_not_active  = 2
  154.       internal_error     = 3
  155.       OTHERS             = 4.

  157.   CALL METHOD lr_http_client->request->set_header_field
  158.     EXPORTING
  159.       name  = '~request_method'
  160.       value = 'POST'.

  162.   CALL METHOD lr_http_client->request->set_header_field
  163.     EXPORTING
  164.       name  = '~server_protocol'
  165.       value = 'HTTP/1.1'.

  167.   CALL METHOD lr_http_client->request->set_header_field
  168.     EXPORTING
  169.       name  = 'Content-Type'
  170.       value = 'application/json; charset=utf-8'.
  171.   CALL METHOD lr_http_client->request->set_header_field
  172.     EXPORTING
  173.       name  = 'Accept'
  174.       value = 'application/json'.
  175. *  CALL METHOD lr_http_client->request->set_header_field
  176. *    EXPORTING
  177. *      name  = 'Content-Length'
  178. *      value = len_str.


  181.   CALL METHOD lr_http_client->request->set_cdata
  182.     EXPORTING
  183.       data   = lv_post_string
  184.       offset = 0
  185.       length = lv_len.

  187.   CALL METHOD lr_http_client->send
  188.     EXCEPTIONS
  189.       http_communication_failure = 1
  190.       http_invalid_state         = 2.
  191.   CALL METHOD lr_http_client->receive
  192.     EXCEPTIONS
  193.       http_communication_failure = 1
  194.       http_invalid_state         = 2
  195.       http_processing_failed     = 3.

  197.   lv_result = lr_http_client->response->get_cdata( ).

  199. ENDFUNCTION.
复制代码
JSON, RFC

相关帖子
回复

使用道具 举报

Venus
谢谢楼主的分享，请问第三方是怎么联系啊，我们公司现在正想用此功能给客户发短息
回复 支持 反对

使用道具 举报

Twilight

RE: SAP中用json数据格式调用http接口发送短信邮件案例

Venus 发表于 2017-8-10 10:13
谢谢楼主的分享，请问第三方是怎么联系啊，我们公司现在正想用此功能给客户发短息

短信平台都不一样，有阿里大鱼短信接口、云片短信平台，或者联通短信接口，每家的API数据通信格式都可能不一样，看他们提供的API文档，然后具体问题具体分析啦
回复 支持 反对

使用道具 举报

zhongguomao
没用过，不过好高大上，先收藏再说。
回复 支持 反对

使用道具 举报

Twilight

管理员

+发表新主题
  1. 847 主题
  2. 125 回帖
  3. 11270 积分
发消息

Ta最近发表

快速回帖

本版积分规则
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册有礼

小黑屋|手机版|SAP顾问圈 ( 沪ICP备18020878号 )

GMT+8, 2024-12-23 07:17 , Processed in 0.051832 second(s), 7 queries , Gzip On, Redis On.

© 2014-2017 SAPclubDesign by Twilight.Liu®X3.5

平台客服 1204767879 无客服码

快速回复 返回顶部 返回列表