ooalv中通过alv控件修改和删除alv数据并更新到数据库

程序执行效果如下：

修改第三行的一项数据，再删除第一和第二行，然后点击保存按钮，在点击退出，获得如下结果：

注：该实例是在屏幕上建立custom control控件，实现oolav输出报表的扩展，如阅读有困难可先参考它。
工具栏需要再定义一个save保存按钮。

处理过程如下：
（1）、设定ALV控件可以编辑；
（2）、退出屏幕时将数据更新到内表；
（3）、捕捉alv控件的数据更改信息，将alv控件的删除行信息保存到内表中；
（4）、在输出时，比较删除行和最后的内表，删除重复行；
（5）、将数据更新到数据库表。

主程序：

REPORT ZDEMON_006.
DATA OK_CODE TYPE SY-UCOMM. " SY-UCOMM：Function code that PAI triggered
TABLES SPFLI.
DATA LS_SPFLI TYPE SPFLI.
DATA IT_SPFLI TYPE TABLE OF SPFLI.
DATA IT_DEL_SPFLI TYPE TABLE OF SPFLI.
DATA:S_CONTAINER TYPE SCRFNAME VALUE 'ALVDATA', " SCRFNAME: Name of a Screen Element 只能为该类型
ALV_GRID TYPE REF TO CL_GUI_ALV_GRID, "参考CL_GUI_ALV_GRID类，定义对象ALV_GRID
LO_CUSTOM_CONTAINER TYPE REF TO CL_GUI_CUSTOM_CONTAINER.
CLASS LCL_EVENT_RECEIVER DEFINITION DEFERRED."DEFERRED大概就是 “预定义”类，先告诉你会有这么一个类，可被别的地方用，之后它还是要定义的
DATA EVENT_RECEIVER TYPE REF TO LCL_EVENT_RECEIVER. "定义事件
SELECT *
INTO CORRESPONDING FIELDS OF TABLE IT_SPFLI
FROM SPFLI.
*alv控制布局结构
DATA GS_LAYOUT TYPE LVC_S_LAYO.
*定义可编辑
GS_LAYOUT-EDIT = 'X'.
*定义事件的属性和方法
CLASS LCL_EVENT_RECEIVER DEFINITION.
PUBLIC SECTION.
*删除内表
TYPES:DEL_ROWS TYPE STANDARD TABLE OF SPFLI.
DATA:DDEL_ROWS TYPE STANDARD TABLE OF SPFLI.
*alv数据修改事件
METHODS:
HANDLE_DATA_CHANGED
FOR EVENT DATA_CHANGED OF CL_GUI_ALV_GRID
IMPORTING ER_DATA_CHANGED.
*读取内表更新的数据
METHODS:
UPDATE_DELTA_TABLES
IMPORTING
PR_DATA_CHANGED TYPE REF TO CL_ALV_CHANGED_DATA_PROTOCOL.
*读取删除的内表
METHODS:
GET_DELETED_ROWS
EXPORTING
DELETED_ROWS TYPE DEL_ROWS.
ENDCLASS.
*实现
CLASS LCL_EVENT_RECEIVER IMPLEMENTATION.
*alv数据修改事件
METHOD HANDLE_DATA_CHANGED.
CALL METHOD UPDATE_DELTA_TABLES( ER_DATA_CHANGED ).
ENDMETHOD.
*读取内表更新的数据
*仅需要读取删除的记录，因为还能通过alv的方法取更新后的内表
METHOD UPDATE_DELTA_TABLES.
*取得删除的内表记录
*逐行将删除数据存入删除内表
DATA:L_DEL_ROW TYPE LVC_S_MOCE.
LOOP AT PR_DATA_CHANGED->MT_DELETED_ROWS INTO L_DEL_ROW.
READ TABLE IT_SPFLI INTO LS_SPFLI INDEX L_DEL_ROW-ROW_ID.
IF SY-SUBRC NE 0.
MESSAGE E208(00) WITH '处理错误'.
ELSE.
APPEND LS_SPFLI TO DDEL_ROWS.
ENDIF.
ENDLOOP.
ENDMETHOD.
*定义取内表的方法
METHOD GET_DELETED_ROWS.
DELETED_ROWS = ME->DDEL_ROWS.
ENDMETHOD.
ENDCLASS.
START-OF-SELECTION.
CALL SCREEN 100.
WRITE / '删除的内表记录：'.
WRITE / '-----------------'.
*通过事件对象取删除的记录
CALL METHOD EVENT_RECEIVER->GET_DELETED_ROWS
IMPORTING DELETED_ROWS = IT_DEL_SPFLI.
*在屏幕上输出删除记录，查阅数据有无变化
LOOP AT IT_DEL_SPFLI INTO SPFLI.
WRITE:/ SPFLI-CARRID,SPFLI-CONNID,SPFLI-CITYFROM.
ENDLOOP.
WRITE:/ '更新后的内表记录'.
WRITE / '----------------'.
*在屏幕上输出删除记录，查阅数据有无变化
LOOP AT IT_SPFLI INTO SPFLI.
WRITE:/ SPFLI-CARRID,SPFLI-CONNID,SPFLI-CITYFROM.
ENDLOOP.
MODULE STATUS_0100 OUTPUT.
SET PF-STATUS 'STATUS1'.
SET TITLEBAR 'ALV TITLEBAR'.
ENDMODULE. " STATUS_0100 OUTPUT
MODULE USER_COMMAND_0100 INPUT.
CASE OK_CODE.
WHEN 'CANCEL'.
LEAVE PROGRAM.
WHEN 'BACK' OR 'EXIT'.
DATA L_RET VALUE 'X'.
CALL METHOD ALV_GRID->CHECK_CHANGED_DATA
IMPORTING
E_VALID = L_RET.
LEAVE TO SCREEN 0.
*将更新后的内表数据更新到数据库并按删除的内部数据删除数据库记录
WHEN 'SAVE'.
MODIFY SPFLI FROM TABLE IT_SPFLI.
*若不成功提示错误
IF SY-SUBRC NE 0.
MESSAGE I005(ZDEMON) WITH '修改更新数据错误！'.
EXIT.
ELSE.
MESSAGE I005(ZDEMON) WITH '修改更新数据ok！'.
ENDIF.
DELETE SPFLI FROM TABLE IT_DEL_SPFLI.
IF SY-SUBRC NE 0.
MESSAGE I005(ZDEMON) WITH '删除更新数据错误！'.
ELSE.
MESSAGE I005(ZDEMON) WITH '删除更新数据ok！'.
ENDIF.
ENDCASE.
ENDMODULE. " USER_COMMAND_0100 INPUT
MODULE CLEAR_OK_CODE OUTPUT.
CLEAR OK_CODE.
ENDMODULE. " CLEAR_OK_CODE OUTPUT
MODULE DISPLAY_OOALV OUTPUT.
IF LO_CUSTOM_CONTAINER IS INITIAL. "如果LO_CUSTOM_CONTAINE RDialog容器对象不存在，实例化该对象
CREATE OBJECT LO_CUSTOM_CONTAINER
EXPORTING CONTAINER_NAME = S_CONTAINER.
CREATE OBJECT ALV_GRID "实例化alv对象
EXPORTING I_PARENT = LO_CUSTOM_CONTAINER.
*将更新事件赋给alv对象
CREATE OBJECT EVENT_RECEIVER.
SET HANDLER EVENT_RECEIVER->HANDLE_DATA_CHANGED FOR ALV_GRID.
CALL METHOD ALV_GRID->SET_TABLE_FOR_FIRST_DISPLAY "调用alv对象的方法显示报表
EXPORTING I_STRUCTURE_NAME = 'SPFLI'
IS_LAYOUT = GS_LAYOUT
CHANGING IT_OUTTAB = IT_SPFLI.
ENDIF.
ENDMODULE. " DISPLAY_OOALV OUTPUT

复制代码

[ooalv] ooalv中通过alv控件修改和删除alv数据并更新到数据库

相关帖子

Ta最近发表

快速回帖