设为首页收藏本站站点任务
请登陆 注册有礼
二维码
网站快捷导航

[面向对象] ABAP面向对象的多态使用教程

Twilight发表于 2014-02-22 17:14Twilight 最后回复于 2014-02-22 17:14 [复制链接] 4449 0

练习6 多态
1、不同子类的变量放到内表中，遍历，写入lcl_airplane类型的变量中，并逐个调用display_attributes方法，观察效果。
  1. CLASS lcl_carrier DEFINITION.

  3.   PUBLIC SECTION.
  4.     "----------------------------------------
  5.     METHODS: constructor IMPORTING im_name TYPE string,
  6.              get_name RETURNING value(ex_name) TYPE string,
  7.              add_airplane,
  8.              display_airplanes,
  9.              display_attributes.

  11.   PRIVATE SECTION.
  12.     "-----------------------------------
  13.     DATA: name              TYPE string,
  14.           airplane_list  TYPE TABLE OF REF TO lcl_airplane.
  15. ENDCLASS.                    "lcl_carrier DEFINITION


  18. CLASS lcl_carrier IMPLEMENTATION.

  20.   METHOD add_airplane.

  22.   ENDMETHOD.                    "add_airplane

  24.   METHOD display_attributes.
  25.     WRITE: / name .

  27.   ENDMETHOD.                    "display_attributes
复制代码
2、定义类lcl_carrier 代码如下
3、编写以下方法的代码
Add_airplane  将飞机增加到飞机列表属性，传输中使用lcl_airplane类
Display_airplanes 遍历airplane_list，调用每个airplane的display_attributes方法
Display_attributes   显示所有的属性，包括显示name和显示航班列表
4、建立一个lcl_carrier的实例
将之前建立的飞机对象加到这个对象的airplane_list中
调用display_attributes属性，显示列表
执行效果：
abap面向对象中的多态使用方法.jpg
主程序代码：
  1. REPORT  ZBC10_EX_6.  "构造函数  主要用来在创建对象时初始化对象 即为对象成员变量赋初始值  重载
  2. INCLUDE ZBC10_EX_A_6.
  3. INCLUDE ZBC10_EX_B_6.
  4. INCLUDE ZBC10_EX_C_6.
  5. INCLUDE ZBC10_EX_D_6.

  7. DATA:R_AIRPLANE TYPE REF TO LCL_AIRPLANE, "相当于结构
  8.      RT_AIRPLANE TYPE TABLE OF REF TO LCL_AIRPLANE. "相当于内表
  9. DATA:R_PASSENGER_PLANE TYPE REF TO LCL_PASSENGER_PLANE,
  10.      R_CARGO_PLANE TYPE REF TO LCL_CARGO_PLANE,
  11.      R_CARRIER TYPE REF TO LCL_CARRIER.

  13. START-OF-SELECTION. "面向对象必须写，面向过程可以不写
  14. CREATE OBJECT R_CARRIER EXPORTING IM_NAME = 'AA'.
  15. CREATE OBJECT R_AIRPLANE EXPORTING IM_NAME = '001'
  16.                                    IM_PLANETYPE = '747-400'.
  17. R_CARRIER->ADD_AIRPLANE( R_AIRPLANE ).

  19. CREATE OBJECT R_AIRPLANE EXPORTING IM_NAME = '002'
  20.                                    IM_PLANETYPE = '747-500'.
  21. R_CARRIER->ADD_AIRPLANE( R_AIRPLANE ).

  23. CREATE OBJECT R_PASSENGER_PLANE EXPORTING IM_NAME = '003'
  24.                                           IM_PLANETYPE = '747-400'
  25.                                           IM_MAXSEATS = '200'.
  26. R_CARRIER->ADD_AIRPLANE( R_PASSENGER_PLANE ).

  28. CREATE OBJECT R_CARGO_PLANE EXPORTING IM_NAME = '004'
  29.                                       IM_PLANETYPE = '747-400'
  30.                                       IM_MAXCARGO = '300'.
  31. R_CARRIER->ADD_AIRPLANE( R_CARGO_PLANE ).

  33. R_CARRIER->DISPLAY_ATTRIBUTES( ).
