设为首页收藏本站站点任务
请登陆 注册有礼
二维码
网站快捷导航

[面向对象] ABAP面向对象中的接口使用教程

Twilight发表于 2014-02-22 17:21Twilight 最后回复于 2014-02-22 17:21 [复制链接] 4947 0

接口与继承之间的区别：
  • 继承只能单继承，就是一个类只能有一个直接父类，而一个类可以实现多个接口
  • 一个类不能继承多个父类，而这个类又需要多种属性，这个时候就可以用接口了
  • 接口与类属于同一层次，实际上，接口是一种特殊的抽象类。

练习7 定义和使用接口
情景：一个旅游代理公司，是一个agency，对于每个旅游代理公司，会有各种各样的合作伙伴，包括酒店、航空公司、汽车公司等，对于这些不同类别的公司，代理公司与他们有一些标准化的业务，凡是符合这些业务标准的，都可以视为合作伙伴。
技术要求：建立类lcl_travel_agency，并定义接口lif_partner，来规定其合作伙伴应该具有的功能，修改lcl_carrier类，建立lcl_rental，符合接口，并写代码测试。
1、从 SAPBC401_VEHD_F中拷贝类lcl_rental  lcl_vehicle  lcl_truck的定义
2、完善lcl_carrier，使之符合接口规范
3、从SAPBC401_VEHT_MAIN_A拷贝代码，建立一些关于车辆的实例，并调用display_attributes方法显示内容。
4、从SAPBC401_VEHT_B中拷贝lcl_travel_agency的定义，并进行对应的修改
5、测试用lcl_travel_agency显示partner信息

执行效果：
abap面向对象中的接口使用方法.jpg

主程序代码：
  1. REPORT  ZBC10_EX_7.  "构造函数  主要用来在创建对象时初始化对象 即为对象成员变量赋初始值  重载
  2. INCLUDE ZBC10_EX_A_7.
  3. INCLUDE ZBC10_EX_B_7.
  4. INCLUDE ZBC10_EX_C_7.
  5. INCLUDE ZBC10_EX_E_7.
  6. INCLUDE ZBC10_EX_D_7.
  7. INCLUDE ZBC10_EX_F_7.

  9. DATA:R_AIRPLANE TYPE REF TO LCL_AIRPLANE, "相当于结构
  10.      RT_AIRPLANE TYPE TABLE OF REF TO LCL_AIRPLANE. "相当于内表
  11. DATA:R_PASSENGER_PLANE TYPE REF TO LCL_PASSENGER_PLANE,
  12.      R_CARGO_PLANE TYPE REF TO LCL_CARGO_PLANE,
  13.      R_CARRIER TYPE REF TO LCL_CARRIER.

  15. START-OF-SELECTION. "面向对象必须写，面向过程可以不写
  16. CREATE OBJECT R_CARRIER EXPORTING IM_NAME = 'AA'.
  17. CREATE OBJECT R_AIRPLANE EXPORTING IM_NAME = '001'
  18.                                    IM_PLANETYPE = '747-400'.
  19. R_CARRIER->ADD_AIRPLANE( R_AIRPLANE ).

  21. CREATE OBJECT R_AIRPLANE EXPORTING IM_NAME = '002'
  22.                                    IM_PLANETYPE = '747-500'.
  23. R_CARRIER->ADD_AIRPLANE( R_AIRPLANE ).

  25. CREATE OBJECT R_PASSENGER_PLANE EXPORTING IM_NAME = '003'
  26.                                           IM_PLANETYPE = '747-400'
  27.                                           IM_MAXSEATS = '200'.
  28. R_CARRIER->ADD_AIRPLANE( R_PASSENGER_PLANE ).

  30. CREATE OBJECT R_CARGO_PLANE EXPORTING IM_NAME = '004'
  31.                                       IM_PLANETYPE = '747-400'
  32.                                       IM_MAXCARGO = '300'.
  33. R_CARRIER->ADD_AIRPLANE( R_CARGO_PLANE ).

  35. R_CARRIER->DISPLAY_ATTRIBUTES( ).



  39. DATA: r_vehicle TYPE REF TO lcl_vehicle,
  40.       r_truck TYPE REF TO lcl_truck,
  41.       r_bus   TYPE REF TO lcl_bus,
  42.       r_rental TYPE REF TO lcl_rental.

  44. START-OF-SELECTION.
  45. *##########################

  47. ******* create rental *****************************************
  48.   CREATE OBJECT r_rental EXPORTING im_name = 'HAPPY CAR RENTAL'.

  50. ******* create truck *****************************************
  51.   CREATE OBJECT r_truck EXPORTING im_make = 'MAN'
  52.                                   im_cargo = 45.
  53.   r_rental->add_vehicle( r_truck ).
  54. ******* create truck *****************************************
  55.   CREATE OBJECT r_bus EXPORTING im_make = 'Mercedes'
  56.                                 im_passengers = 80.
  57.   r_rental->add_vehicle( r_bus ).
  58. ******* create truck *****************************************
  59.   CREATE OBJECT r_truck EXPORTING im_make = 'VOLVO'
  60.                                   im_cargo = 48.
  61.   r_rental->add_vehicle( r_truck ).

  63.   DATA: R_AGENCY TYPE REF TO lcl_travel_agency.
  64.   CREATE OBJECT R_AGENCY EXPORTING IM_NAME = 'XX'.
  65.   R_AGENCY->ADD_PARTNER( R_CARRIER ).
  66.   R_AGENCY->ADD_PARTNER( R_RENTAL ).

  68.   R_AGENCY->DISPLAY_AGENCY_PARTNERS( ).
