通过事件控制实现ALV复选框只能单选

1、程序代码：

1. TYPE-POOLS slis.
   
2. 
   
3. DATA: BEGIN OF gt_list OCCURS 0,
   
4.         sel   TYPE char4,
   
5.         val   TYPE i,
   
6.         style TYPE lvc_t_styl,
   
7.       END OF gt_list.
   
8. DATA: gs_styl TYPE lvc_s_styl,
   
9.       gs_scol TYPE lvc_s_scol.
   
10. 
    
11. DEFINE mcr_fill_styl.
    
12.   GS_STYL-FIELDNAME = &1.
    
13.   GS_STYL-STYLE     = &2.
    
14.   INSERT GS_STYL INTO TABLE GT_LIST-STYLE.
    
15.   CLEAR GS_STYL.
    
16. END-OF-DEFINITION.
    
17. 
    
18. DATA: go_ALV_grid TYPE REF TO cl_gui_alv_grid.
    
19. 
    
20. *&---------------------------------------------------------------------*
    
21. *&      START-OF-SELECTION
    
22. *&---------------------------------------------------------------------*
    
23. START-OF-SELECTION.
    
24.   PERFORM frm_get_data.
    
25.   PERFORM frm_dsp_data.
    
26. *&---------------------------------------------------------------------*
    
27. *&      Form  FRM_GET_DATA
    
28. *&---------------------------------------------------------------------*
    
29. FORM frm_get_data .
    
30.   DATA: lv_index TYPE i.
    
31.   DO 3 TIMES.
    
32.     lv_index = sy-index.
    
33.     DO sy-index * 2 TIMES.
    
34.       IF sy-index NE 1.
    
35.         mcr_fill_styl:  'SEL'   cl_gui_alv_grid=>mc_style_disabled.
    
36.       ELSE.
    
37.         mcr_fill_styl:  'SEL'   cl_gui_alv_grid=>mc_style_enabled.
    
38.       ENDIF.
    
39.       gt_list-val = lv_index.
    
40.       APPEND gt_list.
    
41.       CLEAR gt_list.
    
42.     ENDDO.
    
43.   ENDDO.
    
44. ENDFORM.                    " FRM_GET_DATA
    
45. *&---------------------------------------------------------------------*
    
46. *&      Form  FRM_DSP_DATA
    
47. *&---------------------------------------------------------------------*
    
48. FORM frm_dsp_data .
    
49.   DATA: ls_layo  TYPE lvc_s_layo,
    
50.         lt_fcat  TYPE lvc_t_fcat,
    
51.         ls_fcat  TYPE lvc_s_fcat,
    
52.         lt_event TYPE slis_t_event,
    
53.         ls_event TYPE slis_alv_event.
    
54.   ls_layo-zebra      = abap_true.
    
55.   ls_layo-cwidth_opt = abap_true.
    
56.   ls_layo-stylefname = 'STYLE'.
    
57.   ls_fcat-fieldname = 'SEL'.
    
58.   ls_fcat-checkbox = 'X'.
    
59.   ls_fcat-edit = 'X'.
    
60.   ls_fcat-scrtext_l =
    
61.   ls_fcat-scrtext_m =
    
62.   ls_fcat-scrtext_s = '选择'.
    
63.   APPEND ls_fcat TO lt_fcat.
    
64.   CLEAR ls_fcat.
    
65.   ls_fcat-fieldname = 'VAL'.
    
66.   ls_fcat-scrtext_l =
    
67.   ls_fcat-scrtext_m =
    
68.   ls_fcat-scrtext_s = '值'.
    
69.   APPEND ls_fcat TO lt_fcat.
    
70.   CLEAR ls_fcat.
    
71.   ls_event-name = slis_ev_caller_exit_at_start.
    
72.   ls_event-form = slis_ev_caller_exit_at_start.
    
73.   APPEND ls_event TO lt_event.
    
74.   ls_event-name = slis_ev_data_changed.
    
75.   ls_event-form = slis_ev_data_changed.
    
76.   APPEND ls_event TO lt_event.
    
77. * 显示alv列表
    
78.   CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY_LVC'
    
79.     EXPORTING
    
80.       i_callback_program = sy-repid
    
81.       is_layout_lvc      = ls_layo
    
82.       it_fieldcat_lvc    = lt_fcat
    
83.       i_save             = 'A'
    
84.       it_events          = lt_event
    
85.     TABLES
    