复制代码
INCLUDE ZBC10_EX_A_6.
  1. *&---------------------------------------------------------------------*
  2. *&  Include           ZBC10_EX_A
  3. *&---------------------------------------------------------------------*
  4. CLASS LCL_AIRPLANE DEFINITION.
  5.   PUBLIC SECTION.
  6.     METHODS:CONSTRUCTOR IMPORTING IM_NAME TYPE  STRING
  7.                                   IM_PLANETYPE TYPE SAPLANE-PLANETYPE.
  8.     CLASS-METHODS:DISPLAY_N_O_AIRPLANES.
  9.     METHODS:DISPLAY_ATTRIBUTES.
  10.   PROTECTED SECTION.
  11.     DATA:NAME TYPE  STRING,
  12.          PLANETYPE TYPE SAPLANE-PLANETYPE.
  13.     CLASS-DATA:N_0_ARIPLANES TYPE I.
  14.     METHODS:GET_TECHNICAL_ATTRIBUTES IMPORTING IM_TYPE TYPE SAPLANE-PLANETYPE
  15.                                      EXPORTING EX_WEIGHT  TYPE S_PLAN_WEI
  16.                                                EX_TANKCAP TYPE   S_CAPACITY.
  17. ENDCLASS.                    "LCL_AIRPLANE DEFINITION

  19. *----------------------------------------------------------------------*
  20. *       CLASS LCL_AIRPLANE IMPLEMENTATION
  21. *----------------------------------------------------------------------*
  22. *
  23. *----------------------------------------------------------------------*
  24. CLASS LCL_AIRPLANE IMPLEMENTATION.
  25.   METHOD CONSTRUCTOR.
  26.     NAME = IM_NAME.
  27.     PLANETYPE = IM_PLANETYPE.
  28.     N_0_ARIPLANES = N_0_ARIPLANES + 1.
  29.   ENDMETHOD.                    "SET_ATTRIBUTES
  30.   METHOD DISPLAY_N_O_AIRPLANES.
  31.     WRITE: / 'Number of airplanes:',N_0_ARIPLANES.
  32.   ENDMETHOD.                    "DISPLAY_N_O_AIRPLANES
  33.   METHOD DISPLAY_ATTRIBUTES.
  34.     DATA:WEIGHT  TYPE S_PLAN_WEI,
  35.          TANKCAP TYPE   S_CAPACITY.
  36.     ME->GET_TECHNICAL_ATTRIBUTES( EXPORTING IM_TYPE = PLANETYPE    "在类里引用自身的方法用ME  这里的EXPORTING相当于IMPORTING 相反的
  37.                                   IMPORTING EX_WEIGHT = WEIGHT
  38.                                             EX_TANKCAP = TANKCAP ).
  39.     WRITE: / 'name',NAME,'planetype',PLANETYPE,'weight',WEIGHT,'tankcap',TANKCAP.
  40.   ENDMETHOD.                    "display_attributes
  41.   METHOD GET_TECHNICAL_ATTRIBUTES.
  42.     SELECT SINGLE WEIGHT TANKCAP
  43.       INTO (EX_WEIGHT,EX_TANKCAP)
  44.       FROM SAPLANE
  45.       WHERE PLANETYPE = IM_TYPE.
  46.     IF SY-SUBRC NE 0.
  47.       EX_WEIGHT = 0.
  48.       EX_TANKCAP = 0.
  49.     ENDIF.
  50.   ENDMETHOD.                    "GET_TECHNICAL_ATTRIBUTES
  51. ENDCLASS.                    "LCL_AIRPLANE IMPLEMENTATION
复制代码
INCLUDE ZBC10_EX_B_6.
  1. *&---------------------------------------------------------------------*
  2. *&  Include           ZBC10_EX_B_5
  3. *&---------------------------------------------------------------------*
  4. CLASS LCL_PASSENGER_PLANE DEFINITION INHERITING FROM LCL_AIRPLANE.
  5.   PUBLIC SECTION.
  6.     METHODS:CONSTRUCTOR IMPORTING IM_NAME TYPE  STRING
  7.                                   IM_PLANETYPE TYPE SAPLANE-PLANETYPE
  8.                                   IM_MAXSEATS TYPE  SAPLANE-SEATSMAX.
  9.     METHODS DISPLAY_ATTRIBUTES REDEFINITION.
  10.   PRIVATE SECTION.
  11.     DATA:  MAXSEATS TYPE SAPLANE-SEATSMAX.

  13. ENDCLASS.                    "lcl_passenger_plane DEFINITION
  14. CLASS LCL_PASSENGER_PLANE IMPLEMENTATION.
  15.   METHOD CONSTRUCTOR.
  16.     SUPER->CONSTRUCTOR( IM_NAME = IM_NAME IM_PLANETYPE = IM_PLANETYPE ).
  17.     MAXSEATS = IM_MAXSEATS.
  18.   ENDMETHOD.
  19.   METHOD DISPLAY_ATTRIBUTES.
  20.    SUPER->DISPLAY_ATTRIBUTES( ).
  21.    WRITE: 'MAXSEAT',MAXSEATS.
  22.   ENDMETHOD.
  23. ENDCLASS.