复制代码
INCLUDE ZBC10_EX_A_7.
  1. *&---------------------------------------------------------------------*
  2. *&  Include           ZBC10_EX_A
  3. *&---------------------------------------------------------------------*
  4. CLASS LCL_AIRPLANE DEFINITION.
  5.   PUBLIC SECTION.
  6.     METHODS:CONSTRUCTOR IMPORTING IM_NAME TYPE  STRING
  7.                                   IM_PLANETYPE TYPE SAPLANE-PLANETYPE.
  8.     CLASS-METHODS:DISPLAY_N_O_AIRPLANES.
  9.     METHODS:DISPLAY_ATTRIBUTES.
  10.   PROTECTED SECTION.
  11.     DATA:NAME TYPE  STRING,
  12.          PLANETYPE TYPE SAPLANE-PLANETYPE.
  13.     CLASS-DATA:N_0_ARIPLANES TYPE I.
  14.     METHODS:GET_TECHNICAL_ATTRIBUTES IMPORTING IM_TYPE TYPE SAPLANE-PLANETYPE
  15.                                      EXPORTING EX_WEIGHT  TYPE S_PLAN_WEI
  16.                                                EX_TANKCAP TYPE   S_CAPACITY.
  17. ENDCLASS.                    "LCL_AIRPLANE DEFINITION

  19. *----------------------------------------------------------------------*
  20. *       CLASS LCL_AIRPLANE IMPLEMENTATION
  21. *----------------------------------------------------------------------*
  22. *
  23. *----------------------------------------------------------------------*
  24. CLASS LCL_AIRPLANE IMPLEMENTATION.
  25.   METHOD CONSTRUCTOR.
  26.     NAME = IM_NAME.
  27.     PLANETYPE = IM_PLANETYPE.
  28.     N_0_ARIPLANES = N_0_ARIPLANES + 1.
  29.   ENDMETHOD.                    "SET_ATTRIBUTES
  30.   METHOD DISPLAY_N_O_AIRPLANES.
  31.     WRITE: / 'Number of airplanes:',N_0_ARIPLANES.
  32.   ENDMETHOD.                    "DISPLAY_N_O_AIRPLANES
  33.   METHOD DISPLAY_ATTRIBUTES.
  34.     DATA:WEIGHT  TYPE S_PLAN_WEI,
  35.          TANKCAP TYPE   S_CAPACITY.
  36.     ME->GET_TECHNICAL_ATTRIBUTES( EXPORTING IM_TYPE = PLANETYPE    "在类里引用自身的方法用ME  这里的EXPORTING相当于IMPORTING 相反的
  37.                                   IMPORTING EX_WEIGHT = WEIGHT
  38.                                             EX_TANKCAP = TANKCAP ).
  39.     WRITE: / 'name',NAME,'planetype',PLANETYPE,'weight',WEIGHT,'tankcap',TANKCAP.
  40.   ENDMETHOD.                    "display_attributes
  41.   METHOD GET_TECHNICAL_ATTRIBUTES.
  42.     SELECT SINGLE WEIGHT TANKCAP
  43.       INTO (EX_WEIGHT,EX_TANKCAP)
  44.       FROM SAPLANE
  45.       WHERE PLANETYPE = IM_TYPE.
  46.     IF SY-SUBRC NE 0.
  47.       EX_WEIGHT = 0.
  48.       EX_TANKCAP = 0.
  49.     ENDIF.
  50.   ENDMETHOD.                    "GET_TECHNICAL_ATTRIBUTES
  51. ENDCLASS.                    "LCL_AIRPLANE IMPLEMENTATION
