设为首页收藏本站站点任务
请登陆 注册有礼
二维码
网站快捷导航

[ooalv] 在alv用class方式添加PF-Status, Header and Footer

Twilight发表于 2014-08-26 19:32Twilight 最后回复于 2014-08-26 19:32 [复制链接] 4319 0

以前我们开发ALV是用slis类型池 或者Cl_GUI_ALV_GRID的class方式，在这篇帖子里我们使用CL_SALV 类的方式实现

程序代码：
  1. *----------------------------------------------------------------------*
  2. *       CLASS lcl_report DEFINITION
  3. *----------------------------------------------------------------------*
  4. *
  5. *----------------------------------------------------------------------*
  6. CLASS LCL_REPORT DEFINITION.
  7.   PUBLIC SECTION.
  8. *----------------------------------------------------------------------*
  9. * Final Output Table
  10. *----------------------------------------------------------------------*
  11.     TYPES: BEGIN OF TY_MARA,
  12.             MATNR TYPE MATNR,
  13.             ERSDA TYPE ERSDA,
  14.             MATKL TYPE MATKL,
  15.             MTART TYPE MTART,
  16.             LVORM TYPE LVORM,
  17.            END OF TY_MARA.
  18.     DATA: O_ALV TYPE REF TO CL_SALV_TABLE,              " ALV Reference
  19.           T_MARA TYPE STANDARD TABLE OF TY_MARA.
  20. *----------------------------------------------------------------------*
  21. * Methods to Fetch Data and Generate Output
  22. *----------------------------------------------------------------------*
  23.     METHODS: GET_DATA,                                  "Data Selection
  24.              GENERATE_OUTPUT.                           "Generating Output
  25.   PRIVATE SECTION.
  26. *----------------------------------------------------------------------*
  27. * Methods to Set PF-Status, Header and Footer
  28. *----------------------------------------------------------------------*
  29.     METHODS: SET_PF_STATUS
  30.                   CHANGING
  31.                       CO_ALV TYPE REF TO CL_SALV_TABLE, " Default Pf Status
  32.              SET_TOP_OF_PAGE
  33.                   CHANGING
  34.                       CO_ALV TYPE REF TO CL_SALV_TABLE, " Set Top of page
  35.              SET_END_OF_PAGE
  36.                   CHANGING
  37.                       CO_ALV TYPE REF TO CL_SALV_TABLE. " Set End of page
  38. ENDCLASS.                    "lcl_report DEFINITION
  39. *----------------------------------------------------------------------*
  40. *       CLASS lcl_report IMPLEMENTATION
  41. *----------------------------------------------------------------------*
  42. *
  43. *----------------------------------------------------------------------*
  44. CLASS LCL_REPORT IMPLEMENTATION.
  45. *----------------------------------------------------------------------*
  46. * Data selection
  47. *----------------------------------------------------------------------*
  48.   METHOD GET_DATA.
  49.     SELECT MATNR ERSDA MATKL MTART LVORM INTO TABLE T_MARA
  50.            FROM MARA UP TO 20 ROWS.
  51.   ENDMETHOD.                    "get_data
  52. *----------------------------------------------------------------------*
  53. * Generating Output
  54. *----------------------------------------------------------------------*
  55.   METHOD GENERATE_OUTPUT.
  56. *Exception Class
  57.     DATA: LC_MSG TYPE REF TO CX_SALV_MSG.
  58. *----------------------------------------------------------------------*
  59. * We are calling the static Factory method which will give back
  60. * the ALV object reference.
  61. *----------------------------------------------------------------------*
  62.     TRY.
  63.         CALL METHOD CL_SALV_TABLE=>FACTORY
  64.           IMPORTING
  65.             R_SALV_TABLE = O_ALV
  66.           CHANGING
  67.             T_TABLE      = T_MARA.
  68.       CATCH CX_SALV_MSG INTO LC_MSG .
  69.     ENDTRY.
  70. ************************************************************************
  71. * In this area we will call the methods which will set the
  72. * different properties to the ALV
  73. ************************************************************************
  74. * Calling Set PF status method
  75.     CALL METHOD SET_PF_STATUS
  76.       CHANGING
  77.         CO_ALV = O_ALV.       "set_end_of_page
  78. * Calling the top of page method
  79.     CALL METHOD SET_TOP_OF_PAGE
  80.       CHANGING
  81.         CO_ALV = O_ALV.
  82. * Calling the End of page method
  83.     CALL METHOD SET_END_OF_PAGE
  84.       CHANGING
  85.         CO_ALV = O_ALV.
  86. ************************************************************************
  87. * Displaying the ALV
  88. * Here we will call the DISPLAY method to get the output on the screen
  89. ************************************************************************
  90.     O_ALV->DISPLAY( ).
  91.   ENDMETHOD.                    "generate_output
  92. ************************************************************************
  93. *    In this area we will implement the methods which are defined in
  94. *    the class definition
  95. ************************************************************************
  96. * Setting Default PF-Status
  97.   METHOD SET_PF_STATUS.
  98.     DATA: LO_FUNCTIONS TYPE REF TO CL_SALV_FUNCTIONS_LIST.
  99. * Default functions
  100.     LO_FUNCTIONS = CO_ALV->GET_FUNCTIONS( ).
  101.     LO_FUNCTIONS->SET_DEFAULT( ABAP_TRUE ).
  102.   ENDMETHOD.                    "set_pf_status

  104. * Setting Top_of_page
  105.   METHOD SET_TOP_OF_PAGE.
  106.     DATA: LO_HEADER TYPE REF TO CL_SALV_FORM_LAYOUT_GRID,
  107.           LO_H_LABEL TYPE REF TO CL_SALV_FORM_LABEL,
  108.           LO_H_FLOW  TYPE REF TO CL_SALV_FORM_LAYOUT_FLOW.
  109. * Header object
  110.     CREATE OBJECT LO_HEADER.
  111. *----------------------------------------------------------------------*
  112. * To create a Label or Flow we have to specify the target
  113. * row and column number where we need to set up the output
  114. * text.
  115. *----------------------------------------------------------------------*
  116. * Information in Bold
  117.     LO_H_LABEL = LO_HEADER->CREATE_LABEL( ROW = 1 COLUMN = 1 ).
  118.     LO_H_LABEL->SET_TEXT('Header of the ALV Output in Bold').
  119. * Information in tabular format
  120.     LO_H_FLOW = LO_HEADER->CREATE_FLOW( ROW = 2 COLUMN = 1 ).
  121.     LO_H_FLOW->CREATE_TEXT( TEXT = 'This is text of flow in Header' ).
  122.     LO_H_FLOW = LO_HEADER->CREATE_FLOW( ROW = 3 COLUMN = 1 ).
  123.     LO_H_FLOW->CREATE_TEXT( TEXT = 'Date of List Generation' ).
  124.     LO_H_FLOW = LO_HEADER->CREATE_FLOW( ROW = 3 COLUMN = 2 ).
  125.     LO_H_FLOW->CREATE_TEXT( TEXT = sy-datum ).
  126. * Set the top of list using the header for Online
  127.     CO_ALV->SET_TOP_OF_LIST( LO_HEADER ).
  128. * Set the top of list using the header for Print
  129.     CO_ALV->SET_TOP_OF_LIST_PRINT( LO_HEADER ).
  130.   ENDMETHOD.                    "set_top_of_page

  132. * Setting End_Of_page
  133.   METHOD SET_END_OF_PAGE.
  134.     DATA: LO_FOOTER  TYPE REF TO CL_SALV_FORM_LAYOUT_GRID,
  135.           LO_F_LABEL TYPE REF TO CL_SALV_FORM_LABEL,
  136.           LO_F_FLOW  TYPE REF TO CL_SALV_FORM_LAYOUT_FLOW.
  137. * Footer Object
  138.     CREATE OBJECT LO_FOOTER.
  139. * Information in Bold
  140.     LO_F_LABEL = LO_FOOTER->CREATE_LABEL( ROW = 1 COLUMN = 1 ).
  141.     LO_F_LABEL->SET_TEXT('Footer of the ALV in Bold').
  142. * Tabular Information
  143.     LO_F_FLOW = LO_FOOTER->CREATE_FLOW( ROW = 2 COLUMN = 1 ).
  144.     LO_F_FLOW->CREATE_TEXT( TEXT = 'This is text of flow in footer' ).

  146. * Set the end of list using the header for Online
  147.     CO_ALV->SET_END_OF_LIST( LO_FOOTER ).
  148. * Set the End of list using the header for Print
  149.     CO_ALV->SET_END_OF_LIST_PRINT( LO_FOOTER ).
  150.   ENDMETHOD.                    "set_end_of_page
  151. ENDCLASS.                    "lcl_report IMPLEMENTATION
  152. *----------------------------------------------------------------------*
  153. START-OF-SELECTION.
  154. *----------------------------------------------------------------------*
  155.   DATA: LO_REPORT TYPE REF TO LCL_REPORT.
  156.   CREATE OBJECT LO_REPORT.
  157.   LO_REPORT->GET_DATA( ).
  158.   LO_REPORT->GENERATE_OUTPUT( ).
复制代码

程序执行效果：
header and footer using class.png
alv, class, header, footer, PF-Status

相关帖子
回复

使用道具 举报

Twilight

管理员

+发表新主题
  1. 847 主题
  2. 125 回帖
  3. 11270 积分
发消息

Ta最近发表

快速回帖

本版积分规则
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册有礼

小黑屋|手机版|SAP顾问圈 ( 沪ICP备18020878号 )

GMT+8, 2024-12-23 12:00 , Processed in 0.054663 second(s), 8 queries , Gzip On, Redis On.

© 2014-2017 SAPclubDesign by Twilight.Liu®X3.5

平台客服 1204767879 无客服码

快速回复 返回顶部 返回列表