复制代码
INCLUDE ZBC10_EX_C_6.
  1. *&---------------------------------------------------------------------*
  2. *&  Include           ZBC10_EX_C_5
  3. *&---------------------------------------------------------------------*
  4. CLASS LCL_CARGO_PLANE DEFINITION INHERITING FROM LCL_AIRPLANE.
  5.   PUBLIC SECTION.
  6.     METHODS:CONSTRUCTOR IMPORTING IM_NAME TYPE  STRING
  7.                                   IM_PLANETYPE TYPE SAPLANE-PLANETYPE
  8.                                   IM_MAXCARGO TYPE  SAPLANE-CAP_UNIT.
  9.     METHODS DISPLAY_ATTRIBUTES REDEFINITION.
  10.   PRIVATE SECTION.
  11.     DATA:MAX_CARGO TYPE SAPLANE-CAP_UNIT.

  13. ENDCLASS.                    "lcl_cargo_plane DEFINITION
  14. *----------------------------------------------------------------------*
  15. *       CLASS LCL_CARGO_PLANE IMPLEMENTATION
  16. *----------------------------------------------------------------------*
  17. *
  18. *----------------------------------------------------------------------*
  19. CLASS LCL_CARGO_PLANE IMPLEMENTATION.
  20.   METHOD CONSTRUCTOR.
  21.     SUPER->CONSTRUCTOR( IM_NAME = IM_NAME IM_PLANETYPE = IM_PLANETYPE ).
  22.     MAX_CARGO = IM_MAXCARGO.
  23.   ENDMETHOD.                    "CONSTRUCTOR
  24.   METHOD DISPLAY_ATTRIBUTES.
  25.     SUPER->DISPLAY_ATTRIBUTES( ).
  26.     WRITE: 'MAXCARGO',MAX_CARGO.
  27.   ENDMETHOD.                    "DISPLAY_ATTRIBUTES
  28. ENDCLASS.                    "LCL_CARGO_PLANE IMPLEMENTATION
复制代码
INCLUDE ZBC10_EX_D_6.
  1. *&---------------------------------------------------------------------*
  2. *&  Include           ZBC10_EX_D_6
  3. *&---------------------------------------------------------------------*
  4. CLASS LCL_CARRIER DEFINITION.
  5.   PUBLIC SECTION.
  6.     METHODS:CONSTRUCTOR IMPORTING IM_NAME TYPE STRING.
  7.     METHODS:ADD_AIRPLANE IMPORTING IM_AIRPLANE TYPE REF TO LCL_AIRPLANE.
  8.     METHODS:DISPLAY_AIRPLANES.
  9.     METHODS:DISPLAY_ATTRIBUTES.
  10.   PRIVATE SECTION.
  11.    DATA: NAME TYPE STRING,
  12.          AIRPLANE_LIST TYPE TABLE OF REF TO LCL_AIRPLANE.
  13. ENDCLASS.                    "lcl_CARRIER DEFINITION

  15. *----------------------------------------------------------------------*
  16. *       CLASS lcl_CARRIER IMPLEMENTATION
  17. *----------------------------------------------------------------------*
  18. *
  19. *----------------------------------------------------------------------*
  20. CLASS LCL_CARRIER IMPLEMENTATION.
  21.   METHOD CONSTRUCTOR.
  22.     NAME = IM_NAME.
  23.   ENDMETHOD.
  24.   METHOD ADD_AIRPLANE.
  25.     APPEND IM_AIRPLANE TO AIRPLANE_LIST.
  26.   ENDMETHOD.
  27.   METHOD DISPLAY_AIRPLANES.
  28.     DATA: R_AIRPLANE TYPE REF TO LCL_AIRPLANE.
  29.     LOOP AT AIRPLANE_LIST INTO R_AIRPLANE.
  30.        R_AIRPLANE->DISPLAY_ATTRIBUTES( ).
  31.     ENDLOOP.
  32.   ENDMETHOD.
  33.   METHOD DISPLAY_ATTRIBUTES.
  34.     WRITE: / NAME.
  35.     DISPLAY_AIRPLANES( ).
  36.   ENDMETHOD.
  37. ENDCLASS.                    "lcl_CARRIER IMPLEMENTATION
复制代码
面向对象, 对象, 多态

相关帖子
回复

使用道具 举报

Twilight

管理员

+发表新主题
  1. 847 主题
  2. 125 回帖
  3. 11270 积分
发消息

Ta最近发表

快速回帖

本版积分规则
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册有礼

小黑屋|手机版|SAP顾问圈 ( 沪ICP备18020878号 )

GMT+8, 2024-12-23 06:47 , Processed in 0.049219 second(s), 6 queries , Gzip On, Redis On.

© 2014-2017 SAPclubDesign by Twilight.Liu®X3.5

平台客服 1204767879 无客服码

快速回复 返回顶部 返回列表