复制代码
INCLUDE ZBC10_EX_B_7.
  1. *&---------------------------------------------------------------------*
  2. *&  Include           ZBC10_EX_B_5
  3. *&---------------------------------------------------------------------*
  4. CLASS LCL_PASSENGER_PLANE DEFINITION INHERITING FROM LCL_AIRPLANE.
  5.   PUBLIC SECTION.
  6.     METHODS:CONSTRUCTOR IMPORTING IM_NAME TYPE  STRING
  7.                                   IM_PLANETYPE TYPE SAPLANE-PLANETYPE
  8.                                   IM_MAXSEATS TYPE  SAPLANE-SEATSMAX.
  9.     METHODS DISPLAY_ATTRIBUTES REDEFINITION.
  10.   PRIVATE SECTION.
  11.     DATA:  MAXSEATS TYPE SAPLANE-SEATSMAX.

  13. ENDCLASS.                    "lcl_passenger_plane DEFINITION
  14. CLASS LCL_PASSENGER_PLANE IMPLEMENTATION.
  15.   METHOD CONSTRUCTOR.
  16.     SUPER->CONSTRUCTOR( IM_NAME = IM_NAME IM_PLANETYPE = IM_PLANETYPE ).
  17.     MAXSEATS = IM_MAXSEATS.
  18.   ENDMETHOD.
  19.   METHOD DISPLAY_ATTRIBUTES.
  20.    SUPER->DISPLAY_ATTRIBUTES( ).
  21.    WRITE: 'MAXSEAT',MAXSEATS.
  22.   ENDMETHOD.
  23. ENDCLASS.
复制代码
INCLUDE ZBC10_EX_C_7.
  1. *&---------------------------------------------------------------------*
  2. *&  Include           ZBC10_EX_C_5
  3. *&---------------------------------------------------------------------*
  4. CLASS LCL_CARGO_PLANE DEFINITION INHERITING FROM LCL_AIRPLANE.
  5.   PUBLIC SECTION.
  6.     METHODS:CONSTRUCTOR IMPORTING IM_NAME TYPE  STRING
  7.                                   IM_PLANETYPE TYPE SAPLANE-PLANETYPE
  8.                                   IM_MAXCARGO TYPE  SAPLANE-CAP_UNIT.
  9.     METHODS DISPLAY_ATTRIBUTES REDEFINITION.
  10.   PRIVATE SECTION.
  11.     DATA:MAX_CARGO TYPE SAPLANE-CAP_UNIT.

  13. ENDCLASS.                    "lcl_cargo_plane DEFINITION
  14. *----------------------------------------------------------------------*
  15. *       CLASS LCL_CARGO_PLANE IMPLEMENTATION
  16. *----------------------------------------------------------------------*
  17. *
  18. *----------------------------------------------------------------------*
  19. CLASS LCL_CARGO_PLANE IMPLEMENTATION.
  20.   METHOD CONSTRUCTOR.
  21.     SUPER->CONSTRUCTOR( IM_NAME = IM_NAME IM_PLANETYPE = IM_PLANETYPE ).
  22.     MAX_CARGO = IM_MAXCARGO.
  23.   ENDMETHOD.                    "CONSTRUCTOR
  24.   METHOD DISPLAY_ATTRIBUTES.
  25.     SUPER->DISPLAY_ATTRIBUTES( ).
  26.     WRITE: 'MAXCARGO',MAX_CARGO.
  27.   ENDMETHOD.                    "DISPLAY_ATTRIBUTES
  28. ENDCLASS.                    "LCL_CARGO_PLANE IMPLEMENTATION