86.       t_outtab           = gt_list
    
87.     EXCEPTIONS
    
88.       program_error      = 1
    
89.       OTHERS             = 2.
    
90.   IF sy-subrc <> 0.
    
91.     MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
    
92.           WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    
93.   ENDIF.
    
94. ENDFORM.                    " FRM_DSP_DATA
    
95. *&---------------------------------------------------------------------*
    
96. *&      Form  CALLER_EXIT
    
97. *&---------------------------------------------------------------------*
    
98. FORM caller_exit USING u_exit TYPE slis_data_caller_exit.
    
99.   DATA: ls_f4 TYPE lvc_s_f4,
    
100.         lt_f4 TYPE lvc_t_f4.
     
101.   CALL FUNCTION 'GET_GLOBALS_FROM_SLVC_FULLSCR'
     
102.     IMPORTING
     
103.       e_grid = go_alv_grid.
     
104. * 设置回车事件
     
105.   CALL METHOD go_alv_grid->register_edit_event
     
106.     EXPORTING
     
107.       i_event_id = cl_gui_alv_grid=>mc_evt_enter
     
108.     EXCEPTIONS
     
109.       error      = 1
     
110.       OTHERS     = 2.
     
111. * 设置光标焦点移开被修改单元格后触发事件
     
112.   CALL METHOD go_alv_grid->register_edit_event
     
113.     EXPORTING
     
114.       i_event_id = cl_gui_alv_grid=>mc_evt_modified
     
115.     EXCEPTIONS
     
116.       error      = 1
     
117.       OTHERS     = 2.
     
118. ENDFORM.                    "CALLER_EXIT
     
119. *&---------------------------------------------------------------------*
     
120. *&      Form  DATA_CHANGED
     
121. *&---------------------------------------------------------------------*
     
122. *       数据改变检查
     
123. *----------------------------------------------------------------------*
     
124. FORM data_changed USING or_data_changed TYPE REF TO cl_alv_changed_data_protocol.
     
125.   DATA: ls_mod_cells  TYPE lvc_s_modi.
     
126.   FIELD-SYMBOLS: <fs_line>  LIKE gt_list,
     
127.                  <fs_value> TYPE any.
     
128.   LOOP AT or_data_changed->mt_good_cells INTO ls_mod_cells.
     
129.     CLEAR gt_list.
     
130.     READ TABLE gt_list ASSIGNING <fs_line> INDEX ls_mod_cells-row_id.
     
131.     IF sy-subrc EQ 0.
     
132.       ASSIGN COMPONENT ls_mod_cells-fieldname OF STRUCTURE <fs_line> TO <fs_value>.
     
133.       IF sy-subrc EQ 0.
     
134.         CALL METHOD or_data_changed->get_cell_value
     
135.           EXPORTING
     
136.             i_row_id    = ls_mod_cells-row_id
     
137.             i_fieldname = ls_mod_cells-fieldname
     
138.           IMPORTING
     
139.             e_value     = <fs_value>.
     
140.       ENDIF.
     
141.     ENDIF.
     
142.     CASE ls_mod_cells-fieldname.
     
143.       WHEN 'SEL'.
     
144.         gt_list-sel = ''.
     
145.         MODIFY gt_list TRANSPORTING sel WHERE sel IS NOT INITIAL.
     
146.         LOOP AT gt_list
     
147.           WHERE val EQ <fs_line>-val .
     
148.           gt_list-sel = 'X'.
     
149.           MODIFY gt_list TRANSPORTING sel.
     
150.         ENDLOOP.
     
151.       WHEN OTHERS.
     
152.     ENDCASE.
     
153.   ENDLOOP.
     
154.   PERFORM frm_ref_alv.
     
155. ENDFORM.                    " DATA_CHANGED
     
156. *&---------------------------------------------------------------------*
     
157. *&      Form  FRM_REF_ALV
     
158. *&---------------------------------------------------------------------*
     
159. FORM frm_ref_alv .
     
160.   DATA ls_stbl TYPE lvc_s_stbl.
     
161.   ls_stbl-row = abap_true.
     
162.   ls_stbl-col = abap_true.
     
163.   CALL METHOD go_alv_grid->refresh_table_display
     
164.     EXPORTING
     
165.       is_stable = ls_stbl.
     
166. ENDFORM.                    " FRM_REF_ALV

复制代码

2、程序效果：

ls_fcat-checkbox = 'X'. 这是关键