设为首页收藏本站站点任务
请登陆 注册有礼
二维码
网站快捷导航

HR人事薪资、社保及公积金查询报表开发

Twilight发表于 2018-08-14 16:23Twilight 最后回复于 2018-08-14 16:23 [复制链接] 4544 0

SAP HR模块薪资模块开发不同与传统模块开发直接select即可，HR模块有大量的配置，表、字段等都是配置生产的，庆幸的是SAP提供了标准的函数来查薪资。
我们先来了解一下SAP HR模块标准查薪资、社保及公积金等的操作，标准功能的弱点就是一次只能查看一个人，太局限了，一般公司都需要重新开发。

1、T-code：pc_payresult
pc_payresult1.jpg
每月薪资计算后，会产生一条数据，当然每计算一次就会产生一条
pc_payresult2.jpg
双击，查看薪资明细，都在RT结果表中
pc_payresult3.jpg

2、报表开发代码
  1. REPORT zhrr001 MESSAGE-ID zmg_sd.

  3. *&---------------------------------------------------------------------*
  4. *& INCLUDE
  5. *&---------------------------------------------------------------------*
  6. INCLUDE zhrr001_top.       "Type/Data
  7. *INCLUDE zxxxxxxxx_class.  "Class
  8. INCLUDE zhrr001_selscr.    "Selection screen
  9. INCLUDE zhrr001_form.      "Form
  10. *INCLUDE zxxxxxxxx_module.        "Module

  12. *&---------------------------------------------------------------------*
  13. *& 初始化处理
  14. *&---------------------------------------------------------------------*
  15. INITIALIZATION.
  16. *  PERFORM xxxxxxx.

  18. *&---------------------------------------------------------------------*
  19. *& 选择屏幕控制
  20. *&---------------------------------------------------------------------*
  21. AT SELECTION-SCREEN OUTPUT.
  22. *  PERFORM xxxxxxx.

  24. *&---------------------------------------------------------------------*
  25. *& 参数输入检查
  26. *&---------------------------------------------------------------------*
  27. AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_spmon.
  28.   PERFORM frm_monat_f4.

  30. AT SELECTION-SCREEN.
  31.   PERFORM frm_check_authority .

  33. *&---------------------------------------------------------------------*
  34. *& 程序开始处理
  35. *&---------------------------------------------------------------------*
  36. START-OF-SELECTION.
  37.   PERFORM frm_get_payroll. "取数逻辑
  38. *  PERFORM xxxxxxx. "处理逻辑

  40. *&---------------------------------------------------------------------*
  41. *& 程序结束处理
  42. *&---------------------------------------------------------------------*
  43. END-OF-SELECTION.
  44.   PERFORM frm_display_data ."显示数据
