二维码

[fmalv] FM ALV设置EDT_CLL_CB参数可使编辑字段值更新内表

Twilight发表于 2014-10-30 14:45glb1197531 最后回复于 2015-06-07 10:17 [复制链接] 12224 2

FM ALV在处理可编辑字段方面已经很强大了，所以平常很少用OO ALV来做。当然OO ALV凭借类、事件、方法有其更强大的功能，FM ALV底层实际也是基于OO ALV的。本文主要以REUSE_ALV_GRID_DISPLAY_LVC为例，演示可编辑字段处理的简单方法：

在REUSE_ALV_GRID_DISPLAY_LVC显示的ALV中，实现可编辑字段的新值自动更新到内表有一个前提：
REUSE_ALV_GRID_DISPLAY_LVC的输入参数中，有一个是：I_GRID_SETTINGS，其中的EDT_CLL_CB字段是可回调标识，需要设置EDT_CLL_CB = 'X'。

在此前提下，再按是否自定义STATUS区分：
（1）没有自定义STATUS，即使用标准的界面。
当为可编辑字段输入新值后，敲回车点击标准工具栏的按钮点击标准的保存按钮，都可以自动更新字段的新值到内表中；
（2）自定义STATUS，此时又区分2种情况：
（2.1）自定义按钮的功能码设置为&DATA_SAVE。当为可编辑字段输入新值后，点击此按钮，也可以自动更新字段的新值到内表中；
（2.2）自定义按钮的功能码不是&DATA_SAVE。当为可编辑字段输入新值后，点击此按钮，是不会自动更新字段的新值到内表中的。
其中，&DATA_SAVE是标准界面保存按钮的功能码。

对于（2.2）情况，可以在判断功能码时，调用方法CHECK_CHANGED_DATA，这样即可自动更新可编辑字段的新值到内表中。

以“FM ALV自定义小计文本”一文代码为例，设置“数量”字段为可编辑字段。
新建了状态ZSTATUS，保留标准保存按钮。
创建了按钮YES、NO，功能码分别是POPUP_1、POPUP_2。
这2个按钮和标准的保存按钮都是调用FORM：FRM_ALV_POPUP弹出另一个ALV窗口显示内表最新值。
这2个按钮的区别在于：按钮YES在调用FORM：FRM_ALV_POPUP之前，调用了方法CHECK_CHANGED_DATA；而按钮NO没有。

你可以尝试上述说的几种情况，对比当前界面内表与弹出的窗口内表（即更新后）的值。
对可编辑字段输入新值后：直接点击标准保存按钮按钮YES，内表更新了；点击按钮NO，内表没有更新。
所以自定义按钮时，建议把方法CHECK_CHANGED_DATA的调用移到判断功能码前。

程序代码：