复制代码
INCLUDE ZBC10_EX_E_7.
  1. *&---------------------------------------------------------------------*
  2. *&  Include           ZBC10_EX_E_7
  3. *&---------------------------------------------------------------------*

  5. *---------------------------------------------------------------------*
  6. * define interface lif_partners
  7. *
  8. * implement interface inside of lcl_rental
  9. *---------------------------------------------------------------------*
  10. INTERFACE lif_partners.
  11.   METHODS display_partner.
  12. ENDINTERFACE.                    "lif_partners

  14. *---------------------------------------------------------------------*
  15. *       CLASS lcl_vehicle DEFINITION
  16. *---------------------------------------------------------------------*
  17. CLASS lcl_vehicle DEFINITION.

  19.   PUBLIC SECTION.
  20.     "-------------------
  21.     METHODS: get_average_fuel IMPORTING im_distance TYPE s_distance
  22.                                         im_fuel TYPE s_capacity
  23.                               RETURNING value(re_avgfuel) TYPE s_consum.
  24.     METHODS       constructor IMPORTING im_make TYPE string.
  25.     METHODS       display_attributes.
  26.     METHODS       set_make IMPORTING im_make TYPE string.
  27.     METHODS       get_make EXPORTING ex_make TYPE string.
  28.     CLASS-METHODS get_count EXPORTING re_count TYPE i.

  30.   PRIVATE SECTION.
  31.     "-------------------
  32.     DATA: make   TYPE string.

  34.     METHODS      init_make.

  36.     CLASS-DATA:  n_o_vehicles TYPE i.

  38. ENDCLASS.                    "lcl_vehicle DEFINITION

  40. *---------------------------------------------------------------------*
  41. *       CLASS lcl_vehicle IMPLEMENTATION
  42. *---------------------------------------------------------------------*
  43. *
  44. *---------------------------------------------------------------------*
  45. CLASS lcl_vehicle IMPLEMENTATION.
  46.   METHOD get_average_fuel.
  47.     re_avgfuel = im_distance / im_fuel.
  48.   ENDMETHOD.                    "get_average_fuel

  50.   METHOD constructor.
  51.     make = im_make.
  52.     ADD 1 TO n_o_vehicles.
  53.   ENDMETHOD.                    "constructor

  55.   METHOD set_make.
  56.     IF im_make IS INITIAL.
  57.       init_make( ).   " me->init_make( ). also possible
  58.     ELSE.
  59.       make = im_make.
  60.     ENDIF.
  61.   ENDMETHOD.                    "set_make

  63.   METHOD init_make.
  64.     make = 'default make'.
  65.   ENDMETHOD.                    "init_make

  67.   METHOD get_make.
  68.     ex_make = make.
  69.   ENDMETHOD.                    "get_make

  71.   METHOD display_attributes.
  72.     WRITE: make.
  73.   ENDMETHOD.                    "display_attributes

  75.   METHOD get_count.
  76.     re_count = n_o_vehicles.
  77.   ENDMETHOD.                    "get_count

  79. ENDCLASS.                    "lcl_vehicle IMPLEMENTATION


  82. *---------------------------------------------------------------------*
  83. *       CLASS lcl_truck DEFINITION
  84. *---------------------------------------------------------------------*
  85. *
  86. *---------------------------------------------------------------------*
  87. CLASS lcl_truck DEFINITION INHERITING FROM lcl_vehicle.

  89.   PUBLIC SECTION.
  90.     "-------------------
  91.     METHODS:      constructor IMPORTING im_make TYPE string
  92.                                         im_cargo TYPE s_plan_car.

  94.     METHODS       display_attributes REDEFINITION.
  95.     METHODS       get_cargo RETURNING value(re_cargo) TYPE s_plan_car.

  97.   PRIVATE SECTION.
  98.     "-------------------
  99.     DATA: max_cargo TYPE s_plan_car.

  101. ENDCLASS.                    "lcl_truck DEFINITION

  103. *---------------------------------------------------------------------*
  104. *       CLASS lcl_truck IMPLEMENTATION
  105. *---------------------------------------------------------------------*
  106. *
  107. *---------------------------------------------------------------------*
  108. CLASS lcl_truck IMPLEMENTATION.

  110.   METHOD constructor.
  111.     super->constructor( im_make ).
  112.     max_cargo = im_cargo.
  113.   ENDMETHOD.                    "constructor

  115.   METHOD display_attributes.
  116.     WRITE: / icon_ws_truck AS ICON.
  117.     super->display_attributes( ).
  118.     WRITE: 20 ' Cargo = ', max_cargo.
  119.     ULINE.
  120.   ENDMETHOD.                    "display_attributes

  122.   METHOD get_cargo.
  123.     re_cargo = max_cargo.
  124.   ENDMETHOD.                    "get_cargo

  126. ENDCLASS.                    "lcl_truck DEFINITION


  129. *---------------------------------------------------------------------*
  130. *       CLASS lcl_bus DEFINITION
  131. *---------------------------------------------------------------------*
  132. *
  133. *---------------------------------------------------------------------*
  134. CLASS lcl_bus DEFINITION INHERITING FROM lcl_vehicle.

  136.   PUBLIC SECTION.
  137.     "-------------------
  138.     METHODS:      constructor IMPORTING im_make TYPE string
  139.                                         im_passengers TYPE i.

  141.     METHODS       display_attributes REDEFINITION.

  143.   PRIVATE SECTION.
  144.     "-------------------
  145.     DATA: max_passengers TYPE i.

  147. ENDCLASS.                    "lcl_bus DEFINITION

  149. *---------------------------------------------------------------------*
  150. *       CLASS lcl_bus IMPLEMENTATION
  151. *---------------------------------------------------------------------*
  152. *
  153. *---------------------------------------------------------------------*
  154. CLASS lcl_bus IMPLEMENTATION.

  156.   METHOD constructor.
  157.     super->constructor( im_make ).
  158.     max_passengers = im_passengers.
  159.   ENDMETHOD.                    "constructor

  161.   METHOD display_attributes.
  162.     WRITE: / icon_transportation_mode AS ICON.
  163.     super->display_attributes( ).
  164.     WRITE:  20 ' Passengers = ', max_passengers.
  165.     ULINE.
  166.   ENDMETHOD.                    "display_attributes


  169. ENDCLASS.                    "lcl_bus DEFINITION

  171. *---------------------------------------------------------------------*
  172. *       CLASS lcl_rental DEFINITION
  173. *---------------------------------------------------------------------*
  174. *
  175. *---------------------------------------------------------------------*
  176. CLASS lcl_rental DEFINITION.

  178.   PUBLIC SECTION.
  179.     "-------------------
  180.     METHODS:      constructor IMPORTING im_name TYPE string.
  181.     METHODS       add_vehicle IMPORTING im_vehicle
  182.                                   TYPE REF TO lcl_vehicle.
  183.     METHODS       display_attributes.
  184.     INTERFACES lif_partners.

  186.   PRIVATE SECTION.
  187.     "-------------------
  188.     DATA: name TYPE string,
  189.           vehicle_list TYPE TABLE OF REF TO lcl_vehicle.
  190. ENDCLASS.                    "lcl_rental DEFINITION

  192. *---------------------------------------------------------------------*
  193. *       CLASS lcl_rental IMPLEMENTATION
  194. *---------------------------------------------------------------------*
  195. *
  196. *---------------------------------------------------------------------*
  197. CLASS lcl_rental IMPLEMENTATION.

  199.   METHOD lif_partners~display_partner.
  200.     display_attributes( ).
  201.   ENDMETHOD.                    "lif_partners~display_partner

  203.   METHOD  constructor.
  204.     name = im_name.
  205.   ENDMETHOD.                    "constructor

  207.   METHOD  add_vehicle.
  208.     APPEND im_vehicle TO vehicle_list.
  209.   ENDMETHOD.                    "add_vehicle

  211.   METHOD  display_attributes.
  212.     DATA: r_vehicle TYPE REF TO lcl_vehicle.
  213.     WRITE: /  icon_transport_proposal AS ICON, name.
  214.     WRITE:  ' Here comes the vehicle list: '.
  215.     ULINE.
  216.     ULINE.
  217.     LOOP AT vehicle_list INTO r_vehicle.
  218.       r_vehicle->display_attributes( ).
  219.     ENDLOOP.
  220.   ENDMETHOD.                    "display_attributes

  222. ENDCLASS.                    "lcl_rental IMPLEMENTATION
