设为首页收藏本站站点任务
请登陆 注册有礼
二维码
网站快捷导航

[教程] BASICS OF BOL PROGRAMMING

Twilight发表于 2015-12-05 00:58Twilight 最后回复于 2015-12-05 00:58 [复制链接] 4659 0

***************************************************************************************************************
*BOL PROGRAMMING
*SAP CRM WEBCLIENT
*GIVES INTRODUCTION TO * basic activities like search, create, update in the bol
*programming in order to give introduction to the main classes and methods of business object layer.
***************************************************************************************************************
  1. *used data
  2. DATA: lr_core TYPE REF TO cl_crm_bol_core.

  4. *in order to use any service of BOL, we need to start the MODEL (component set) using
  5. * CORE class.
  6. lr_core = cl_crm_bol_core=>get_instance( ).

  8. *once we have the instance, then load the component set.
  9. *here we will be using ONEORDER component set.

  11. *when we are working on web ui, this will be handled by framework. here we are doing it in the report programming so we need to handle it
  12. TRY.
  13.     CALL METHOD lr_core->load_component_set
  14.       EXPORTING
  15.         iv_component_set_name = 'ONEORDER'.
  16.   CATCH cx_crm_genil_general_error .
  17. ENDTRY.

  19. *component is loaded, so we can use the BOL services. Let us search for a particular
  20. *contract. for that we need to get an instance of dquery service class.
  21. DATA: lr_query TYPE REF TO cl_crm_bol_dquery_service,
  22.       lr_result TYPE REF TO cl_crm_bol_bo_col.

  24. *-->SEARCH OPERATION
  25. "get the instance of dynamic search object,which will be used to search service contracts.
  26. lr_query ?= cl_crm_bol_dquery_service=>get_instance( iv_query_name = 'BTQSrvCon' ).

  28. "Every dynamic search object will have its own result type object. here BTQSrvcon has BTQRSrvcon as result object.
  29. "so in the result list all objects are type of BTQRSrvcon.

  31. "we got the instance, so we need to set the selection criteria.

  33. "fetching all contracts whose description is 'testing'.
  34. "you can call this method multiple times to add different selection parameters.
  35. lr_query->add_selection_param( iv_attr_name = 'DESCRIPTION'
  36.                                                 iv_sign      = 'I'
  37.                                                 iv_option    = 'EQ'
  38.                                                 iv_low       = 'testing' ).

  40. "get the list contracts that match the selection criteria in the form of collection.
  41. "collection is nothing but a container that holds records. we can compare it like a internal table
  42. "that holds records.
  43. lr_result ?= lr_query->get_query_result( ).

  45. "Let us print the contract id and description of all records in teh collection.

  47. "cl_crm_bol_entity is used to represent the record in the BUSINESS OBJECT LAYER.
  48. DATA: lr_entity TYPE REF TO cl_crm_bol_entity,
  49.       lv_objectid TYPE string,
  50.       lv_descr TYPE char40.

  52. "read the first record in the collection.
  53. lr_entity ?= lr_result->if_bol_bo_col~get_first( ).

  55. "following while loop mechanism is used to visit each record in the collection.
  56. WHILE lr_entity IS BOUND.
  57.   "read the contract id.
  58.   "get property as string will return attribute values in the form of string. so we declared lv_objectid as string.
  59.   lr_entity->get_property_as_string( EXPORTING iv_attr_name = 'OBJECT_ID'
  60. RECEIVING rv_result = lv_objectid  ).

  62.   "get property as value will return the value as it as.so we declared DESCRIPTION with data element.
  63.   lr_entity->get_property_as_value( EXPORTING iv_attr_name = 'DESCRIPTION' IMPORTING ev_result = lv_descr ).
  64.   WRITE : lv_objectid, lv_descr.
  65.   WRITE /:.

  67.   "read the next record in the collection.
  68.   lr_entity ?= lr_result->if_bol_bo_col~get_next( ).
  69. ENDWHILE.
复制代码