复制代码
  1. *&---------------------------------------------------------------------*
  2. *&  包含                ZHRR001_TOP
  3. *&---------------------------------------------------------------------*
  4. TABLES:pa0001,pa0000.
  5. DATA: gs_fieldcat  TYPE lvc_s_fcat , " 相当于工作区
  6.       gt_fieldcat  TYPE lvc_t_fcat . " 存放列名的内表

  8. DATA:BEGIN OF gt_ALV OCCURS 0,
  9.       pernr TYPE pa0001-pernr,
  10.       ename TYPE pa0001-ename,
  11.       orgeh TYPE pa0001-orgeh,
  12.       orgtx TYPE t527x-orgtx,
  13.       werks TYPE pa0001-werks,
  14.       name2 TYPE t500p-name2,
  15.       btrtl TYPE pa0001-btrtl,
  16.       btext TYPE t001p-btext,
  17.       persg TYPE pa0001-persg,
  18.       ptext TYPE t501t-ptext,
  19.       persk TYPE pa0001-persk,
  20.       ptextsub TYPE t503t-ptext,
  21.       zhukou TYPE pa0002-zhukou,
  22.       inbase TYPE pa0014-betrg, "社保基数
  23.       fubase TYPE pa0014-betrg, "公积金基数
  24.       z313 TYPE pa9501-zztel0064b, "养老保险员工实交
  25.       z333 TYPE pa9501-zztel0068b, "医疗保险员工实交
  26.       z323 TYPE pa9501-zztel0066b, "失业保险员工实交
  27.       z314 TYPE pa9501-zztel0065b, "养老保险雇主实交
  28.       z334 TYPE pa9501-zztel0069b, "医疗保险雇主实交
  29.       z324 TYPE pa9501-zztel0067b, "失业保险雇主实交
  30.       z344 TYPE pa9501-zztel0070b, "工伤保险雇主实交
  31.       z354 TYPE pa9501-zztel0071b, "生育保险雇主实交
  32.       personin TYPE pa0014-betrg, "个人社保综合缴费
  33.       companin TYPE pa0014-betrg, "公司社保综合缴费
  34.       z362 TYPE pa9501-zztel0072b, "住房公积金保险员工实交
  35.       z363 TYPE pa9501-zztel0073b, "住房公积金保险雇主实交
  36.       begda TYPE pa9501-begda,  "开始时间
  37.       endda TYPE pa9501-endda,  "结束时间
  38.       f1613 TYPE pa0015-betrg,  "个人养老补缴
  39.       f1615 TYPE pa0015-betrg,  "个人医疗补缴
  40.       f1614 TYPE pa0015-betrg,  "个人失业补缴
  41.       f1608 TYPE pa0015-betrg,  "公司养老补缴
  42.       f1610 TYPE pa0015-betrg,  "公司医疗补缴
  43.       f1609 TYPE pa0015-betrg,  "公司失业补缴
  44.       f1611 TYPE pa0015-betrg,  "公司工伤补缴
  45.       f1612 TYPE pa0015-betrg,  "公司生育补缴
  46.       f1607 TYPE pa0015-betrg,  "个人公积金补缴
  47.       f1605 TYPE pa0015-betrg,  "公司公积金补缴
  48.     END OF gt_alv.

  50. DEFINE alv_field. "定义模块
  51.   CLEAR gs_fieldcat.
  52.   gs_fieldcat-fieldname = &1.  " 字段名称
  53.   gs_fieldcat-scrtext_l = &2.  " 显示标题
  54.   gs_fieldcat-scrtext_m = &2.  " 显示标题
  55.   gs_fieldcat-scrtext_s = &2.  " 显示标题
  56.   APPEND gs_fieldcat TO gt_fieldcat.
  57. END-OF-DEFINITION.
复制代码
  1. *&---------------------------------------------------------------------*
  2. *&  包含                ZHRR001_SELSCR
  3. *&---------------------------------------------------------------------*
  4. SELECTION-SCREEN BEGIN OF BLOCK b1 WITH FRAME TITLE text-001.
  5. PARAMETERS: p_spmon TYPE s295-spmon OBLIGATORY DEFAULT sy-datum+0(6)."年月
  6. SELECT-OPTIONS : s_abkrs FOR pa0001-abkrs NO INTERVALS."工资核算范围
  7. SELECT-OPTIONS : s_pernr FOR pa0001-pernr NO INTERVALS."人员编号
  8. SELECT-OPTIONS : s_werks FOR pa0001-werks NO INTERVALS."人事范围
  9. SELECT-OPTIONS : s_btrtl FOR pa0001-btrtl NO INTERVALS."人事子范围
  10. SELECT-OPTIONS : s_persg FOR pa0001-persg NO INTERVALS."员工组
  11. SELECT-OPTIONS : s_persk FOR pa0001-persk NO INTERVALS."员工子组
  12. SELECT-OPTIONS : s_stat2 FOR pa0000-stat2 NO INTERVALS DEFAULT '3'."雇佣状态
  13. SELECTION-SCREEN END OF BLOCK b1.