复制代码
INCLUDE ZBC10_EX_D_7.
  1. *&---------------------------------------------------------------------*
  2. *&  Include           ZBC10_EX_D_6
  3. *&---------------------------------------------------------------------*
  4. CLASS LCL_CARRIER DEFINITION.
  5.   PUBLIC SECTION.
  6.     METHODS:CONSTRUCTOR IMPORTING IM_NAME TYPE STRING.
  7.     METHODS:ADD_AIRPLANE IMPORTING IM_AIRPLANE TYPE REF TO LCL_AIRPLANE.
  8.     METHODS:DISPLAY_AIRPLANES.
  9.     METHODS:DISPLAY_ATTRIBUTES.
  10.     INTERFACES lif_partners.
  11.   PRIVATE SECTION.
  12.    DATA: NAME TYPE STRING,
  13.          AIRPLANE_LIST TYPE TABLE OF REF TO LCL_AIRPLANE.
  14. ENDCLASS.                    "lcl_CARRIER DEFINITION

  16. *----------------------------------------------------------------------*
  17. *       CLASS lcl_CARRIER IMPLEMENTATION
  18. *----------------------------------------------------------------------*
  19. *
  20. *----------------------------------------------------------------------*
  21. CLASS LCL_CARRIER IMPLEMENTATION.
  22.   METHOD CONSTRUCTOR.
  23.     NAME = IM_NAME.
  24.   ENDMETHOD.
  25.   METHOD ADD_AIRPLANE.
  26.     APPEND IM_AIRPLANE TO AIRPLANE_LIST.
  27.   ENDMETHOD.
  28.   METHOD DISPLAY_AIRPLANES.
  29.     DATA: R_AIRPLANE TYPE REF TO LCL_AIRPLANE.
  30.     LOOP AT AIRPLANE_LIST INTO R_AIRPLANE.
  31.        R_AIRPLANE->DISPLAY_ATTRIBUTES( ).
  32.     ENDLOOP.
  33.   ENDMETHOD.
  34.   METHOD DISPLAY_ATTRIBUTES.
  35.     WRITE: / NAME.
  36.     DISPLAY_AIRPLANES( ).
  37.   ENDMETHOD.
  38.   METHOD lif_partners~display_partner.
  39.     display_attributes( ).
  40.   ENDMETHOD.
  41. ENDCLASS.                    "lcl_CARRIER IMPLEMENTATION
