设为首页收藏本站站点任务
请登陆 注册有礼
二维码
网站快捷导航

[基础语法] ABAP动态指针Field symbol使用案例

Twilight发表于 2015-08-19 17:33Twilight 最后回复于 2015-08-19 17:33 [复制链接] 15145 0

通过一些小案例来熟悉动态指针Field symbol的使用。

1、Full type specification
  1. DATA: BEGIN OF line,
  2.         col1(1) TYPE c,
  3.         col2(1) TYPE c VALUE 'X',
  4.       END OF line.
  5. FIELD-SYMBOLS <fs> LIKE line.

  7. ASSIGN line TO <fs>.
  8. <fs>-col1 = <fs>-col2.
  9. WRITE: <fs>-col1, <fs>-col2.
复制代码
输出结果：X，X

2、Forcing structures
  1. DATA: wa(10) TYPE c VALUE '0123456789'.
  2. DATA: BEGIN OF line1,
  3.         col1(3) TYPE c,
  4.         col2(2) TYPE c,
  5.         col3(5) TYPE c,
  6.       END OF line1.
  7. DATA: BEGIN OF line2,
  8.         col1(2) TYPE c,
  9.         col2    TYPE sy-datum,
  10.       END OF line2.

  12. * obsolete -------------------------------------------------------------
  13. FIELD-SYMBOLS: <f1> STRUCTURE line1 DEFAULT wa,
  14.                <f2> STRUCTURE line2 DEFAULT wa.

  16. * correct --------------------------------------------------------------
  17. FIELD-SYMBOLS <f3> LIKE line1.
  18. ASSIGN wa TO <f3> CASTING.

  20. FIELD-SYMBOLS <f4> LIKE line2.
  21. ASSIGN wa TO <f4> CASTING.

  23. * ----------------------------------------------------------------------
  24. WRITE: / <f1>-col1, <f1>-col2, <f1>-col3,
  25.        / <f2>-col1, <f2>-col2.
  26. SKIP.
  27. WRITE: / <f3>-col1, <f3>-col2, <f3>-col3,
  28.        / <f4>-col1, <f4>-col2.
复制代码
输出结果：
  1. 012 34 56789
  2. 01 2345.67.89

  4. 012 34 56789
  5. 01 2345.67.89
复制代码

3、Static assign
  1. FIELD-SYMBOLS: <f1> TYPE any, <f2> TYPE i.
  2. DATA: text(20) TYPE c VALUE 'Hello, how are you?',
  3.       num      TYPE i VALUE 5,
  4.       BEGIN OF line1,
  5.         col1 TYPE f VALUE '1.1e+10',
  6.         col2 TYPE i VALUE '1234',
  7.       END OF line1,
  8.       line2 LIKE line1.

  10. ASSIGN text TO <f1>.
  11. ASSIGN num TO  <f2>.
  12. DESCRIBE FIELD <f1> LENGTH <f2> IN BYTE MODE.
  13. WRITE: / <f1>, 'has length', num.

  15. ASSIGN line1 TO <f1>.
  16. ASSIGN line2-col2 TO <f2>.
  17. MOVE <f1> TO line2.
  18. ASSIGN 'LINE2-COL2 =' TO <f1>.
  19. WRITE: / <f1>, <f2>.
复制代码
输出结果：
  1. Hello, how are you?  has length         40
  2. LINE2-COL2 =      1,234
复制代码

4、Assign with offset 偏移量n(m)，表示截取从n+1（包括n+1）开始长度为m的字符串
  1. FIELD-SYMBOLS <fs> TYPE any.
  2. DATA: BEGIN OF line,
  3.         string1(10) VALUE '0123456789',
  4.         string2(10) VALUE 'abcdefghij',
  5.       END OF line.

  7. WRITE / line-string1+5.

  9. ASSIGN line-string1+5(*) TO <fs>.
  10. WRITE / <fs>.
复制代码
输出结果：
  1. 56789
  2. 56789
复制代码