复制代码
  1. *&---------------------------------------------------------------------*
  2. *&  包含                ZHRR001_FORM
  3. *&---------------------------------------------------------------------*
  4. FORM frm_get_payroll.
  5.   DATA:lt_in_rgdir       TYPE TABLE OF pc261 WITH HEADER LINE.
  6.   DATA:lt_payroll_result TYPE TABLE OF pay99_result WITH HEADER LINE.
  7.   DATA:ls_rt TYPE pc207.
  8.   DATA:lv_relid          TYPE relid_pcl.
  9.   DATA:BEGIN OF lt_pa0001 OCCURS 0,
  10.         pernr TYPE pa0000-pernr,
  11.         ename TYPE pa0001-ename,
  12.         orgeh TYPE pa0001-orgeh,
  13.         werks TYPE pa0001-werks,
  14.         btrtl TYPE pa0001-btrtl,
  15.         persg TYPE pa0001-persg,
  16.         persk TYPE pa0001-persk,
  17.        END OF lt_pa0001.
  18.   DATA:BEGIN OF lt_pa0002 OCCURS 0,
  19.         pernr  TYPE pa0002-pernr,
  20.         zhukou TYPE pa0002-zhukou,
  21.       END OF lt_pa0002.
  22.   DATA:BEGIN OF lt_t527x OCCURS 0,
  23.         orgeh TYPE t527x-orgeh,
  24.         orgtx TYPE t527x-orgtx,
  25.        END OF lt_t527x.
  26.   DATA:BEGIN OF lt_t500p OCCURS 0,
  27.         persa TYPE t500p-persa,
  28.         name2 TYPE t500p-name2,
  29.       END OF lt_t500p.
  30.   DATA:BEGIN OF lt_t001p OCCURS 0,
  31.         werks TYPE t001p-werks,
  32.         btrtl TYPE t001p-btrtl,
  33.         btext TYPE t001p-btext,
  34.      END OF lt_t001p.
  35.   DATA:BEGIN OF lt_t501t OCCURS 0,
  36.         persg TYPE t501t-persg,
  37.         ptext TYPE t501t-ptext,
  38.       END OF lt_t501t.
  39.   DATA:BEGIN OF lt_t503t OCCURS 0,
  40.         persk TYPE t503t-persk,
  41.         ptext TYPE t503t-ptext,
  42.       END OF lt_t503t.

  44.   SELECT pa0000~pernr
  45.          pa0001~ename
  46.          pa0001~orgeh
  47.          pa0001~werks
  48.          pa0001~btrtl
  49.          pa0001~persg
  50.          pa0001~persk
  51.     INTO TABLE lt_pa0001
  52.     FROM pa0000
  53.     INNER JOIN pa0001 ON pa0000~pernr = pa0001~pernr AND pa0001~endda >= sy-datum AND pa0001~begda <= sy-datum
  54.     WHERE pa0000~stat2 IN s_stat2
  55.       AND pa0000~endda >= sy-datum
  56.       AND pa0000~begda <= sy-datum
  57.       AND pa0000~pernr IN s_pernr
  58.       AND pa0001~abkrs IN s_abkrs
  59.       AND pa0001~werks IN s_werks
  60.       AND pa0001~btrtl IN s_btrtl
  61.       AND pa0001~persg IN s_persg
  62.       AND pa0001~persk IN s_persk.
  63.   IF sy-subrc NE 0.
  64.     MESSAGE i000(zhr001) WITH '没有符合条件的数据!'.
  65.     LEAVE LIST-PROCESSING.
  66.   ENDIF.

  68.   IF lt_pa0001[] IS NOT INITIAL.
  69.     SELECT pernr
  70.            zhukou
  71.       INTO TABLE lt_pa0002
  72.       FROM pa0002
  73.       FOR ALL ENTRIES IN lt_pa0001
  74.       WHERE pernr = lt_pa0001-pernr
  75.         AND endda >= sy-datum
  76.         AND begda <= sy-datum.
  77.   ENDIF.

  79. *部门
  80.   SELECT orgeh
  81.          orgtx
  82.   INTO TABLE lt_t527x
  83.   FROM t527x
  84.   WHERE sprsl = sy-langu
  85.     AND endda >= sy-datum
  86.     AND begda <= sy-datum.
  87. *人事范围
  88.   SELECT persa
  89.          name2
  90.   INTO TABLE lt_t500p
  91.   FROM t500p.
  92. *人事子范围
  93.   SELECT werks
  94.          btrtl
  95.          btext
  96.   INTO TABLE lt_t001p
  97.   FROM t001p.
  98. *员工组
  99.   SELECT persg
  100.          ptext
  101.   INTO TABLE lt_t501t
  102.   FROM t501t
  103.   WHERE sprsl = sy-langu.
  104. *员工子组
  105.   SELECT persk
  106.          ptext
  107.   INTO TABLE lt_t503t
  108.   FROM t503t
  109.   WHERE sprsl = sy-langu.


  112.   SORT lt_pa0002 BY pernr.
  113.   SORT lt_t527x BY orgeh.
  114.   SORT lt_t500p BY persa.
  115.   SORT lt_t001p BY werks btrtl.
  116.   SORT lt_t501t BY persg.
  117.   SORT lt_t503t BY persk.
  118.   LOOP AT lt_pa0001.
  119.     CLEAR:lt_in_rgdir[],lv_relid,gt_alv.
  120.     gt_alv-pernr  = lt_pa0001-pernr.
  121.     gt_alv-ename  = lt_pa0001-ename.
  122.     gt_alv-orgeh  = lt_pa0001-orgeh.
  123.     gt_alv-werks  = lt_pa0001-werks.
  124.     gt_alv-btrtl  = lt_pa0001-btrtl.
  125.     gt_alv-persg  = lt_pa0001-persg.
  126.     gt_alv-persk  = lt_pa0001-persk.
  127.     READ TABLE lt_pa0002 WITH KEY pernr = lt_pa0001-pernr BINARY SEARCH.
  128.     IF sy-subrc = 0.
  129.       gt_alv-zhukou = lt_pa0002-zhukou.
  130.     ENDIF.
  131.     READ TABLE lt_t527x WITH KEY orgeh = lt_pa0001-orgeh BINARY SEARCH.
  132.     IF sy-subrc = 0.
  133.       gt_alv-orgtx = lt_t527x-orgtx.
  134.     ENDIF.
  135.     READ TABLE lt_t500p WITH KEY persa = lt_pa0001-werks BINARY SEARCH.
  136.     IF sy-subrc = 0.
  137.       gt_alv-name2 = lt_t500p-name2.
  138.     ENDIF.
  139.     READ TABLE lt_t001p WITH KEY werks = lt_pa0001-werks btrtl = lt_pa0001-btrtl BINARY SEARCH.
  140.     IF sy-subrc = 0.
  141.       gt_alv-btext = lt_t001p-btext.
  142.     ENDIF.
  143.     READ TABLE lt_t501t WITH KEY persg = lt_pa0001-persg BINARY SEARCH.
  144.     IF sy-subrc = 0.
  145.       gt_alv-ptext = lt_t501t-ptext.
  146.     ENDIF.
  147.     READ TABLE lt_t503t WITH KEY persk = lt_pa0001-persk BINARY SEARCH.
  148.     IF sy-subrc = 0.
  149.       gt_alv-ptextsub = lt_t503t-ptext.
  150.     ENDIF.

  152.     CALL FUNCTION 'CU_READ_RGDIR'
  153.       EXPORTING
  154.         persnr             = lt_pa0001-pernr
  155.         no_authority_check = 'X'
  156.       TABLES
  157.         in_rgdir           = lt_in_rgdir
  158.       EXCEPTIONS
  159.         no_record_found    = 1
  160.         OTHERS             = 2.

  162.     CALL FUNCTION 'PYXX_GET_RELID_FROM_PERNR'
  163.       EXPORTING
  164.         employee                    = lt_pa0001-pernr
  165.       IMPORTING
  166.         relid                       = lv_relid
  167.       EXCEPTIONS
  168.         error_reading_infotype_0001 = 1
  169.         error_reading_molga         = 2
  170.         error_reading_relid         = 3
  171.         OTHERS                      = 4.

  173.     READ TABLE lt_in_rgdir WITH KEY fpper = p_spmon void = ''.
  174.     IF sy-subrc = 0 .
  175.       gt_alv-begda  = lt_in_rgdir-fpbeg. "开始时间
  176.       gt_alv-endda  = lt_in_rgdir-fpend. "结束时间
  177.       CALL FUNCTION 'PYXX_READ_PAYROLL_RESULT'
  178.         EXPORTING
  179.           clusterid                    = lv_relid
  180.           employeenumber               = lt_pa0001-pernr
  181.           sequencenumber               = lt_in_rgdir-seqnr
  182.           read_only_international      = 'X'
  183.           client                       = ''
  184.         CHANGING
  185.           payroll_result               = lt_payroll_result
  186.         EXCEPTIONS
  187.           illegal_isocode_or_clusterid = 1
  188.           error_generating_import      = 2
  189.           import_mismatch_error        = 3
  190.           subpool_dir_full             = 4
  191.           no_read_authority            = 5
  192.           no_record_found              = 6
  193.           versions_do_not_match        = 7
  194.           error_reading_archive        = 8
  195.           error_reading_relid          = 9
  196.           OTHERS                       = 10.
  197.       IF sy-subrc = 0.
  198.         LOOP AT lt_payroll_result-inter-rt INTO ls_rt.
  199.           CASE ls_rt-lgart.
  200.             WHEN '1602'.  "社保基数
  201.               gt_alv-inbase = ls_rt-betrg.
  202.             WHEN '1603'.  "公积金基数
  203.               gt_alv-fubase = ls_rt-betrg.
  204.             WHEN 'Z313'.  "养老保险员工实交
  205.               gt_alv-z313  = ls_rt-betrg.
  206.             WHEN 'Z333'.  "医疗保险员工实交
  207.               gt_alv-z333  = ls_rt-betrg.
  208.             WHEN 'Z323'.  "失业保险员工实交
  209.               gt_alv-z323  = ls_rt-betrg.
  210.             WHEN 'Z314'.  "养老保险雇主实交
  211.               gt_alv-z314  = ls_rt-betrg.
  212.             WHEN 'Z334'.  "医疗保险雇主实交
  213.               gt_alv-z334  = ls_rt-betrg.
  214.             WHEN 'Z324'.  "失业保险雇主实交
  215.               gt_alv-z324  = ls_rt-betrg.
  216.             WHEN 'Z344'.  "工伤保险雇主实交
  217.               gt_alv-z344  = ls_rt-betrg.
  218.             WHEN 'Z354'.  "生育保险雇主实交
  219.               gt_alv-z354  = ls_rt-betrg.
  220.             WHEN '/362'.  "住房公积金保险员工实交
  221.               gt_alv-z362  = ls_rt-betrg.
  222.             WHEN '/363'.  "住房公积金保险雇主实交
  223.               gt_alv-z363  = ls_rt-betrg.
  224.             WHEN '1613'.  "个人养老补缴
  225.               gt_alv-f1613  = ls_rt-betrg.
  226.             WHEN '1615'.  "个人医疗补缴
  227.               gt_alv-f1615  = ls_rt-betrg.
  228.             WHEN '1614'.  "个人失业补缴
  229.               gt_alv-f1614  = ls_rt-betrg.
  230.             WHEN '1608'.  "公司养老补缴
  231.               gt_alv-f1608 = ls_rt-betrg.
  232.             WHEN '1610'.  "公司医疗补缴
  233.               gt_alv-f1610 = ls_rt-betrg.
  234.             WHEN '1609'.  "公司失业补缴
  235.               gt_alv-f1609 = ls_rt-betrg.
  236.             WHEN '1611'.  "公司工伤补缴
  237.               gt_alv-f1611 = ls_rt-betrg.
  238.             WHEN '1612'.  "公司生育补缴
  239.               gt_alv-f1612 = ls_rt-betrg.
  240.             WHEN '1607'.  "个人公积金补缴
  241.               gt_alv-f1607 = ls_rt-betrg.
  242.             WHEN '1605'.  "公司公积金补缴
  243.               gt_alv-f1605 = ls_rt-betrg.
  244.             WHEN OTHERS.
  245.           ENDCASE.
  246.         ENDLOOP.
  247.       ENDIF.
  248.     ENDIF .
  249.     gt_alv-personin = gt_alv-z313 + gt_alv-z333 + gt_alv-z323.  "个人社保综合缴费
  250.     gt_alv-companin = gt_alv-z314 + gt_alv-z334 + gt_alv-z324 + gt_alv-z344 + gt_alv-z354.  "公司社保综合缴费
  251.     APPEND gt_alv.
  252.   ENDLOOP.

  254. ENDFORM.
  255. FORM frm_check_authority .
  256.   AUTHORITY-CHECK OBJECT 'S_TCODE' FOR USER sy-uname ID 'TCD' FIELD 'ZHRR002'.
  257.   IF sy-subrc NE 0 .
  258.     MESSAGE e002(zhr001) WITH '用户：' sy-uname.
  259.   ENDIF .
  260. ENDFORM.                    " FRM_CHECK_AUTHORITY
  261. FORM  frm_monat_f4.
  262.   DATA: BEGIN OF mf_dynpfields OCCURS 1.
  263.           INCLUDE STRUCTURE dynpread.
  264.   DATA: END   OF mf_dynpfields.
  265.   DATA: mf_returncode LIKE sy-subrc,
  266.         mf_monat      LIKE isellist-month,
  267.         mf_hlp_repid  LIKE sy-repid.
  268.   FIELD-SYMBOLS: <mf_feld>.
  269.   GET CURSOR FIELD mf_dynpfields-fieldname.
  270.   APPEND mf_dynpfields.
  271.   mf_hlp_repid = sy-repid.
  272.   DO 2 TIMES.
  273.     CALL FUNCTION 'DYNP_VALUES_READ'
  274.       EXPORTING
  275.         dyname               = mf_hlp_repid
  276.         dynumb               = sy-dynnr
  277.       TABLES
  278.         dynpfields           = mf_dynpfields
  279.       EXCEPTIONS
  280.         invalid_abapworkarea = 01
  281.         invalid_dynprofield  = 02
  282.         invalid_dynproname   = 03
  283.         invalid_dynpronummer = 04
  284.         invalid_request      = 05
  285.         no_fielddescription  = 06
  286.         undefind_error       = 07.
  287.     IF sy-subrc = 3.
  288.       mf_hlp_repid = 'SAPLALDB'.
  289.     ELSE.
  290.       READ TABLE mf_dynpfields INDEX 1.
  291.       TRANSLATE mf_dynpfields-fieldvalue USING '_ '.
  292.       EXIT.
  293.     ENDIF.
  294.   ENDDO.
  295.   IF sy-subrc = 0.
  296.     CALL FUNCTION 'CONVERSION_EXIT_PERI_INPUT'
  297.       EXPORTING
  298.         input         = mf_dynpfields-fieldvalue
  299.       IMPORTING
  300.         output        = mf_monat
  301.       EXCEPTIONS
  302.         error_message = 1.
  303.     IF mf_monat IS INITIAL.
  304.       mf_monat = sy-datlo(6).
  305.     ENDIF.
  306.     CALL FUNCTION 'POPUP_TO_SELECT_MONTH'
  307.       EXPORTING
  308.         actual_month               = mf_monat
  309.       IMPORTING
  310.         selected_month             = mf_monat
  311.         return_code                = mf_returncode
  312.       EXCEPTIONS
  313.         factory_calendar_not_found = 01
  314.         holiday_calendar_not_found = 02
  315.         month_not_found            = 03.
  316.     IF sy-subrc = 0 AND mf_returncode = 0.
  317.       CALL FUNCTION 'CONVERSION_EXIT_PERI_OUTPUT'
  318.         EXPORTING
  319.           input  = mf_monat
  320.         IMPORTING
  321.           output = mf_dynpfields-fieldvalue.
  322.       COLLECT mf_dynpfields.
  323.       CALL FUNCTION 'DYNP_VALUES_UPDATE'
  324.         EXPORTING
  325.           dyname               = mf_hlp_repid
  326.           dynumb               = sy-dynnr
  327.         TABLES
  328.           dynpfields           = mf_dynpfields
  329.         EXCEPTIONS
  330.           invalid_abapworkarea = 01
  331.           invalid_dynprofield  = 02
  332.           invalid_dynproname   = 03
  333.           invalid_dynpronummer = 04
  334.           invalid_request      = 05
  335.           no_fielddescription  = 06
  336.           undefind_error       = 07.
  337.     ENDIF.
  338.   ENDIF.
  339. ENDFORM.
  340. FORM frm_display_data .
  341.   DATA:ls_layout_lvc    TYPE lvc_s_layo.

  343.   CLEAR:ls_layout_lvc.
  344.   ls_layout_lvc-zebra        = 'X' .       " 使ALV界面呈现颜色交替
  345.   ls_layout_lvc-sel_mode     = 'A' .       " 选择模式，“A”在最左端有选择按钮
  346.   ls_layout_lvc-cwidth_opt   = 'X' .       " 自动优化列宽

  348.   alv_field :
  349.   'PERNR' '人员编号' ,
  350.   'ENAME' '人员名称' ,
  351.   'ORGTX' '部门' ,
  352.   'NAME2' '人事范围' ,
  353.   'BTEXT' '人事子范围' ,
  354.   'PTEXT' '员工组' ,
  355.   'PTEXTSUB' '员工子组' ,
  356.   'ZHUKOU' '户口信息' ,
  357.   'INBASE' '社保基数' ,
  358.   'FUBASE' '公积金基数' ,
  359.   'Z313' '个人养老实缴' ,
  360.   'Z333' '个人医疗实缴' ,
  361.   'Z323' '个人失业实缴' ,
  362.   'Z314' '公司养老实缴' ,
  363.   'Z334' '公司医疗实缴' ,
  364.   'Z324' '公司失业实缴' ,
  365.   'Z344' '公司工伤实缴' ,
  366.   'Z354' '公司生育实缴' ,
  367.   'PERSONIN' '个人社保综合缴费' ,
  368.   'COMPANIN' '公司社保综合缴费' ,
  369.   'Z362' '个人公积金实缴' ,
  370.   'Z363' '公司公积金实缴' ,
  371.   'BEGDA' '开始时间' ,
  372.   'ENDDA' '结束时间' ,
  373.   'F1613' '个人养老补缴' ,
  374.   'F1615' '个人医疗补缴' ,
  375.   'F1614' '个人失业补缴' ,
  376.   'F1608' '公司养老补缴' ,
  377.   'F1610' '公司医疗补缴' ,
  378.   'F1609' '公司失业补缴' ,
  379.   'F1611' '公司工伤补缴' ,
  380.   'F1612' '公司生育补缴' ,
  381.   'F1607' '个人公积金补缴' ,
  382.   'F1605' '公司公积金补缴' .

  384.   CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY_LVC'
  385.     EXPORTING
  386. *     i_bypassing_buffer = 'X'
  387. *     i_callback_program = myrepid
  388.       it_fieldcat_lvc = gt_fieldcat[]
  389.       is_layout_lvc   = ls_layout_lvc
  390. *     i_save          = 'A'
  391.     TABLES
  392.       t_outtab        = gt_alv[]
  393.     EXCEPTIONS
  394.       program_error   = 1
  395.       OTHERS          = 2.

  397. ENDFORM.                    " FRM_DISPLAY_DATA
复制代码


薪资

相关帖子
回复

使用道具 举报

Twilight

管理员

+发表新主题
  1. 846 主题
  2. 125 回帖
  3. 11239 积分
发消息

Ta最近发表

快速回帖

本版积分规则
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册有礼

小黑屋|手机版|SAP顾问圈 ( 沪ICP备18020878号 )

GMT+8, 2024-11-21 17:34 , Processed in 0.049554 second(s), 6 queries , Gzip On, Redis On.

© 2014-2017 SAPclubDesign by Twilight.Liu®X3.5

平台客服 1204767879 无客服码

快速回复 返回顶部 返回列表