**************UPDATING OPERATION***************************
  1. "Let us change the description of one service contract.

  3. "get the curren entity from the result list.

  5. "Every collection holds one pointer which always points to the current record we visited.We generally call it is a focus
  6. "in the BOL language. so get current returns the object which has focus. so what ever the last object we visited in the
  7. "above loop, will be fetched in the below statement.
  8. lr_entity ?= lr_result->if_bol_bo_col~get_current( ).

  10. IF lr_entity IS BOUND.  "we never work on object references which are initial. this is check is very important in BOL.
  11.   "can we use the set property as string directly on this lr_entity?.

  13.   "No, it is dynamic query result object, generally all properties of these type objects are read only.

  15.   "DESCRIPTION is property of BTAdminH object. we need to get it using the relations. We need to take help from MODEl to see
  16.   "what are the relations that we need to go through to reach the target object. Transaction GENIL_MODEL_BROWSER

  18.   "in our scenario, we have BTQRSrvcon as a soruce in the lr_entity variable. This object has a relation 'Association BTADVSSrvCon Child Cardinality 1'
  19.   "which will give the object BTOrder.

  21.   "again BTOrder is having a relation 'Composition BTOrderHeader Child Cardinality 1', which will fetch the target object BTAdminH. this object has
  22.   "an attribute 'DESCRIPTION'.

  24.   "while looking at the relations, look at the cardinality of relation. if cardinality is 0...1, then relation always fetch one single entity. if is
  25.   "0...N, then relation will fetch multiple entities.

  27.   " use the GET RELATED ENTITY when cardinality is 0...1.
  28.   " use the GET_RELATED_ENTITIES when cardinality is 0...N.
  29.   DATA: lr_order TYPE REF TO cl_crm_bol_entity.

  31.   "read the BTORDER first.
  32.   " the parameter iv_mode will take another value 'b', which stands for bypassing the buffer.
  33.   "which means, framework will ignore the values that exist in the bol buffer and read the target
  34.   "entity values from the database by triggering required APIs. it can decrease the performance. so use only in necessary
  35.   "situations like when you are reading that particular entity first time..
  36.   TRY.
  37.       CALL METHOD lr_entity->get_related_entity
  38.         EXPORTING
  39.           iv_relation_name = 'BTADVSSrvCon'
  40.           iv_mode          = cl_crm_bol_entity=>bypassing_buffer
  41.         RECEIVING
  42.           rv_result        = lr_order.
  43.     CATCH cx_crm_genil_model_error .
  44.   ENDTRY.

  46.   "we got the order, then read the BTAdminH.
  47.   DATA:  lr_header TYPE REF TO cl_crm_bol_entity.
  48.   IF lr_order IS BOUND.
  49.     TRY.
  50.         CALL METHOD lr_order->get_related_entity
  51.           EXPORTING
  52.             iv_relation_name = 'BTOrderHeader'
  53.             iv_mode          = cl_crm_bol_entity=>bypassing_buffer
  54.           RECEIVING
  55.             rv_result        = lr_header.
  56.       CATCH cx_crm_genil_model_error .
  57.     ENDTRY.
  58.   ENDIF.

  60.   "we got the BTadminH. change its DESCRIPTION property.
  61.   IF lr_header IS BOUND.
  62.     "before changing any property of BOL object, we need to lock it.
  63.     "this will be accomplished by lock method.
  64.     IF  lr_header->lock( ) = abap_true.  "if we get the lock, then only continue
  65.       "we use set_* methods to change the properties of BOL objects.
  66.       lr_header->set_property_as_string( EXPORTING iv_attr_name = 'DESCRIPTION'
  67.       iv_value = 'changed'  ).
  68.     ENDIF.

  70.     "once change is done, we need to tell about this change to the framework.
  71.     "we will use core class for this.
  72.     lr_core->modify( ).

  74.     "then get the transaction from the entity and check whether this save is possible or not.
  75.     DATA: lr_transaction TYPE REF TO if_bol_transaction_context.
  76.     lr_transaction ?= lr_header->get_transaction( ).
  77.     IF lr_transaction IS BOUND.
  78.       IF lr_transaction->check_save_possible( ) EQ abap_true.
  79.         "if we can save , then save the transaction and commit the changes.
  80.         IF lr_transaction->save( ) EQ abap_true.
  81.           lr_transaction->commit( ).
  82.         ENDIF.
  83.         "we changed the object description. read it again to get the new value.
  84.         lr_header->get_property_as_value( EXPORTING iv_attr_name = 'DESCRIPTION'
  85.                  IMPORTING ev_result = lv_descr ).
  86.       ENDIF.
  87.     ENDIF.
  88.   ENDIF.
  89. ENDIF.