6、Dynamic assign
  1. TABLES sbook.
  2. DATA: name1(20) TYPE c VALUE 'SBOOK-FLDATE',
  3.       name2(20) TYPE c VALUE 'NAME1'.
  4. FIELD-SYMBOLS <fs> TYPE any.

  6. ASSIGN TABLE FIELD (name1) TO <fs>.
  7. WRITE: / 'SY-SUBRC:', sy-subrc.

  9. ASSIGN TABLE FIELD (name2) TO <fs>.
  10. WRITE: / 'SY-SUBRC:', sy-subrc.
复制代码
输出结果：
  1. SY-SUBRC:     0
  2. SY-SUBRC:     4
复制代码
(name1) 是call by value 的用法，取的是name1里的值SBOOK-FLDATE
7、Assigning a structure by component
  1. DATA: BEGIN OF line,
  2.         col1 TYPE i VALUE '11',
  3.         col2 TYPE i VALUE '22',
  4.         col3 TYPE i VALUE '33',
  5.       END OF line.
  6. DATA comp(5) TYPE c VALUE 'COL3'.
  7. FIELD-SYMBOLS: <f1> TYPE any, <f2> TYPE any, <f3> TYPE any.

  9. ASSIGN line TO <f1>.
  10. ASSIGN comp TO <f2>.

  12. DO 3 TIMES.
  13.   ASSIGN COMPONENT sy-index OF STRUCTURE <f1> TO <f3>.
  14.   WRITE <f3>.
  15. ENDDO.

  17. ASSIGN COMPONENT <f2> OF STRUCTURE <f1> TO <f3>.
  18. WRITE / <f3>.
复制代码
输出结果：
  1.         11          22          33
  2.         33
复制代码

8、Casting with field symbol type：CASTING主要用来指定<fs>的隐式数据类型t_date
  1. TYPES: BEGIN OF t_date,
  2.          year(4)  TYPE n,
  3.          month(2) TYPE n,
  4.          day(2)   TYPE n,
  5.        END OF t_date.
  6. FIELD-SYMBOLS <fs> TYPE t_date.

  8. ASSIGN sy-datum TO <fs> CASTING.

  10. WRITE / sy-datum.
  11. SKIP.
  12. WRITE: / <fs>-year , / <fs>-month, / <fs>-day.
复制代码
输出结果：
  1. 2015.08.19

  3. 2015
  4. 08
  5. 19
复制代码

9、Casting with explicit type：CASTING主要用来指定<fs>的显式数据类型t_date
  1. TYPES: BEGIN OF t_date,
  2.          year(4)  TYPE n,
  3.          month(2) TYPE n,
  4.          day(2)   TYPE n,
  5.        END OF t_date.
  6. FIELD-SYMBOLS: <fs> TYPE any,
  7.                <f>  TYPE n.

  9. ASSIGN sy-datum TO <fs> CASTING TYPE t_date.
  10. WRITE / sy-datum.
  11. SKIP.
  12. DO.
  13.   ASSIGN COMPONENT sy-index OF STRUCTURE <fs> TO <f>.
  14.   IF sy-subrc <> 0.
  15.     EXIT.
  16.   ENDIF.
  17.   WRITE / <f>.
  18. ENDDO.
复制代码
结果同上
10、Casting with predefined data types
  1. DATA txt(8) TYPE c VALUE '19980606'.
  2. DATA mytype(1) VALUE 'X'.
  3. FIELD-SYMBOLS <fs> TYPE any.

  5. ASSIGN txt TO <fs>.
  6. WRITE / <fs>.

  8. SKIP.
  9. * obsolete -------------------------------------------------------------
  10. ASSIGN txt TO <fs> TYPE 'D'.
  11. WRITE / <fs>.

  13. ASSIGN txt TO <fs> TYPE mytype.
  14. WRITE / <fs>.

  16. SKIP.
  17. * correct --------------------------------------------------------------
  18. ASSIGN txt TO <fs> CASTING TYPE d.
  19. WRITE / <fs>.

  21. ASSIGN txt TO <fs> CASTING TYPE (mytype).
  22. WRITE / <fs>.
复制代码
输出结果：
  1. 19980606

  3. 19980606
  4. 31003900390038003000360030003600

  6. 19980606
  7. 31003900390038003000360030003600