REPORT ydamon_001 MESSAGE-ID oo.
*----------------------------------------------------------------------*
* Pools and Types
*----------------------------------------------------------------------*
TYPE-POOLS: slis,abap,vrm,icon,ole2.
TYPES: BEGIN OF struc_tab,
mblnr TYPE mseg-mblnr,
mjahr TYPE mseg-mjahr,
zeile TYPE mseg-zeile,
bwart TYPE mseg-bwart,
matnr TYPE mseg-matnr,
maktx TYPE makt-maktx,
dmbtr TYPE mseg-dmbtr,
menge TYPE mseg-menge,
bpmng TYPE mseg-bpmng,
meins TYPE mara-meins,
sum TYPE char50,
END OF struc_tab.
*----------------------------------------------------------------------*
* Work Area and Internal Table
*----------------------------------------------------------------------*
DATA: gs_layout TYPE lvc_s_layo,
gs_settings TYPE lvc_s_glay,
gt_sort TYPE lvc_t_sort,
gt_fieldcat TYPE lvc_t_fcat.
DATA: gs_tab TYPE struc_tab,
gt_tab TYPE TABLE OF struc_tab.
*----------------------------------------------------------------------*
* Ranges and Field Symbols
*----------------------------------------------------------------------*
FIELD-SYMBOLS: <fs_tab> TYPE struc_tab.
*----------------------------------------------------------------------*
* Class and Object
*----------------------------------------------------------------------*
DATA: grid TYPE REF TO cl_gui_alv_grid.
*----------------------------------------------------------------------*
* START-OF-SELECTION
*----------------------------------------------------------------------*
START-OF-SELECTION.
PERFORM frm_data_get.
PERFORM frm_data_process.
PERFORM frm_data_output.
*&---------------------------------------------------------------------*
*& FORM FRM_DATA_GET
*&---------------------------------------------------------------------*
FORM frm_data_get.
SELECT a~mblnr a~mjahr a~zeile a~bwart a~matnr a~dmbtr a~menge a~bpmng
b~maktx
FROM mseg AS a
INNER JOIN makt AS b ON b~matnr EQ a~matnr AND b~spras EQ sy-langu
UP TO 15 ROWS
INTO CORRESPONDING FIELDS OF TABLE gt_tab.
IF gt_tab IS INITIAL.
MESSAGE s000 DISPLAY LIKE 'E' WITH '没有符合条件的数据！'.
STOP.
ENDIF.
ENDFORM. "FRM_DATA_GET
*&---------------------------------------------------------------------*
*& FORM FRM_DATA_PROCESS
*&---------------------------------------------------------------------*
FORM frm_data_process.
LOOP AT gt_tab ASSIGNING <fs_tab>.
CONCATENATE <fs_tab>-maktx '-' <fs_tab>-bwart INTO <fs_tab>-sum.
ENDLOOP.
gs_tab-meins = 'EA'.
MODIFY gt_tab FROM gs_tab TRANSPORTING meins WHERE meins NE 'EA'.
CLEAR gs_tab.
ENDFORM. "FRM_DATA_PROCESS
*&---------------------------------------------------------------------*
*& FORM FRM_DATA_OUTPUT
*&---------------------------------------------------------------------*
FORM frm_data_output.
PERFORM frm_alv_init_layout.
PERFORM frm_alv_init_settings.
PERFORM frm_alv_sort_build.
PERFORM frm_alv_init_fieldcat.
PERFORM frm_alv_display.
ENDFORM. " FRM_DATA_OUTPUT
*&---------------------------------------------------------------------*
*& FORM FRM_ALV_INIT_LAYOUT
*&---------------------------------------------------------------------*
FORM frm_alv_init_layout.
gs_layout-zebra = 'X'.
gs_layout-sel_mode = 'D'.
gs_layout-cwidth_opt = 'X'.
gs_layout-detailinit = 'X'.
ENDFORM. " FRM_ALV_INIT_LAYOUT
*&---------------------------------------------------------------------*
*& FORM FRM_ALV_INIT_SETTINGS
*&---------------------------------------------------------------------*
FORM frm_alv_init_settings.
gs_settings-edt_cll_cb = 'X'.
ENDFORM. " FRM_ALV_INIT_SETTINGS
*&---------------------------------------------------------------------*
*& FORM FRM_ALV_SORT_BUILD
*&---------------------------------------------------------------------*
FORM frm_alv_sort_build.
DATA: ls_sort TYPE lvc_s_sort.
ls_sort-fieldname = 'MATNR'.
ls_sort-up = 'X'.
APPEND ls_sort TO gt_sort.
CLEAR ls_sort.
ls_sort-fieldname = 'MAKTX'.
ls_sort-up = 'X'.
APPEND ls_sort TO gt_sort.
CLEAR ls_sort.
ls_sort-fieldname = 'BWART'.
ls_sort-up = 'X'.
APPEND ls_sort TO gt_sort.
CLEAR ls_sort.
ls_sort-fieldname = 'SUM'.
ls_sort-up = 'X'.
ls_sort-subtot = 'X'.
APPEND ls_sort TO gt_sort.
CLEAR ls_sort.
ENDFORM. "FRM_ALV_SORT_BUILD
*&---------------------------------------------------------------------*
*& FORM FRM_ALV_INIT_FIELDCAT
*&---------------------------------------------------------------------*
FORM frm_alv_init_fieldcat.
DATA: ls_fieldcat TYPE lvc_s_fcat.
DEFINE mac_fill_fieldcat.
ls_fieldcat-fieldname = &1.
ls_fieldcat-coltext = &2.
ls_fieldcat-no_zero = &3.
ls_fieldcat-do_sum = &4.
ls_fieldcat-no_out = &5.
ls_fieldcat-ref_table = &6.
ls_fieldcat-ref_field = &7.
ls_fieldcat-decimals_o = &8.
ls_fieldcat-qfieldname = &9.
append ls_fieldcat to gt_fieldcat.
clear ls_fieldcat.
END-OF-DEFINITION.
mac_fill_fieldcat 'MBLNR' '物料凭证' '' '' '' '' '' '' ''.
mac_fill_fieldcat 'MJAHR' '凭证年度' '' '' '' '' '' '' ''.
mac_fill_fieldcat 'ZEILE' '行号' 'X' '' '' '' '' '' ''.
mac_fill_fieldcat 'BWART' '移动类型' '' '' '' '' '' '' ''.
mac_fill_fieldcat 'MATNR' '物料编码' 'X' '' '' 'MARA' 'MATNR' '' ''.
mac_fill_fieldcat 'MAKTX' '物料描述' '' '' '' '' '' '' ''.
mac_fill_fieldcat 'DMBTR' '金额' '' 'X' '' '' '' '' ''.
mac_fill_fieldcat 'MENGE' '数量' '' 'X' '' 'MSEG' 'MENGE' '0' 'MEINS'.
mac_fill_fieldcat 'BPMNG' '计算数量' '' 'X' '' 'MSEG' 'MENGE' '0' 'MEINS'.
mac_fill_fieldcat 'SUM' '小计：' '' '' 'X' '' '' '' ''.
mac_fill_fieldcat 'MEINS' '单位' '' '' 'X' '' '' '' ''.
ls_fieldcat-edit = 'X'.
MODIFY gt_fieldcat FROM ls_fieldcat TRANSPORTING edit
WHERE fieldname EQ 'MENGE'.
CLEAR ls_fieldcat.
ENDFORM. " FRM_ALV_INIT_FIELDCAT
*&---------------------------------------------------------------------*
*& FORM FRM_ALV_DISPLAY
*&---------------------------------------------------------------------*
FORM frm_alv_display.
CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY_LVC'
EXPORTING
i_callback_program = sy-repid
is_layout_lvc = gs_layout
i_grid_settings = gs_settings
it_sort_lvc = gt_sort
it_fieldcat_lvc = gt_fieldcat
i_save = 'U'
i_default = space
i_callback_pf_status_set = 'FRM_ALV_STATUS_SET'
i_callback_user_command = 'FRM_ALV_USER_COMMAND'
TABLES
t_outtab = gt_tab
EXCEPTIONS
program_error = 1
OTHERS = 2.
IF sy-subrc <> 0.
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.
ENDFORM. " FRM_ALV_DISPLAY
*&---------------------------------------------------------------------*
*& FORM FRM_ALV_STATUS_SET
*&---------------------------------------------------------------------*
FORM frm_alv_status_set USING pt_extab TYPE slis_t_extab.
SET PF-STATUS 'ZSTATUS' EXCLUDING pt_extab.
CHECK grid IS INITIAL.
CALL FUNCTION 'GET_GLOBALS_FROM_SLVC_FULLSCR'
IMPORTING
e_grid = grid.
ENDFORM. " FRM_ALV_STATUS_SET
*&---------------------------------------------------------------------*
*& FORM FRM_ALV_USER_COMMAND
*&---------------------------------------------------------------------*
FORM frm_alv_user_command USING pa_ucomm TYPE sy-ucomm
ps_selfield TYPE slis_selfield.
CASE pa_ucomm.
WHEN '&DATA_SAVE'.
PERFORM frm_alv_popup.
WHEN 'POPUP_1'.
CALL METHOD grid->check_changed_data.
PERFORM frm_alv_popup.
WHEN 'POPUP_2'.
PERFORM frm_alv_popup.
ENDCASE.
ENDFORM. " FRM_ALV_USER_COMMAND
*&---------------------------------------------------------------------*
*& FORM FRM_ALV_POPUP
*&---------------------------------------------------------------------*
FORM frm_alv_popup.
DATA: ls_fieldcat_sub TYPE slis_fieldcat_alv,
lt_fieldcat_sub TYPE slis_t_fieldcat_alv.
DEFINE mac_fill_fieldcat_sub.
ls_fieldcat_sub-fieldname = &1.
ls_fieldcat_sub-seltext_m = &2.
ls_fieldcat_sub-key = &3.
ls_fieldcat_sub-no_zero = &4.
ls_fieldcat_sub-no_out = &5.
ls_fieldcat_sub-ref_tabname = &6.
ls_fieldcat_sub-ref_fieldname = &7.
ls_fieldcat_sub-decimals_out = &8.
ls_fieldcat_sub-qfieldname = &9.
append ls_fieldcat_sub to lt_fieldcat_sub.
clear ls_fieldcat_sub.
END-OF-DEFINITION.
mac_fill_fieldcat_sub 'MBLNR' '物料凭证' '' '' '' '' '' '' ''.
mac_fill_fieldcat_sub 'MJAHR' '凭证年度' '' '' '' '' '' '' ''.
mac_fill_fieldcat_sub 'ZEILE' '行号' '' 'X' '' '' '' '' ''.
mac_fill_fieldcat_sub 'BWART' '移动类型' '' '' '' '' '' '' ''.
mac_fill_fieldcat_sub 'MATNR' '物料编码' '' 'X' '' 'MARA' 'MATNR' '' ''.
mac_fill_fieldcat_sub 'MAKTX' '物料描述' '' '' '' '' '' '' ''.
mac_fill_fieldcat_sub 'DMBTR' '金额' '' '' '' '' '' '' ''.
mac_fill_fieldcat_sub 'MENGE' '数量' '' '' '' 'MSEG' 'MENGE' '0' 'MEINS'.
mac_fill_fieldcat_sub 'BPMNG' '计算数量' '' '' '' 'MSEG' 'MENGE' '0' 'MEINS'.
mac_fill_fieldcat_sub 'MEINS' '单位' '' '' 'X' '' '' '' ''.
CALL FUNCTION 'REUSE_ALV_POPUP_TO_SELECT'
EXPORTING
i_callback_program = sy-repid
i_zebra = 'X'
i_screen_start_column = 10
i_screen_start_line = 1
i_screen_end_column = 135
i_screen_end_line = 15
i_tabname = '1'
it_fieldcat = lt_fieldcat_sub
i_callback_user_command = 'FRM_ALV_USER_COMMAND_POPUP'
TABLES
t_outtab = gt_tab
EXCEPTIONS
program_error = 1
OTHERS = 2.
ENDFORM. "FRM_ALV_POPUP
*&---------------------------------------------------------------------*
*& FORM FRM_ALV_USER_COMMAND_POPUP
*&---------------------------------------------------------------------*
FORM frm_alv_user_command_popup USING pa_ucomm TYPE sy-ucomm
pwa_selfield TYPE slis_selfield.
DATA: l_filename TYPE string,
l_path TYPE string,
l_fullpath TYPE string,
l_action TYPE i.
TYPES: BEGIN OF struc_table,
mblnr TYPE char20,
mjahr TYPE char20,
zeile TYPE char20,
bwart TYPE char20,
matnr TYPE char20,
maktx TYPE char20,
dmbtr TYPE char20,
menge TYPE char20,
bpmng TYPE char20,
END OF struc_table.
DATA: ls_tab TYPE struc_table,
lt_tab TYPE TABLE OF struc_table.
CASE pa_ucomm.
WHEN '&ETA'.
CLEAR pa_ucomm.
CALL METHOD cl_gui_frontend_services=>file_save_Dialog
EXPORTING
file_filter = 'Excel Files (*.xls,*.xlsx)|*.xls;*.xlsx'
CHANGING
filename = l_filename
path = l_path
fullpath = l_fullpath
user_action = l_action
EXCEPTIONS
cntl_error = 1
error_no_gui = 2
not_supported_by_gui = 39
OTHERS = 4.
IF sy-subrc <> 0.
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.
CHECK l_action EQ 0.
CLEAR ls_tab.
REFRESH lt_tab.
LOOP AT gt_tab ASSIGNING <fs_tab>.
MOVE-CORRESPONDING <fs_tab> TO ls_tab.
APPEND ls_tab TO lt_tab.
CLEAR ls_tab.
ENDLOOP.
ls_tab-mblnr = '物料凭证'.
ls_tab-mjahr = '凭证年度'.
ls_tab-zeile = '行号'.
ls_tab-bwart = '移动类型'.
ls_tab-matnr = '物料编码'.
ls_tab-maktx = '物料描述'.
ls_tab-dmbtr = '金额'.
ls_tab-menge = '数量'.
ls_tab-bpmng = '计算数量'.
INSERT ls_tab INTO lt_tab INDEX 1.
CLEAR ls_tab.
CALL METHOD cl_gui_frontend_services=>gui_download
EXPORTING
filename = l_fullpath
write_field_separator = 'X'
CHANGING
data_tab = lt_tab
EXCEPTIONS
file_write_error = 1
no_batch = 2
gui_refuse_filetransfer = 3
invalid_type = 4
no_authority = 5
unknown_error = 6
header_not_allowed = 7
separator_not_allowed = 8
filesize_not_allowed = 9
header_too_long = 10
dp_error_create = 11
dp_error_send = 12
dp_error_write = 13
unknown_dp_error = 14
access_denied = 15
dp_out_of_memory = 16
disk_full = 17
dp_timeout = 18
file_not_found = 19
dataprovider_exception = 20
control_flush_error = 21
not_supported_by_gui = 22
error_no_gui = 23
OTHERS = 24.
IF sy-subrc <> 0.
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.
ENDCASE.
ENDFORM. " FRM_ALV_USER_COMMAND_POPUP

复制代码

* 本程序保留了“REUSE_ALV_POPUP_TO_SELECT导出”一文中的导出功能。
程序执行初始界面
EDT_CLL_CB 1.png

EDT_CLL_CB 1.png

yes按钮调用oo的CHECK_CHANGED_DATA方法监听修改内容更新至内表
EDT_CLL_CB 2.png

EDT_CLL_CB 2.png

no按钮没有调用oo的CHECK_CHANGED_DATA方法，所以alv界面的值没有更新至内表，但我们也可以设置I_GRID_SETTINGS-EDT_CLL_CB = 'X'参数达到同样的效果
EDT_CLL_CB 3.png

EDT_CLL_CB 3.png

EDT_CLL_CB, alv, 修改, 保存

相关帖子

回复

使用道具举报

小懒

站长写的帖子倒还可以{:soso_e142:}

回复支持反对

使用道具举报

glb1197531

不设置I_GRID_SETTINGS-EDT_CLL_CB，只调用oo的CHECK_CHANGED_DATA方法，应该也可以实现

回复支持反对

使用道具举报

Twilight

管理员

+发表新主题

847 主题
125 回帖
11270 积分

发消息

Ta最近发表

快速回帖

本版积分规则

快速回复 返回顶部 返回列表