复制代码

***************CREATE operation*****************************
  1. *Let us create one service contract and fill some of its properties.

  3. *"first step , we need to create the root entity.
  4. DATA:  lr_factory       TYPE REF TO cl_crm_bol_entity_factory,
  5.        lr_order_new     TYPE REF TO cl_crm_bol_entity,
  6.        ls_params        TYPE crmt_name_value_pair,
  7.        lt_params        TYPE crmt_name_value_pair_tab.

  9. ls_params-name  = 'PROCESS_TYPE'.
  10. ls_params-value = 'ZSZ'.
  11. APPEND ls_params TO lt_params.

  13. "create root entity will be handled by the factory class. we use CORE class
  14. "to get the instance of required factory class by sending the root object to its
  15. "method get entity factory. then we use CREATE method of factory class by sending
  16. "the necessary parameters.

  18. "here we are creating contracts, so we are sending the process type as input.
  19. lr_factory   = lr_core->get_entity_factory( 'BTOrder' ).    "#EC NOTEXT
  20. lr_order_new = lr_factory->create( lt_params ).
  21. IF lr_order_new IS BOUND.
  22.   "BTOrder is having only GUID, we need to get BTAdminH entity to fill up some of its properties.
  23.   TRY.
  24.       CALL METHOD lr_order_new->get_related_entity
  25.         EXPORTING
  26.           iv_relation_name = 'BTOrderHeader'
  27.           iv_mode          = cl_crm_bol_entity=>bypassing_buffer
  28.         RECEIVING
  29.           rv_result        = lr_header.
  30.     CATCH cx_crm_genil_model_error .
  31.   ENDTRY.

  33.   "fill the properties using the setter method
  34.   IF lr_header IS BOUND.
  35.     "we use set_* methods to change the properties of BOL objects.
  36.     lr_header->set_property_as_string( EXPORTING iv_attr_name = 'DESCRIPTION'
  37.     iv_value = 'New Contract'  ).
  38.     lr_core->modify( ).
  39.     lr_transaction ?= lr_header->get_transaction( ).
  40.     IF lr_transaction IS BOUND.
  41.       IF lr_transaction->check_save_possible( ) EQ abap_true.
  42.         "if we can save , then save the transaction and commit the changes.
  43.         IF lr_transaction->save( ) EQ abap_true.
  44.           lr_transaction->commit( ).
  45.         ENDIF.

  47.         "we changed the object description. read it again to get the new value.
  48.         lr_header->get_property_as_value( EXPORTING iv_attr_name = 'DESCRIPTION'
  49.                   IMPORTING ev_result = lv_descr ).

  51.       ENDIF.
  52.     ENDIF.
  53.   ENDIF.
  54. ENDIF.
复制代码
crm

相关帖子
回复

使用道具 举报

Twilight

管理员

+发表新主题
  1. 846 主题
  2. 125 回帖
  3. 11239 积分
发消息

Ta最近发表

快速回帖

本版积分规则
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册有礼

小黑屋|手机版|SAP顾问圈 ( 沪ICP备18020878号 )

GMT+8, 2024-11-21 23:50 , Processed in 0.075116 second(s), 7 queries , Gzip On, Redis On.

© 2014-2017 SAPclubDesign by Twilight.Liu®X3.5

平台客服 1204767879 无客服码

快速回复 返回顶部 返回列表