复制代码

11、Casting decimla places
  1. DATA: pack1 TYPE p DECIMALS 2 VALUE '400',
  2.       pack2 TYPE p DECIMALS 2,
  3.       pack3 TYPE p DECIMALS 2.
  4. FIELD-SYMBOLS: <f1> TYPE any,
  5.                <f2> TYPE any.

  7. WRITE: / 'PACK1', pack1.
  8. SKIP.

  10. * obsolete -------------------------------------------------------------
  11. ASSIGN pack1 TO <f1> DECIMALS 1.
  12. WRITE: / '<F1> ', <f1>.

  14. pack2 = <f1>.
  15. WRITE: / 'PACK2', pack2.

  17. ASSIGN pack2 TO <f2> DECIMALS 4.
  18. WRITE: / '<F2> ', <f2>.

  20. pack3 = <f1> + <f2>.
  21. WRITE: / 'PACK3', pack3.

  23. <f2> = '1234.56789'.
  24. WRITE: / '<F2> ', <f2>.
  25. WRITE: / 'PACK2', pack2.

  27. SKIP.
  28. * correct --------------------------------------------------------------
  29. ASSIGN pack1 TO <f1> CASTING TYPE p DECIMALS 1.
  30. WRITE: / '<F1> ', <f1>.

  32. pack2 = <f1>.
  33. WRITE: / 'PACK2', pack2.

  35. ASSIGN pack2 TO <f2> CASTING TYPE p DECIMALS 4.
  36. WRITE: / '<F2> ', <f2>.

  38. pack3 = <f1> + <f2>.
  39. WRITE: / 'PACK3', pack3.

  41. <f2> = '1234.56789'.
  42. WRITE: / '<F2> ', <f2>.
  43. WRITE: / 'PACK2', pack2.
复制代码
输出结果：
  1. PACK1           400.00

  3. <F1>           4,000.0
  4. PACK2         4,000.00
  5. <F2>           40.0000
  6. PACK3         4,040.00
  7. <F2>        1,234.5679
  8. PACK2       123,456.79

  10. <F1>           4,000.0
  11. PACK2         4,000.00
  12. <F2>           40.0000
  13. PACK3         4,040.00
  14. <F2>        1,234.5679
  15. PACK2       123,456.79
复制代码

12、Data references：分配类的方法给指针
  1. TYPES: BEGIN OF t_struct,
  2.          col1 TYPE i,
  3.          col2 TYPE i,
  4.        END OF t_struct.
  5. DATA: dref1 TYPE REF TO data,
  6.       dref2 TYPE REF TO data.

  8. FIELD-SYMBOLS: <fs1> TYPE t_struct,
  9.                <fs2> TYPE i.

  11. CREATE DATA dref1 TYPE t_struct.

  13. ASSIGN dref1->* TO <fs1>.

  15. <fs1>-col1 = 1.
  16. <fs1>-col2 = 2.

  18. dref2 = dref1.

  20. ASSIGN dref2->* TO <fs2> CASTING.
  21. WRITE / <fs2>.

  23. GET REFERENCE OF <fs1>-col2 INTO dref2.

  25. ASSIGN dref2->* TO <fs2>.
  26. WRITE / <fs2>.
复制代码
输出结果：
  1.          1
  2.          2
复制代码

注意：ASSIGN TABLE FIELD (f) TO <fs>. 只能用TABLES定义的变量
动态, 指针, Field symbol

相关帖子
回复

使用道具 举报

Twilight

管理员

+发表新主题
  1. 846 主题
  2. 125 回帖
  3. 11239 积分
发消息

Ta最近发表

快速回帖

本版积分规则
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册有礼

小黑屋|手机版|SAP顾问圈 ( 沪ICP备18020878号 )

GMT+8, 2024-11-21 20:16 , Processed in 0.051845 second(s), 7 queries , Gzip On, Redis On.

© 2014-2017 SAPclubDesign by Twilight.Liu®X3.5

平台客服 1204767879 无客服码

快速回复 返回顶部 返回列表