设为首页收藏本站站点任务
请登陆 注册有礼
二维码
网站快捷导航

商品批量调拨，通过bapi将execl上传到sap系统

Twilight发表于 2014-02-06 21:00Twilight 最后回复于 2014-02-06 21:00 [复制链接] 3252 0

在业务中经常存在仓库或门店间相互调入调出、服装换款（剪标改唛）的需求，我们称其为商品调拨。在现在的企业信息化处理中，很多直接通过系统间的接口来实现商品调拨数据的传递，也可能有部分企业存在通过数据文件（如Excel）进行批量导入的方式
商品调拨可能是公司间的、仓库间的调拨，根据移动类型进行区分。需要的数据包括调出和调入的工厂、库位、商品编码、数量（基本单位）等

执行结果：
excel_upload.jpg
最后两列 显示bapi创建成功的凭证号码和时间，不成功不显示

主程序代码：
  1. *--------------------------------------------------------------------*
  2. *DEFINE TYPE POOL
  3. *--------------------------------------------------------------------*
  4. TYPE-POOLS:SLIS,TRUXS.

  6. *--------------------------------------------------------------------*
  7. *DEFINE TABLES
  8. *--------------------------------------------------------------------*
  9. *TABLES:

  11. *--------------------------------------------------------------------*
  12. *DEFINE CONSTANTS
  13. *--------------------------------------------------------------------*
  14. CONSTANTS: CO_BWART_STOCK_TRANS TYPE MSEG-BWART VALUE '311',
  15.            "Movement Type (Inventory Management)
  16.            CO_MAT_DOC_LINES TYPE I VALUE 2."批次过账的行数

  18. *--------------------------------------------------------------------*
  19. *DEFINE INTERNAL TABLES & VARIANTS
  20. *--------------------------------------------------------------------*
  21. DATA:BEGIN OF IT_FDAT OCCURS 0,
  22.         WERKS LIKE ZMM_STOCK_TRANS-WERKS,
  23.         LGORT LIKE ZMM_STOCK_TRANS-LGORT,
  24.         UMLGO LIKE ZMM_STOCK_TRANS-UMLGO,
  25.         MATNR LIKE ZMM_STOCK_TRANS-MATNR,
  26.         MENGE TYPE CHAR20,
  27.         MEINS LIKE ZMM_STOCK_TRANS-MEINS,
  28.      END OF IT_FDAT.
  29. DATA:IT_DATA TYPE ZMM_STOCK_TRANS OCCURS 0 WITH HEADER LINE.

  31. *--------------------------------------------------------------------*
  32. *DEFINE RANGES
  33. *--------------------------------------------------------------------*

  35. *--------------------------------------------------------------------*
  36. *PARAMETERS
  37. *--------------------------------------------------------------------*
  38. SELECTION-SCREEN BEGIN OF BLOCK BLK_010 WITH FRAME TITLE TEXT-001.
  39. PARAMETERS:
  40. P_BLDAT LIKE MKPF-BLDAT OBLIGATORY DEFAULT SY-DATUM,
  41. P_BUDAT LIKE MKPF-BUDAT OBLIGATORY DEFAULT SY-DATUM.
  42. PARAMETERS:
  43. P_FILE LIKE RLGRAP-FILENAME OBLIGATORY.
  44. SELECTION-SCREEN END OF BLOCK BLK_010.

  46. *--------------------------------------------------------------------*
  47. *INITIALIZATION
  48. *--------------------------------------------------------------------*
  49. INITIALIZATION.
  50.   PERFORM INIT_PARAMETERS.

  52. *--------------------------------------------------------------------*
  53. *AT SELECTION-SCREEN OUTPUT
  54. *--------------------------------------------------------------------*
  55. AT SELECTION-SCREEN OUTPUT.

  57. *--------------------------------------------------------------------*
  58. *AT SELECTION-SCREEN
  59. *--------------------------------------------------------------------*
  60. AT SELECTION-SCREEN.

  62. *--------------------------------------------------------------------*
  63. *AT SELECTION-SCREEN ON VALUE-REQUEST
  64. *--------------------------------------------------------------------*
  65. AT SELECTION-SCREEN ON VALUE-REQUEST FOR P_FILE.
  66.   CALL FUNCTION 'KD_GET_FILENAME_ON_F4'
  67.    EXPORTING
  68. *     PROGRAM_NAME        = SYST-REPID
  69. *     DYNPRO_NUMBER       = SYST-DYNNR
  70. *     FIELD_NAME          = ' '
  71.      STATIC              = 'X'
  72. *     MASK                = ' '
  73. *     FILEOPERATION       = 'R'
  74. *     PATH                =
  75.     CHANGING
  76.       FILE_NAME           = P_FILE
  77. *     LOCATION_FLAG       = 'P'
  78. *   EXCEPTIONS
  79. *     MASK_TOO_LONG       = 1
  80. *     OTHERS              = 2
  81.             .
  82.   IF SY-SUBRC <> 0.
  83. * Implement suitable error handling here
  84.   ENDIF.


  87. *--------------------------------------------------------------------*
  88. *AT SELECTION-SCREEN ON HELP-REQUEST
  89. *--------------------------------------------------------------------*

  91. *--------------------------------------------------------------------*
  92. *START-OF-SELECTION
  93. *--------------------------------------------------------------------*
  94. START-OF-SELECTION.
  95.   PERFORM PARAMETERS_CHECK.
  96.   PERFORM GET_DATA.

  98. *--------------------------------------------------------------------*
  99. *END-OF-SELECTION
  100. *--------------------------------------------------------------------*
  101. END-OF-SELECTION.
  102.   PERFORM POST_DATA.
  103.   PERFORM DIAPLAY_DATA.

  105. *&---------------------------------------------------------------------*
  106. *&      Form  INIT_PARAMETERS
  107. *&---------------------------------------------------------------------*
  108. FORM INIT_PARAMETERS .

  110. ENDFORM.                    " INIT_PARAMETERS
  111. *&---------------------------------------------------------------------*
  112. *&      Form  PARAMETERS_CHECK
  113. *&---------------------------------------------------------------------*
  114. FORM PARAMETERS_CHECK .
  115.   DATA: LV_FILE TYPE STRING,
  116.         LV_EXIST TYPE ABAP_BOOL.
  117.   LV_FILE = P_FILE.
  118.   "Checks if a File Exists  检查文件是否存在
  119.   CALL METHOD CL_GUI_FRONTEND_SERVICES=>FILE_EXIST
  120.     EXPORTING
  121.       FILE                 = LV_FILE
  122.     RECEIVING
  123.       RESULT               = LV_EXIST
  124.     EXCEPTIONS
  125.       CNTL_ERROR           = 1
  126.       ERROR_NO_GUI         = 2
  127.       WRONG_PARAMETER      = 3
  128.       NOT_SUPPORTED_BY_GUI = 4
  129.       OTHERS               = 5.
  130.   IF SY-SUBRC <> 0.
  131.     MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
  132.             WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  133.     LEAVE LIST-PROCESSING.
  134.   ELSEIF LV_EXIST = ABAP_FALSE.
  135.     MESSAGE S001(00) WITH '文件：' LV_FILE '不存在'.
  136.     LEAVE LIST-PROCESSING.
  137.   ENDIF.

  139. ENDFORM.                    " PARAMETERS_CHECK
  140. *&---------------------------------------------------------------------*
  141. *&      Form  GET_DATA
  142. *&---------------------------------------------------------------------*
  143. FORM GET_DATA .
  144.   DATA: IT_RAW_DATA TYPE TRUXS_T_TEXT_DATA,
  145.         LV_OUTPUT LIKE IT_FDAT-MENGE.
  146.   REFRESH: IT_FDAT,IT_DATA.
  147.   "ALSM_EXCEL_TO_INTERNAL_TABLE 需要用at end of整理内表数据格式
  148.   "“TEXT_CONVERT_XLS_TO_SAP”。这个函数直接可以把execl的内容
  149.   "原原本本的写入到内表，不用格式转化那么麻烦。
  150.   CALL FUNCTION 'TEXT_CONVERT_XLS_TO_SAP'
  151.     EXPORTING
  152. *   I_FIELD_SEPERATOR          =
  153.       I_LINE_HEADER              = 'X'"去掉模板第一行标题头部
  154.       I_TAB_RAW_DATA             = IT_RAW_DATA
  155.       I_FILENAME                 = P_FILE
  156.     TABLES
  157.       I_TAB_CONVERTED_DATA       = IT_FDAT[]
  158. * EXCEPTIONS
  159. *   CONVERSION_FAILED          = 1
  160. *   OTHERS                     = 2
  161.             .
  162.   IF SY-SUBRC <> 0.
  163.     MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
  164.             WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  165.   ENDIF.

  167.   IF IT_FDAT[] IS INITIAL.
  168.     MESSAGE S001(00) WITH '文件中没有数据'(001).
  169.     LEAVE LIST-PROCESSING.
  170.   ENDIF.

  172.   LOOP AT IT_FDAT.
  173.     CLEAR IT_DATA.
  174.     IT_DATA-TABIX = SY-TABIX.
  175.     IT_DATA-WERKS = IT_FDAT-WERKS.
  176.     IT_DATA-LGORT = IT_FDAT-LGORT.
  177.     IT_DATA-UMLGO = IT_FDAT-UMLGO.
  178.     CALL FUNCTION 'CONVERSION_EXIT_MATN1_INPUT' "料号前面补0
  179.       EXPORTING
  180.         INPUT              = IT_FDAT-MATNR
  181.       IMPORTING
  182.         OUTPUT             = IT_DATA-MATNR
  183. *   EXCEPTIONS
  184. *     LENGTH_ERROR       = 1
  185. *     OTHERS             = 2
  186.               .
  187.     CALL FUNCTION 'CATS_NUMERIC_INPUT_CHECK'"检查字段值是否为数值
  188.       EXPORTING
  189.         INPUT            = IT_FDAT-MENGE
  190. *        INTERNAL         = 'X'
  191.        IMPORTING
  192.          OUTPUT           = LV_OUTPUT
  193.    EXCEPTIONS
  194.      NO_NUMERIC       = 1
  195.      OTHERS           = 2
  196.               .
  197.     IF SY-SUBRC <> 0.
  198.       MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
  199.               WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  200.     ELSE.
  201.       IT_DATA-MENGE = LV_OUTPUT.
  202.     ENDIF.
  203.     CALL FUNCTION 'CONVERSION_EXIT_CUNIT_INPUT' "外部单位转换成内部单位
  204.       EXPORTING
  205.         INPUT                = IT_FDAT-MEINS
  206. *       LANGUAGE             = SY-LANGU
  207.      IMPORTING
  208.        OUTPUT               = IT_DATA-MEINS
  209. *     EXCEPTIONS
  210. *       UNIT_NOT_FOUND       = 1
  211. *       OTHERS               = 2
  212.               .
  213.     APPEND IT_DATA.
  214.   ENDLOOP.
  215. ENDFORM.                    " GET_DATA
  216. *&---------------------------------------------------------------------*
  217. *&      Form  POST_DATA
  218. *&---------------------------------------------------------------------*
  219. FORM POST_DATA .
  220.   DATA:IT_DATA_PST LIKE TABLE OF IT_DATA,
  221.        IS_DATA_PST LIKE LINE OF IT_DATA_PST,
  222.        LV_TAB_LINES TYPE SY-TABIX,
  223.        LV_TAB_IDXFM TYPE SY-TABIX,
  224.        LV_TAB_IDXTO TYPE SY-TABIX.
  225. DATA:GOODSMVT_HEADER LIKE TABLE OF BAPI2017_GM_HEAD_01 WITH HEADER LINE,
  226.      GOODSMVT_CODE LIKE BAPI2017_GM_CODE,
  227.      GOODSMVT_ITEM LIKE TABLE OF BAPI2017_GM_ITEM_CREATE
  228.      WITH HEADER LINE,
  229.      GOODSMVT_HEADRET LIKE BAPI2017_GM_HEAD_RET,
  230.      RETURN LIKE TABLE OF BAPIRET2 WITH HEADER LINE.

  232.   DESCRIBE TABLE IT_DATA LINES LV_TAB_LINES.
  233.   DO."没指定times 无限循环  通过下面的条件exit退出循环的
  234.     CLEAR:GOODSMVT_HEADER,GOODSMVT_CODE,GOODSMVT_ITEM[],
  235.           GOODSMVT_HEADRET,RETURN[],IT_DATA_PST.
  236.     LV_TAB_IDXFM = CO_MAT_DOC_LINES * ( SY-INDEX - 1 ) + 1.
  237.     IF LV_TAB_IDXFM > LV_TAB_LINES.
  238.       EXIT.
  239.     ENDIF.
  240.     LV_TAB_IDXTO = CO_MAT_DOC_LINES * SY-INDEX.
  241.     IF LV_TAB_IDXTO > LV_TAB_LINES.
  242.       LV_TAB_IDXTO = LV_TAB_LINES.
  243.     ENDIF.
  244.     "批次处理的范围控制
  245.     APPEND LINES OF IT_DATA FROM LV_TAB_IDXFM TO LV_TAB_IDXTO
  246.                                               TO IT_DATA_PST.
  247.     GOODSMVT_HEADER-PSTNG_DATE = P_BUDAT.
  248.     GOODSMVT_HEADER-DOC_DATE = P_BLDAT.
  249.     GOODSMVT_CODE = '06'.
  250.     LOOP AT IT_DATA_PST INTO IS_DATA_PST.
  251.       CLEAR:GOODSMVT_ITEM.
  252.       GOODSMVT_ITEM-MATERIAL = IS_DATA_PST-MATNR.
  253.       GOODSMVT_ITEM-PLANT = IS_DATA_PST-WERKS.
  254.       GOODSMVT_ITEM-STGE_LOC = IS_DATA_PST-LGORT.
  255.       GOODSMVT_ITEM-MOVE_TYPE = CO_BWART_STOCK_TRANS.
  256.       GOODSMVT_ITEM-MOVE_PLANT = IS_DATA_PST-WERKS.
  257.       GOODSMVT_ITEM-MOVE_STLOC = IS_DATA_PST-UMLGO.
  258.       GOODSMVT_ITEM-ENTRY_QNT = IS_DATA_PST-MENGE.
  259.       GOODSMVT_ITEM-ENTRY_UOM = IS_DATA_PST-MEINS.
  260.       APPEND GOODSMVT_ITEM.
  261.     ENDLOOP.
  262. *BAPI_GOODSMVT_CREATE*的功能就是用于货物移动，其主要可以实现MB*
  263. *事物的一些功能，其中该BAPI的参数
  264. *GOODSMVT_CODE就控制了对应哪个事物码的功能，
  265. *下面给出该参数的值和对应的事务码：
  266. *01 MB01
  267. *02 MB31
  268. *03 MB1A
  269. *04 MB1B
  270. *05 MB1C
  271. *06 MB11
  272. *07 MB04
  273. *
  274. *这些值存储在表T158G中。
  275.     CALL FUNCTION 'BAPI_GOODSMVT_CREATE'
  276.       EXPORTING
  277.         GOODSMVT_HEADER         = GOODSMVT_HEADER
  278.         GOODSMVT_CODE           = GOODSMVT_CODE
  279. *       TESTRUN                 = ' '
  280. *       GOODSMVT_REF_EWM        =
  281.       IMPORTING"Material Document Number/Material Document Year
  282.         GOODSMVT_HEADRET        = GOODSMVT_HEADRET"bapi创建成功传出的凭证号
  283. *       MATERIALDOCUMENT        =
  284. *       MATDOCUMENTYEAR         =
  285.       TABLES
  286.         GOODSMVT_ITEM           = GOODSMVT_ITEM
  287. *       GOODSMVT_SERIALNUMBER   =
  288.         RETURN                  = RETURN
  289. *       GOODSMVT_SERV_PART_DATA =
  290. *       EXTENSIONIN             =
  291.       .

  293.     READ TABLE RETURN WITH KEY TYPE = 'E'.
  294.     IF SY-SUBRC = 0 OR GOODSMVT_HEADRET-MAT_DOC IS INITIAL.
  295.       CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK'
  296. *       IMPORTING
  297. *         RETURN        =
  298.                 .
  299.     ELSE.
  300.       CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
  301.        EXPORTING
  302.          WAIT          = 'X'
  303. *     IMPORTING
  304. *       RETURN        =
  305.                 .
  306.       CLEAR IT_DATA.
  307.       IT_DATA-MBLNR = GOODSMVT_HEADRET-MAT_DOC.
  308.       IT_DATA-MJAHR = GOODSMVT_HEADRET-DOC_YEAR.
  309.       MODIFY IT_DATA TRANSPORTING MBLNR MJAHR
  310.              WHERE TABIX >= LV_TAB_IDXFM AND TABIX <= LV_TAB_IDXTO.
  311.     ENDIF.

  313.   ENDDO.
  314. ENDFORM.                    " POST_DATA
  315. *&---------------------------------------------------------------------*
  316. *&      Form  DIAPLAY_DATA
  317. *&---------------------------------------------------------------------*
  318. FORM DIAPLAY_DATA .
  319.   DATA:LV_TITLE TYPE LVC_TITLE,
  320.        LS_LAYOUT TYPE SLIS_LAYOUT_ALV.
  321.   LS_LAYOUT-ZEBRA = 'X'.
  322.   LS_LAYOUT-COLWIDTH_OPTIMIZE = 'X'.

  324.   CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
  325.    EXPORTING
  326.    I_STRUCTURE_NAME                  = 'ZMM_STOCK_TRANS'
  327. *   I_BACKGROUND_ID                   = ' '
  328.      I_GRID_TITLE                      = LV_TITLE
  329. *   I_GRID_SETTINGS                   =
  330.      IS_LAYOUT                         = LS_LAYOUT
  331.     TABLES
  332.       T_OUTTAB                          = IT_DATA
  333. * EXCEPTIONS
  334. *   PROGRAM_ERROR                     = 1
  335. *   OTHERS                            = 2
  336.             .
  337. ENDFORM.                    " DIAPLAY_DATA
复制代码


定义结构
stock transfer.jpg

测试excel附件 导入文件.zip (7.26 KB, 下载次数: 1, 售价: 2 枚金币)
接口, 企业信息化, sap系统, Excel, 仓库

相关帖子
回复

使用道具 举报

Twilight

管理员

+发表新主题
  1. 847 主题
  2. 125 回帖
  3. 11270 积分
发消息

Ta最近发表

快速回帖

本版积分规则
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册有礼

小黑屋|手机版|SAP顾问圈 ( 沪ICP备18020878号 )

GMT+8, 2024-12-23 07:17 , Processed in 0.057356 second(s), 10 queries , Gzip On, Redis On.

© 2014-2017 SAPclubDesign by Twilight.Liu®X3.5

平台客服 1204767879 无客服码

快速回复 返回顶部 返回列表