数据库表行记录层级锁定

通常某人通过表格维护生成器维护一个表时，其他人则不能同时在维护这张表，因为sap默认的是表层级的锁定。这里教大家一种方法实现表行记录层级的锁定，可以实现多人同时维护这张表，但不能同时修改同一条记录。

1、se11创建表YTEST_SHUKS3

2、为表创建表格维护生成器（菜单：实用程序->表格维护生成器）

PS:这里的屏幕编号是点击系统自动建议的应为2，不是1，截图错了，你的可能与这里的不一致
点击创建，表格维护代码自动生成，保存在function group(YFMG_LEON，可以se80创建并激活)中
3、创建锁对象EYTEST_SHUKS3

锁一定要有E开头，如果是我们自定义的锁，通常用EZ或EY开头

name:需要加锁的表名
lock mode：
1）S (Shared lock, read lock) 共享锁——只读锁，一个用户正在读数据时，阻止其他用户更改该数据；该模式允许 多个用户访问指定表行,但只能读访问.任何时候都不允许写访问
2）E (Exclusive lock, write lock) 排他锁（独占锁）——可写锁，一个用户正在修改数据时，阻止其他用户更改该数据；只有自己可以读、写
3）X (eXclusive lock, extended write lock, cannot be cumulated) 排他但不累计，只有自己可以读、写，并且一个事务只能使用一次
如果我们使用一般情况下，E就可以了。
    如果你在一个程序里成功对一个锁对象加锁之后，如果模式为E，其他用户不能再对这个锁对象加E、X、S模式的任意一种锁；
    如果你在一个程序里成功对一个锁对象加锁之后，如果模式为X，其他用户不能再对这个锁对象加E、X、S模式的任意一种锁；
    如果你在一个程序里成功对一个锁对象加锁之后，如果模式为S，其他用户不能再对这个锁对象加E、X模式的锁，但是可以加S模式的锁；
    如果你在一个程序里成功对一个锁对象加锁之后，如果模式为E，在这个程序，你还可以再对这个锁对象加E、S模式的锁，X模式的不可以。
    如果你在一个程序里成功对一个锁对象加锁之后，如果模式为X，在这个程序，你不可以再对这个锁对象加E、X、S模式的锁。
    如果你在一个程序里成功对一个锁对象加锁之后，如果模式为S，在这个程序，你还可以再对这个锁对象加S模式的锁，如果没有别的用户对其加S模式的锁，那么你还可以对其加E模式的锁。X模式的不可以。

保存并激活lock，系统会自动创建两个FM，ENQUEUE_<锁对象名>和DEQUEUE_<锁对象名>，分别用来锁定和解锁
ENQUEUE_EYTEST_SHUKS3 加锁
DEQUEUE_EYTEST_SHUKS3 解锁
4、新建程序YDAMON_077和t-code:YTEST_SHUKS3(program and selection screen)
程序代码：

1. **Selection range for view maintenance
   
2. DATA:BEGIN OF selekttab OCCURS 1.         "Selektionsbereich
   
3.         INCLUDE STRUCTURE vimsellist.
   
4. DATA: END OF selekttab,
   
5. 
   
6. **Table of inactive CUA functions for view maintenance
   
7. BEGIN OF excl_cua_funct OCCURS 1.    "inaktive CUA-Fkt bei View-Pflege
   
8.         INCLUDE STRUCTURE vimexclfun.
   
9. DATA: END OF excl_cua_funct.
   
10. 
    
11. DATA:lt_enq_del TYPE STANDARD TABLE OF seqg3,
    
12.      lt_enq_read TYPE STANDARD TABLE OF seqg7,
    
13.      lw_enq_read TYPE seqg7,
    
14.      lw_enq_del TYPE seqg3,
    
15.      lv_subrc TYPE sy-subrc.
    
16. 
    
17. *Read all the lock details in system  
    
18. CALL FUNCTION 'ENQUE_READ2'
    
19.   EXPORTING
    
20.     gclient = sy-mandt
    
21.     gname   = ' '
    
22.     guname  = '*'
    
23.   TABLES
    
24.     enq     = lt_enq_read.
    
25. 
    
26. *We will search entry for table level lock for our table
    
27. LOOP AT lt_enq_read INTO lw_enq_read
    
28.   WHERE gname EQ 'RSTABLE'
    
29.   AND   garg CS 'YTEST_SHUKS3'.
    
30.   MOVE-CORRESPONDING lw_enq_read TO lw_enq_del.
    
31.   APPEND lw_enq_del TO lt_enq_del.
    
32. ENDLOOP.
    
33. 
    
34. *Delete table level lock entry for our table 可以用sm12查看被锁的记录，这里是删除锁对象
    
35. CALL FUNCTION 'ENQUE_DELETE'
    
36.   EXPORTING
    
37.     check_upd_requests = 1
    
38.   IMPORTING
    
39.     subrc              = lv_subrc
    
40.   TABLES
    
41.     enq                = lt_enq_del.
    
42. 
    
43. *Now call the table maintenace generator.
    
44. CALL FUNCTION 'VIEW_MAINTENANCE_CALL'
    
45.   EXPORTING
    
46.     action               = 'U'
    
47.     view_name            = 'YTEST_SHUKS3'
    
48.     show_selection_popup = 'X'
    
49.   TABLES
    
50.     dba_sellist          = selekttab
    
51.     excl_cua_funct       = excl_cua_funct.

复制代码

5、se80 打开function group（YFMG_LEON），对002屏幕增强，即在PBO里添加MODULE m_change_locking.

双击module名称，添加到一个include里，这个include可以自己新建，代码：

1. *Call the function module corresponding to the lock object we created
   
2.   CALL FUNCTION 'ENQUEUE_EYTEST_SHUKS3'
   
3.     EXPORTING
   
4.       matnr          = ytest_shuks3-matnr
   
5.       werks          = ytest_shuks3-werks
   
6.     EXCEPTIONS
   
7.       foreign_lock   = 1
   
8.       system_failure = 2
   
9.       OTHERS         = 3.
   
10.   IF sy-subrc NE 0.
    
11. * row is locked..hence gray.. 因为上面把锁对象删除了 这里加锁不成功，会修改屏幕成不可输状态
    
12.     LOOP AT SCREEN.
    
13.       screen-input = 0.
    
14.       MODIFY SCREEN.
    
15.     ENDLOOP.
    
16.   ENDIF.

复制代码

6、输入自定义t-code，添加几条记录

7、测试结果
打开1个session，输入t-code：YTEST_SHUKS3




打开另1个session，输入t-code：YTEST_SHUKS3，条件全选，默认所有记录


PS:sm12解锁