设为首页收藏本站站点任务
请登陆 注册有礼
二维码
网站快捷导航

[BDC] BDC的Session编程方式批处理上传数据

Twilight发表于 2015-01-21 17:34Twilight 最后回复于 2015-01-21 17:34 [复制链接] 4109 0

扩展阅读基础版：使用BDC的session编程方式导入数据

选择界面
  1. SELECTION-SCREEN BEGIN OF BLOCK b0 WITH FRAME TITLE text-t00.
  2. PARAMETERS: group(12) DEFAULT 'ZSCMLT',        "group name of session
  3.             user(12)  DEFAULT sy-uname,        "user for session in batch
  4.             once TYPE i DEFAULT 5000,          "每个Session处理的数据条数
  5.             keep AS CHECKBOX DEFAULT 'X',      "' ' = delete session if finished;'X' = keep   session if finished
  6.             smalllog AS CHECKBOX DEFAULT 'X',  "' ' = log all transactions ;'X' = no transaction logging
  7.             autorun AS CHECKBOX."是否自动运行生成的Session
  8. SELECTION-SCREEN END OF BLOCK b0.
复制代码

主要的FORM：
  1. *&---------------------------------------------------------------------*
  2. *&      Form  bdc
  3. *&---------------------------------------------------------------------*
  4. FORM bdc .
  5.   DATA: linenum  LIKE sy-tabix,
  6.         fromnum  LIKE sy-index,
  7.         tonum    LIKE sy-index.
  8.   DATA: n TYPE i ,
  9.         m LIKE sy-tabix.
  10.   DATA: listobject LIKE abaplist OCCURS 0.

  12.   SORT itab BY infnr.
  13.   DESCRIBE TABLE itab LINES linenum.
  14.   n = linenum DIV once.
  15.   n = n + 1.
  16.   DO n TIMES.
  17.     itab_once[] = itab[].
  18.     fromnum = sy-index * once + 1 .
  19.     DELETE itab_once FROM fromnum TO linenum.
  20.     IF sy-index > 1 .
  21.       tonum = fromnum - once - 1 .
  22.       DELETE itab_once FROM 1 TO tonum.
  23.     ENDIF.
  24.     PERFORM bdc_once USING sy-index.
  25.   ENDDO.
  26.   IF autorun = 'X'.
  27.     CONCATENATE group '*' INTO group_all .
  28.     SUBMIT rsbdcsub
  29.       WITH mappe EQ group_all
  30.       WITH z_verarb EQ 'X'
  31.       WITH fehler EQ ' '
  32.       WITH von = sy-datum
  33.       WITH bis = sy-datum
  34.       AND RETURN
  35.       EXPORTING LIST TO MEMORY.
  36.     CALL FUNCTION 'LIST_FROM_MEMORY'
  37.          TABLES
  38.               listobject = listobject
  39.          EXCEPTIONS
  40.               not_found  = 1
  41.               OTHERS     = 2.
  42.     SKIP 2.
  43.     WRITE '后台Job设置情况:'.
  44.     ULINE.
  45.     CALL FUNCTION 'WRITE_LIST'
  46.          TABLES
  47.               listobject = listobject
  48.          EXCEPTIONS
  49.               empty_list = 1
  50.               OTHERS     = 2.
  51.   ENDIF.
  52.   LEAVE TO SCREEN 300.
  53. ENDFORM .
  54. *---------------------------------------------------------------------*
  55. *       FORM bdc_once                                                 *
  56. *---------------------------------------------------------------------*
  57. FORM bdc_once USING index.
  58.   DATA: c(3) ,
  59.         group_tmp(12).
  60.   c = index.
  61.   CONDENSE c .
  62.   CONCATENATE group c INTO group_tmp.
  63. *  PERFORM open_group.
  64.   SKIP.
  65.   WRITE: /(20) 'Create group'(i01), group_tmp.
  66.   SKIP.
  67.   CALL FUNCTION 'BDC_OPEN_GROUP'
  68.        EXPORTING
  69.             client = sy-mandt
  70.             group  = group_tmp
  71.             user   = user
  72.             keep   = keep.
  73.   WRITE: /(30) 'BDC_OPEN_GROUP'(i02),
  74.           (12) 'returncode:'(i05),
  75.                sy-subrc.

  77.   LOOP AT itab_once .
  78.     CALL FUNCTION 'CONVERSION_EXIT_ALPHA_OUTPUT'
  79.          EXPORTING
  80.               input  = itab_once-matnr
  81.          IMPORTING
  82.               output = itab_once-matnr.
  83.     REFRESH bdcdata .
  84.     CLEAR bdcdata .
  85.     PERFORM bdc_dynpro  USING 'SAPMM06I'   '0100'.
  86.     PERFORM bdc_field   USING 'BDC_OKCODE' '/00'.
  87.     PERFORM bdc_field   USING 'EINA-INFNR' itab_once-infnr.
  88.     PERFORM bdc_field   USING 'EINA-LIFNR' itab_once-lifnr.
  89.     PERFORM bdc_field   USING 'EINA-MATNR' itab_once-matnr.
  90.     PERFORM bdc_field   USING 'EINE-EKORG' itab_once-ekorg.
  91.     PERFORM bdc_field   USING 'EINE-WERKS' itab_once-werks.
  92.     CASE itab_once-esokz .
  93.       WHEN '0'.
  94.         PERFORM bdc_field   USING 'RM06I-NORMB' 'X'.
  95.       WHEN '3'.
  96.         PERFORM bdc_field   USING 'RM06I-LOHNB' 'X'.
  97.       WHEN '2'.
  98.         PERFORM bdc_field   USING 'RM06I-KONSI' 'X'.
  99.       WHEN 'P'.
  100.         PERFORM bdc_field   USING 'RM06I-PIPEL' 'X'.
  101.     ENDCASE.
  102.     PERFORM bdc_dynpro  USING 'SAPMM06I'   '0101'.
  103.     PERFORM bdc_field   USING 'BDC_OKCODE' '=EINE'.
  104.     PERFORM bdc_dynpro  USING 'SAPMM06I'   '0102'.
  105.     PERFORM bdc_field   USING 'BDC_OKCODE' '=BU'.
  106.     PERFORM bdc_field   USING 'EINE-APLFZ' itab_once-apsum.

  108.     CALL FUNCTION 'BDC_INSERT'
  109.          EXPORTING
  110.               tcode     = 'ME12'
  111.          TABLES
  112.               dynprotab = bdcdata.
  113.     IF smalllog <> 'X'.
  114.       WRITE: / 'BDC_INSERT'(i03),
  115.                'ME12',
  116.                'returncode:'(i05),
  117.                sy-subrc,
  118.                'RECORD:',
  119.                sy-index.
  120.     ENDIF.
  121.   ENDLOOP.

  123. *  PERFORM close_group.
  124.   CALL FUNCTION 'BDC_CLOSE_GROUP'.
  125.   WRITE: /(30) 'BDC_CLOSE_GROUP'(i04),
  126.           (12) 'returncode:'(i05),
  127.                sy-subrc.
  128. ENDFORM.                    " bdc
  129. *---------------------------------------------------------------------*
  130. *       FORM bdc_field                                               *
  131. *---------------------------------------------------------------------*
  132. FORM bdc_field USING fnam fval.
  133.   CLEAR bdcdata.
  134.   bdcdata-fnam = fnam.
  135.   bdcdata-fval = fval.
  136.   CONDENSE bdcdata-fval.
  137.   APPEND bdcdata.
  138. ENDFORM.
  139. *---------------------------------------------------------------------*
  140. *       FORM BDC_DYNPRO                                               *
  141. *---------------------------------------------------------------------*
  142. FORM bdc_dynpro USING program dynpro.
  143.   CLEAR bdcdata.
  144.   bdcdata-program  = program.
  145.   bdcdata-dynpro   = dynpro.
  146.   bdcdata-dynbegin = 'X'.
  147.   APPEND bdcdata.
  148. ENDFORM.

  150. *&---------------------------------------------------------------------*
  151. *&      Module  STATUS_0300  OUTPUT
  152. *&---------------------------------------------------------------------*
  153. MODULE status_0300 OUTPUT.
  154.   DATA: n TYPE i VALUE 3.
  155.   DATA: len TYPE i .
  156.   LEAVE TO LIST-PROCESSING AND RETURN TO SCREEN 0.
  157.   SET PF-STATUS space.
  158.   SUPPRESS Dialog.
  159. ENDMODULE.                 " STATUS_0300  OUTPUT
复制代码
session, bdc, sm35

相关帖子
回复

使用道具 举报

Twilight

管理员

+发表新主题
  1. 846 主题
  2. 125 回帖
  3. 11239 积分
发消息

Ta最近发表

快速回帖

本版积分规则
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册有礼

小黑屋|手机版|SAP顾问圈 ( 沪ICP备18020878号 )

GMT+8, 2024-11-21 23:11 , Processed in 0.045112 second(s), 5 queries , Gzip On, Redis On.

© 2014-2017 SAPclubDesign by Twilight.Liu®X3.5

平台客服 1204767879 无客服码

快速回复 返回顶部 返回列表