复制代码
INCLUDE ZBC10_EX_F_7.
  1. *&---------------------------------------------------------------------*
  2. *&  Include           ZBC10_EX_F_7
  3. *&---------------------------------------------------------------------*
  4. *---------------------------------------------------------------------*
  5. *       CLASS lcl_travel_agency DEFINITION
  6. *---------------------------------------------------------------------*
  7. CLASS lcl_travel_agency DEFINITION.

  9.   PUBLIC SECTION.
  10.     "-------------------
  11.     METHODS:      constructor IMPORTING im_name TYPE string.
  12.     METHODS       add_partner IMPORTING IM_PARTNER TYPE REF TO LIF_PARTNERS.
  13.     METHODS       display_agency_partners.

  15.   PRIVATE SECTION.
  16.     "-------------------
  17.     DATA: name TYPE string.
  18.     DATA  partner_list TYPE TABLE OF REF TO LIF_PARTNERS.

  20. ENDCLASS.                    "lcl_travel_agency DEFINITION

  22. *---------------------------------------------------------------------*
  23. *       CLASS lcl_travel_agency IMPLEMENTATION
  24. *---------------------------------------------------------------------*
  25. CLASS lcl_travel_agency IMPLEMENTATION.

  27. METHOD display_agency_partners.
  28.    DATA: r_partner TYPE REF TO LIF_PARTNERS.
  29.    WRITE: icon_dependents AS ICON, name.
  30.    LOOP AT partner_list INTO r_partner.
  31.       r_partner->DISPLAY_PARTNER( ).
  32.    ENDLOOP.

  34. ENDMETHOD.                    "display_agency_partners

  36. METHOD  constructor.
  37.   name = im_name.
  38. ENDMETHOD.                    "constructor

  40. METHOD  add_partner.
  41.    APPEND IM_PARTNER TO partner_list.
  42. ENDMETHOD.                    "add_partner

  44. ENDCLASS.                    "lcl_travel_agency IMPLEMENTATION
复制代码
接口, 面向对象, 对象

相关帖子
回复

使用道具 举报

Twilight

管理员

+发表新主题
  1. 849 主题
  2. 125 回帖
  3. 11496 积分
发消息

Ta最近发表

快速回帖

本版积分规则
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册有礼

小黑屋|手机版|SAP顾问圈 ( 沪ICP备18020878号 )

GMT+8, 2025-4-21 02:36 , Processed in 0.058072 second(s), 9 queries , Gzip On, Redis On.

© 2014-2017 SAPclubDesign by Twilight.Liu®X3.5

平台客服 1204767879 无客服码

快速回复 返回顶部 返回列表