动态汇总alv与动态tree代码

Sariel采用动态编程完成的余额发生额通用查询报表，代码规范、质量都是可圈可点{:soso_e179:} ，只可惜没有最终运行的截图，下面分享代码共大家学习一下。

************************************************************************
* Report ZZREPORT
************************************************************************
*
* 作者: Sariel
* 完成日期: 2013/03/19
* 描述: 余额发生额通用查询
************************************************************************
* 版本号日期作者修改描述功能更改说明书
************************************************************************
* 1. YYYY/MM/DD author Read dataset from app. Server @001
************************************************************************
REPORT ZZREPORT NO STANDARD PAGE HEADING LINE-SIZE 255.
*&---------------------------------------------------------------------*
*& DEFINE TYPE-POOLS
*&---------------------------------------------------------------------*
TYPE-POOLS: SLIS,ABAP.
*&---------------------------------------------------------------------*
*& DEFINE TABLES
*&---------------------------------------------------------------------*
TABLES: FAGLFLEXA.
CLASS CL_GUI_CFW DEFINITION LOAD.
CLASS LCL_EVENT_RECEIVER DEFINITION DEFERRED.
*----------------------------------------------------------------------*
* CLASS LCL_EVENT_RECEIVER DEFINITION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS LCL_EVENT_RECEIVER DEFINITION.
PUBLIC SECTION.
METHODS:
HANDLE_ITEM_DOUBLE_CLICK
FOR EVENT ITEM_DOUBLE_CLICK OF CL_GUI_ALV_TREE
IMPORTING FIELDNAME
NODE_KEY.
ENDCLASS. "LCL_EVENT_RECEIVER DEFINITION
*----------------------------------------------------------------------*
* CLASS LCL_EVENT_RECEIVER IMPLEMENTATION
*----------------------------------------------------------------------*
CLASS LCL_EVENT_RECEIVER IMPLEMENTATION.
METHOD HANDLE_ITEM_DOUBLE_CLICK.
CHECK FIELDNAME EQ 'BQJES'
OR FIELDNAME EQ 'BQJEH'
OR FIELDNAME EQ 'LJJES'
OR FIELDNAME EQ 'LJJEH'
OR FIELDNAME EQ 'BQSLS'
OR FIELDNAME EQ 'BQSLH'
OR FIELDNAME EQ 'LJSLS'
OR FIELDNAME EQ 'LJSLH'.
PERFORM FRM_GET_ITEMS USING FIELDNAME NODE_KEY.
ENDMETHOD. "HANDLE_ITEM_DOUBLE_CLICK
ENDCLASS. "LCL_EVENT_RECEIVER IMPLEMENTATION
*&---------------------------------------------------------------------*
*& DEFINE TYPES
*&---------------------------------------------------------------------*
TYPES: BEGIN OF TY_FIELD,
SEQ TYPE NUMC2,
DSP TYPE NUMC2, "是否显示
SUM TYPE FLAG, "是否汇总
FLAG TYPE CHAR1, "H:汇总/J:金额/S:数量/T:描述/N:ALV小计字段
NAME TYPE FIELDNAME,
TYPE TYPE FIELD_TYPE,
TEXT TYPE LVC_TXT,
END OF TY_FIELD.
TYPES: BEGIN OF TY_T001,
BUKRS TYPE T001-BUKRS,
BUTXT TYPE T001-BUTXT,
END OF TY_T001.
TYPES: BEGIN OF TY_BNKA,
BUKRS TYPE T012-BUKRS,
HBKID TYPE T012-HBKID,
BANKA TYPE BNKA-BANKA,
END OF TY_BNKA.
TYPES: BEGIN OF TY_BSEG,
GJAHR TYPE BSEG-GJAHR,
BUKRS TYPE BSEG-BUKRS,
BELNR TYPE BSEG-BELNR,
BUZEI TYPE BSEG-BUZEI,
SGTXT TYPE BSEG-SGTXT,
MATNR TYPE BSEG-MATNR,
ANLN1 TYPE BSEG-ANLN1,
ANLN2 TYPE BSEG-ANLN2,
AUFNR TYPE BSEG-AUFNR,
KOSTL TYPE BSEG-KOSTL,
END OF TY_BSEG.
TYPES: BEGIN OF TY_DETA,
RACCT TYPE FAGLFLEXA-RACCT, "总帐帐目
RACCTT TYPE SKAT-TXT20, "科目描述
RBUKRS TYPE FAGLFLEXA-RBUKRS, "公司
BUTXT TYPE T001-BUTXT, "公司名称
RYEAR TYPE FAGLFLEXA-RYEAR, "会计年度
POPER TYPE FAGLFLEXA-POPER, "会计期间
BELNR TYPE FAGLFLEXA-BELNR, "凭证编号
BUZEI TYPE FAGLFLEXA-BUZEI, "行项目
BLART TYPE BKPF-BLART, "凭证日期
BUDAT TYPE FAGLFLEXA-BUDAT, "过账日期
BLDAT TYPE BKPF-BLDAT, "行项目编号
SGTXT TYPE BSEG-SGTXT, "文本
ZZLIFNR TYPE FAGLFLEXA-ZZLIFNR, "供应商
ZZLIFNRT TYPE LFA1-NAME1, "供应商描述
ZZKUNNR TYPE FAGLFLEXA-ZZKUNNR, "客户
ZZKUNNRT TYPE KNA1-NAME1, "客户描述
ZZRSTGR TYPE FAGLFLEXA-ZZRSTGR, "原因代码
ZZRSTGRT TYPE T053S-TXT20, "现金流量文本
ZZAUFNR TYPE FAGLFLEXA-ZZAUFNR, "订单
ZZAUFNRT TYPE AUFK-KTEXT, "订单描述
RCNTR TYPE FAGLFLEXA-RCNTR, "成本中心
RCNTRT TYPE CSKT-KTEXT, "成本中心描述
PRCTR TYPE FAGLFLEXA-PRCTR, "利润中心
PRCTRT TYPE CEPCT-KTEXT, "利润中心描述
ZZHBKID TYPE FAGLFLEXA-ZZHBKID, "银行
ZZHBKIDT TYPE BNKA-BANKA, "银行描述
ZZHKTID TYPE FAGLFLEXA-ZZHKTID, "账户
ZZHKTIDT TYPE T012T-TEXT1, "账户描述
ZZIVTP TYPE FAGLFLEXA-ZZIVTP, "发票类型
ZZIVTPT TYPE ZFIT0013-TXT20, "发票类型描述
ZZCSTP TYPE FAGLFLEXA-ZZCSTP, "费用类型
ZZCSTPT TYPE ZFIT0014-TXT50, "费用类型描述
ZZSTFCH TYPE FAGLFLEXA-ZZSTFCH, "员工性质
ZZSTFCHT TYPE ZFIT0015-TXT20, "员工性质描述
ZZMTRTP TYPE FAGLFLEXA-ZZMTRTP, "物料类型
ZZMTRTPT TYPE ZFIT0016-TXT20, "物料类型描述
ZZPJTP TYPE FAGLFLEXA-ZZPJTP, "统筹项目
ZZPJTPT TYPE ZFIT0017-TXT50, "统筹项目描述
MATNR TYPE BSEG-MATNR, "物料
MAKTX TYPE MAKT-MAKTX, "物料描述
HSL TYPE FAGLFLEXA-HSL, "本位币金额
TSL TYPE FAGLFLEXA-TSL, "交易货币金额
RWCUR TYPE FAGLFLEXA-RWCUR, "货币
MSL TYPE FAGLFLEXA-MSL, "数量
RUNIT TYPE FAGLFLEXA-RUNIT, "数量单位
ANLN1 TYPE BSEG-ANLN1, "资产
ANLN2 TYPE BSEG-ANLN2, "次级
ANLN1T TYPE ANLT-TXT50, "资产描述
END OF TY_DETA.
TYPES: BEGIN OF TY_GRPL.
INCLUDE TYPE LVC_S_GRPL.
TYPES: NKEY TYPE LVC_NKEY.
TYPES: END OF TY_GRPL.
*&---------------------------------------------------------------------*
*& DEFINE DATA
*&---------------------------------------------------------------------*
DATA: GC_EVENT_RECEIVER TYPE REF TO LCL_EVENT_RECEIVER,
GO_ALV_GRID TYPE REF TO CL_GUI_ALV_GRID,
GO_ALV_TREE TYPE REF TO CL_GUI_ALV_TREE,
GT_FCAT_TREE TYPE LVC_T_FCAT,
GS_FCAT_TREE TYPE LVC_S_FCAT,
GV_FCAT_TREE TYPE FLAG,
GT_FCAT TYPE SLIS_T_FIELDCAT_ALV,
GS_FCAT TYPE SLIS_FIELDCAT_ALV,
GT_SORT TYPE SLIS_T_SORTINFO_ALV,
GS_SORT TYPE SLIS_SORTINFO_ALV,
GO_DATA0 TYPE REF TO DATA,
GO_DATA1 TYPE REF TO DATA,
GO_DATA2 TYPE REF TO DATA,
GO_DATA3 TYPE REF TO DATA,
GO_DATA4 TYPE REF TO DATA,
GO_DATA5 TYPE REF TO DATA,
GO_DATA6 TYPE REF TO DATA,
GO_DATA7 TYPE REF TO DATA,
GO_DATA8 TYPE REF TO DATA,
GO_DATA9 TYPE REF TO DATA,
GT_GRPL TYPE LVC_T_GRPL,
GS_GRPL TYPE LVC_S_GRPL.
DATA: RT_RACCT TYPE RANGE OF RACCT,
RS_RACCT LIKE LINE OF RT_RACCT.
DATA: GT_FIELD TYPE STANDARD TABLE OF TY_FIELD,
GS_FIELD TYPE TY_FIELD,
GT_FIELDX TYPE STANDARD TABLE OF TY_FIELD,
GS_FIELDX TYPE TY_FIELD,
GT_FNHSL TYPE STANDARD TABLE OF FIELDNAME,
GS_FNHSL LIKE LINE OF GT_FNHSL,
GT_FNMSL TYPE STANDARD TABLE OF FIELDNAME,
GS_FNMSL LIKE LINE OF GT_FNMSL,
GT_SORTX TYPE ABAP_SORTORDER_TAB,
GS_SORTX TYPE ABAP_SORTORDER,
GT_0010 TYPE STANDARD TABLE OF ZFIT0010,
GS_0010 TYPE ZFIT0010,
GT_BSEG TYPE STANDARD TABLE OF TY_BSEG,
GS_BSEG TYPE TY_BSEG,
GT_T001 TYPE STANDARD TABLE OF TY_T001,
GS_T001 TYPE TY_T001,
GT_SKAT TYPE STANDARD TABLE OF SKAT,
GS_SKAT TYPE SKAT,
GT_LFA1 TYPE STANDARD TABLE OF LFA1,
GS_LFA1 TYPE LFA1,
GT_KNA1 TYPE STANDARD TABLE OF KNA1,
GS_KNA1 TYPE KNA1,
GT_T053S TYPE STANDARD TABLE OF T053S,
GS_T053S TYPE T053S,
GT_CSKT TYPE STANDARD TABLE OF CSKT,
GS_CSKT TYPE CSKT,
GT_AUFK TYPE STANDARD TABLE OF AUFK,
GS_AUFK TYPE AUFK,
GT_0013 TYPE STANDARD TABLE OF ZFIT0013,
GS_0013 TYPE ZFIT0013,
GT_0014 TYPE STANDARD TABLE OF ZFIT0014,
GS_0014 TYPE ZFIT0014,
GT_0015 TYPE STANDARD TABLE OF ZFIT0015,
GS_0015 TYPE ZFIT0015,
GT_0016 TYPE STANDARD TABLE OF ZFIT0016,
GS_0016 TYPE ZFIT0016,
GT_BNKA TYPE STANDARD TABLE OF TY_BNKA,
GS_BNKA TYPE TY_BNKA,
GT_T012T TYPE STANDARD TABLE OF T012T,
GS_T012T TYPE T012T,
GT_0017 TYPE STANDARD TABLE OF ZFIT0017,
GS_0017 TYPE ZFIT0017,
GT_TGSBT TYPE STANDARD TABLE OF TGSBT,
GS_TGSBT TYPE TGSBT,
GT_CEPCT TYPE STANDARD TABLE OF CEPCT,
GS_CEPCT TYPE CEPCT,
GT_T856T TYPE STANDARD TABLE OF T856T,
GS_T856T TYPE T856T,
GT_TFKBT TYPE STANDARD TABLE OF TFKBT,
GS_TFKBT TYPE TFKBT,
GT_TKA01 TYPE STANDARD TABLE OF TKA01,
GS_TKA01 TYPE TKA01,
GT_DETA TYPE STANDARD TABLE OF TY_DETA,
GS_DETA TYPE TY_DETA.
DATA: GV_FIELD TYPE FIELDNAME,
GV_DESC TYPE CHAR100.
*&---------------------------------------------------------------------*
*& DEFINE FIELD-SYMBOLS
*&---------------------------------------------------------------------*
FIELD-SYMBOLS: <FS_TEMPT> TYPE STANDARD TABLE,
<FS_LISTT> TYPE STANDARD TABLE,
<FS_TABLE> TYPE STANDARD TABLE,
<FS_TEMPS> TYPE ANY,
<FS_LISTS> TYPE ANY,
<FS_DATA> TYPE ANY.
*&---------------------------------------------------------------------*
*& DEFINE MACRO
*&---------------------------------------------------------------------*
DEFINE MCR_DEF_SCREEN.
SELECTION-SCREEN BEGIN OF LINE.
PARAMETERS: &1 TYPE NUMC1.
SELECTION-SCREEN POSITION 30.
SELECT-OPTIONS &2 FOR &3.
SELECTION-SCREEN COMMENT 03(15) &4 FOR FIELD &2.
SELECTION-SCREEN END OF LINE.
END-OF-DEFINITION.
*&---------------------------------------------------------------------*
*& DEFINE SCREENS
*&---------------------------------------------------------------------*
SELECT-OPTIONS: S_BUKRS FOR FAGLFLEXA-RBUKRS,
S_RYEAR FOR FAGLFLEXA-GJAHR NO-EXTENSION NO INTERVALS,
S_POPER FOR FAGLFLEXA-POPER NO-EXTENSION,
S_RACCT FOR FAGLFLEXA-RACCT.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 01(08) TEXT-S01.
SELECTION-SCREEN POSITION 35.
* 一级
PARAMETERS R_YJ RADIOBUTTON GROUP RB USER-COMMAND RBK.
SELECTION-SCREEN COMMENT 37(04) TEXT-S02 FOR FIELD R_YJ.
* 二级
PARAMETERS R_EJ RADIOBUTTON GROUP RB.
SELECTION-SCREEN COMMENT 44(04) TEXT-S03 FOR FIELD R_EJ.
* 三级
PARAMETERS R_SJ RADIOBUTTON GROUP RB.
SELECTION-SCREEN COMMENT 51(04) TEXT-S04 FOR FIELD R_SJ.
* 末级
PARAMETERS R_MJ RADIOBUTTON GROUP RB.
SELECTION-SCREEN COMMENT 58(04) TEXT-S05 FOR FIELD R_MJ.
* 不显示科目
PARAMETERS R_BX RADIOBUTTON GROUP RB.
SELECTION-SCREEN COMMENT 66(10) TEXT-S06 FOR FIELD R_BX.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN BEGIN OF BLOCK BL1 WITH FRAME TITLE TEXT-B01.
SELECTION-SCREEN BEGIN OF LINE.
* 显示描述
SELECTION-SCREEN POSITION 1.
PARAMETERS: CK_MS AS CHECKBOX.
SELECTION-SCREEN COMMENT 2(08) TEXT-S08 FOR FIELD CK_MS.
* 显示数量
SELECTION-SCREEN POSITION 33.
PARAMETERS: CK_SL AS CHECKBOX.
SELECTION-SCREEN COMMENT 35(08) TEXT-S07 FOR FIELD CK_SL.
* 显示零值
SELECTION-SCREEN POSITION 65.
PARAMETERS: CK_LZ AS CHECKBOX.
SELECTION-SCREEN COMMENT 68(08) TEXT-S27 FOR FIELD CK_LZ.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN END OF BLOCK BL1.
SELECTION-SCREEN BEGIN OF BLOCK BL2 WITH FRAME TITLE TEXT-B02.
MCR_DEF_SCREEN: P_A S_LIFNR FAGLFLEXA-ZZLIFNR TEXT-S09, "供应商
P_B S_KUNNR FAGLFLEXA-ZZKUNNR TEXT-S10. "客户
SELECTION-SCREEN BEGIN OF LINE.
PARAMETERS: P_C TYPE NUMC1.
SELECTION-SCREEN POSITION 30.
SELECT-OPTIONS S_RSTGR FOR FAGLFLEXA-ZZRSTGR MATCHCODE OBJECT FOAP_CDITEM_T053R.
SELECTION-SCREEN COMMENT 03(15) TEXT-S11 FOR FIELD S_RSTGR.
SELECTION-SCREEN END OF LINE. "付款原因代码
MCR_DEF_SCREEN: P_D S_RCNTR FAGLFLEXA-RCNTR TEXT-S12. "成本中心
SELECTION-SCREEN BEGIN OF LINE.
PARAMETERS: P_E TYPE NUMC1.
SELECTION-SCREEN POSITION 30.
SELECT-OPTIONS S_AUFNR FOR FAGLFLEXA-ZZAUFNR MATCHCODE OBJECT ORDE.
SELECTION-SCREEN COMMENT 03(15) TEXT-S13 FOR FIELD S_AUFNR.
SELECTION-SCREEN END OF LINE. "订单
MCR_DEF_SCREEN: P_F S_ZCSTP FAGLFLEXA-ZZCSTP TEXT-S14, "费用类型
P_G S_MTRTP FAGLFLEXA-ZZMTRTP TEXT-S15, "物料类型
P_H S_ZIVTP FAGLFLEXA-ZZIVTP TEXT-S16, "发票类型
P_I S_STFCH FAGLFLEXA-ZZSTFCH TEXT-S17, "员工性质
P_J S_HBKID FAGLFLEXA-ZZHBKID1 TEXT-S18, "银行
P_K S_HKTID FAGLFLEXA-ZZHKTID1 TEXT-S19, "账户
P_L S_ZPJTP FAGLFLEXA-ZZPJTP TEXT-S20, "统筹项目
P_M S_RBUSA FAGLFLEXA-RBUSA TEXT-S21, "业务范围
P_N S_PRCTR FAGLFLEXA-PRCTR TEXT-S22, "利润中心
P_O S_RMVCT FAGLFLEXA-RMVCT TEXT-S23, "事务类型
P_P S_FAREA FAGLFLEXA-RFAREA TEXT-S24, "功能范围
P_Q S_KOKRS FAGLFLEXA-KOKRS TEXT-S25. "控制范围
SELECTION-SCREEN BEGIN OF LINE.
PARAMETERS: P_X TYPE NUMC1 MODIF ID ACC.
SELECTION-SCREEN POSITION 30.
SELECTION-SCREEN COMMENT 03(08) TEXT-S26 FOR FIELD P_X MODIF ID ACC.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN END OF BLOCK BL2.
*----------------------------------------------------------------------*
* INITIALIZATION
*----------------------------------------------------------------------*
INITIALIZATION.
PERFORM FRM_INIT_PROG.
*----------------------------------------------------------------------*
* AT SELECTION-SCREEN OUTPUT
*----------------------------------------------------------------------*
AT SELECTION-SCREEN OUTPUT.
PERFORM FRM_SET_SCREEN.
*----------------------------------------------------------------------*
* AT SELECTION-SCREEN
*----------------------------------------------------------------------*
AT SELECTION-SCREEN.
PERFORM FRM_CHECK_SCREEN.
*&---------------------------------------------------------------------*
* START-OF-SELECTION
*&---------------------------------------------------------------------*
START-OF-SELECTION.
PERFORM FRM_GET_RACCT.
PERFORM FRM_GET_FIELD.
PERFORM FRM_GET_DESC.
PERFORM FRM_GET_TABLE.
PERFORM FRM_EDT_DATA.
PERFORM FRM_DSP_LIST.
*&---------------------------------------------------------------------*
*& Form FRM_INIT_PROG
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
FORM FRM_INIT_PROG .
DATA: LS_RESTRICT TYPE SSCR_RESTRICT,
LS_OPTLIST TYPE SSCR_OPT_LIST,
LS_ASS TYPE SSCR_ASS.
S_RYEAR-SIGN = 'I'.
S_RYEAR-OPTION = 'EQ'.
S_RYEAR-LOW = SY-DATUM.
APPEND S_RYEAR.
LS_OPTLIST-NAME = 'RACCT'.
LS_OPTLIST-OPTIONS-CP = ABAP_TRUE.
LS_OPTLIST-OPTIONS-EQ = ABAP_TRUE.
LS_OPTLIST-OPTIONS-BT = ABAP_TRUE.
APPEND LS_OPTLIST TO LS_RESTRICT-OPT_LIST_TAB.
LS_ASS-KIND = 'S'.
LS_ASS-NAME = 'S_RACCT'.
LS_ASS-SG_MAIN = 'I'.
LS_ASS-SG_ADDY = SPACE.
LS_ASS-OP_MAIN = 'RACCT'.
APPEND LS_ASS TO LS_RESTRICT-ASS_TAB.
CALL FUNCTION 'SELECT_OPTIONS_RESTRICT'
EXPORTING
RESTRICTION = LS_RESTRICT
EXCEPTIONS
TOO_LATE = 1St
REPEATED = 2
SELOPT_WITHOUT_OPTIONS = 3
SELOPT_WITHOUT_SIGNS = 4
INVALID_SIGN = 5
EMPTY_OPTION_LIST = 6
INVALID_KIND = 7
REPEATED_KIND_A = 8
OTHERS = 9.
IF SY-SUBRC <> 0.
MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
ENDFORM. " FRM_INIT_PROG
*&---------------------------------------------------------------------*
*& Form FRM_SET_SCREEN
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
FORM FRM_SET_SCREEN .
LOOP AT SCREEN.
IF SCREEN-GROUP1 EQ 'ACC'.
IF R_BX IS NOT INITIAL.
SCREEN-INPUT = '1'.
ELSE.
SCREEN-INPUT = '0'.
CLEAR P_X.
ENDIF.
ENDIF.
IF SCREEN-NAME EQ 'S_BURKS-LOW'
OR SCREEN-NAME EQ 'S_RYEAR-LOW'
OR SCREEN-NAME EQ 'S_POPER-LOW'
OR SCREEN-NAME EQ 'S_RACCT-LOW'.
SCREEN-REQUIRED = '2'.
ENDIF.
MODIFY SCREEN.
ENDLOOP.
ENDFORM. " FRM_SET_SCREEN
*&---------------------------------------------------------------------*
*& Form FRM_CHECK_SCREEN
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
FORM FRM_CHECK_SCREEN .
DATA: LV_SEQ TYPE I,
LV_FIELD TYPE FIELDNAME,
LT_SEQ TYPE STANDARD TABLE OF NUMC1,
LS_SEQ LIKE LINE OF LT_SEQ.
FIELD-SYMBOLS: <LF_FIELD> TYPE ANY.
CHECK SY-UCOMM NE 'RBK'
AND SY-UCOMM NE SPACE.
IF S_BUKRS[] IS INITIAL.
SET CURSOR FIELD 'S_BURKS-LOW'.
MESSAGE E055(00).
* 填入所有必需的条目字段
ENDIF.
IF S_RYEAR[] IS INITIAL.
SET CURSOR FIELD 'S_RYEAR-LOW'.
MESSAGE E055(00).
* 填入所有必需的条目字段
ENDIF.
IF S_POPER[] IS INITIAL.
SET CURSOR FIELD 'S_POPER-LOW'.
MESSAGE E055(00).
* 填入所有必需的条目字段
ENDIF.
IF S_RACCT-LOW IS INITIAL.
SET CURSOR FIELD 'S_RACCT-LOW'.
MESSAGE E055(00).
* 填入所有必需的条目字段
ENDIF.
SELECT COUNT(*)
FROM ZFIT0010
WHERE HKONT IN S_RACCT.
IF SY-SUBRC NE 0.
MESSAGE '输入科目在科目层级表中未维护' TYPE 'E'.
ENDIF.
* 判断科目级次是否大于输入的科目级次
IF R_BX IS INITIAL.
LOOP AT S_RACCT.
IF S_RACCT-LOW NA '*'
AND S_RACCT-HIGH NA '*'.
CASE ABAP_TRUE.
WHEN R_YJ.
LV_SEQ = 1.
WHEN R_EJ.
LV_SEQ = 2.
WHEN R_SJ.
LV_SEQ = 3.
WHEN R_MJ.
LV_SEQ = 4.
WHEN OTHERS.
ENDCASE.
SELECT COUNT(*)
FROM ZFIT0010
WHERE HKONT IN S_RACCT
AND KMJC GT LV_SEQ.
IF SY-SUBRC EQ 0.
MESSAGE '输入科目含有低于选择级次的科目' TYPE 'E'.
LEAVE LIST-PROCESSING.
ENDIF.
ENDIF.
ENDLOOP.
ENDIF.
* 检查重复输入
DO.
LV_SEQ = SY-INDEX - 1.
IF LV_SEQ GE STRLEN( SY-ABCDE ).
EXIT.
ENDIF.
LV_FIELD = 'P_' && SY-ABCDE+LV_SEQ(1).
ASSIGN (LV_FIELD) TO <LF_FIELD>.
IF SY-SUBRC NE 0.
EXIT.
ELSE.
IF <LF_FIELD> NE '0'.
LS_SEQ = <LF_FIELD>.
APPEND LS_SEQ TO LT_SEQ.
CLEAR LS_SEQ.
ENDIF.
ENDIF.
ENDDO.
CLEAR LV_SEQ.
DESCRIBE TABLE LT_SEQ LINES LV_SEQ.
DELETE ADJACENT DUPLICATES FROM LT_SEQ COMPARING ALL FIELDS.
IF LV_SEQ NE LINES( LT_SEQ ).
MESSAGE '输入的汇总层次存在重复！请重新输入' TYPE 'E'.
ENDIF.
ENDFORM. " FRM_CHECK_SCREEN
*&---------------------------------------------------------------------*
*& Form FRM_GET_RACCT
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
FORM FRM_GET_RACCT .
DATA: RT_KMJC TYPE RANGE OF ZKMJC,
RS_KMJC LIKE LINE OF RT_KMJC,
RT_MJBZ TYPE RANGE OF ZMJBZ,
RS_MJBZ LIKE LINE OF RT_MJBZ,
RT_HKONT TYPE RANGE OF HKONT,
RS_HKONT LIKE LINE OF RT_HKONT.
DATA: LV_LOW TYPE HKONT,
LV_HIGH TYPE HKONT.
DEFINE MCR_SET_RANGE.
&1-SIGN = 'I'.
&1-OPTION = &3.
&1-LOW = &4.
&1-HIGH = &5.
APPEND &1 TO &2.
CLEAR &1.
END-OF-DEFINITION.
* 期间检查
IF S_POPER-HIGH IS INITIAL.
S_POPER-HIGH = S_POPER-LOW.
ENDIF.
IF R_BX IS NOT INITIAL.
RT_RACCT = S_RACCT[].
ELSE.
LOOP AT S_RACCT.
* 输入的科目含有“*”的情况
IF S_RACCT-LOW CA '*'
OR S_RACCT-HIGH CA '*'.
RT_HKONT = S_RACCT[].
CASE ABAP_TRUE.
WHEN R_YJ.
MCR_SET_RANGE RS_KMJC RT_KMJC 'GE' '1' ' '.
WHEN R_EJ.
MCR_SET_RANGE RS_KMJC RT_KMJC 'GE' '2' ' '.
WHEN R_SJ.
MCR_SET_RANGE RS_KMJC RT_KMJC 'GE' '3' ' '.
WHEN R_MJ.
MCR_SET_RANGE RS_MJBZ RT_MJBZ 'EQ' 'Y' ' '.
WHEN OTHERS.
ENDCASE.
* 不含“*”的情况
ELSE.
* 输入科目上限的情况，添加上限范围
IF S_RACCT-HIGH IS NOT INITIAL.
CASE ABAP_TRUE.
WHEN R_YJ.
LV_LOW = S_RACCT-LOW+0(4) && '*'.
LV_HIGH = S_RACCT-HIGH+0(4) && '*'.
MCR_SET_RANGE RS_HKONT RT_HKONT 'BT' LV_LOW LV_HIGH.
WHEN R_EJ.
LV_LOW = S_RACCT-LOW+0(6) && '*'.
LV_HIGH = S_RACCT-HIGH+0(6) && '*'.
MCR_SET_RANGE RS_HKONT RT_HKONT 'BT' LV_LOW LV_HIGH.
WHEN R_SJ.
LV_LOW = S_RACCT-LOW+0(8) && '*'.
LV_HIGH = S_RACCT-HIGH+0(8) && '*'.
MCR_SET_RANGE RS_HKONT RT_HKONT 'BT' LV_LOW LV_HIGH.
WHEN R_MJ.
RT_HKONT = S_RACCT[].
MCR_SET_RANGE RS_MJBZ RT_MJBZ 'EQ' 'Y' ' '.
WHEN OTHERS.
ENDCASE.
ELSE.
CASE ABAP_TRUE.
WHEN R_YJ.
LV_LOW = S_RACCT-LOW+0(4) && '*'.
MCR_SET_RANGE RS_HKONT RT_HKONT 'CP' LV_LOW ' '.
WHEN R_EJ.
LV_LOW = S_RACCT-LOW+0(6) && '*'.
MCR_SET_RANGE RS_HKONT RT_HKONT 'CP' LV_LOW ' '.
WHEN R_SJ.
LV_LOW = S_RACCT-LOW+0(8) && '*'.
MCR_SET_RANGE RS_HKONT RT_HKONT 'CP' LV_LOW ' '.
WHEN R_MJ.
RT_HKONT = S_RACCT[].
MCR_SET_RANGE RS_MJBZ RT_MJBZ 'EQ' 'Y' ' '.
WHEN OTHERS.
ENDCASE.
ENDIF.
ENDIF.
ENDLOOP.
* 取得科目范围
SELECT *
INTO TABLE GT_0010
FROM ZFIT0010
WHERE KTOPL EQ 'SNJT'.
IF SY-SUBRC EQ 0.
LOOP AT GT_0010 INTO GS_0010
WHERE HKONT IN RT_HKONT
AND KMJC IN RT_KMJC
AND MJBZ IN RT_MJBZ.
MCR_SET_RANGE RS_RACCT RT_RACCT 'EQ' GS_0010-HKONT ' '.
ENDLOOP.
IF SY-SUBRC NE 0.
MESSAGE '输入的科目范围为空' TYPE 'S' DISPLAY LIKE 'E'.
LEAVE LIST-PROCESSING.
ENDIF.
ENDIF.
ENDIF.
ENDFORM. " FRM_GET_RACCT
*&---------------------------------------------------------------------*
*& Form FRM_GET_FIELD
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
FORM FRM_GET_FIELD .
DATA: LT_COMPONENT TYPE CL_ABAP_STRUCTDESCR=>COMPONENT_TABLE,
LS_COMPONENT TYPE CL_ABAP_STRUCTDESCR=>COMPONENT,
LR_TYPEDESCR TYPE REF TO CL_ABAP_TYPEDESCR,
LR_STRDESCR TYPE REF TO CL_ABAP_STRUCTDESCR,
LR_TABDESCR TYPE REF TO CL_ABAP_TABLEDESCR,
LR_DATA TYPE REF TO DATA,
LV_NAME TYPE FIELDNAME,
LS_FIELD TYPE TY_FIELD,
LV_FIELD TYPE FIELDNAME,
LV_SPOS TYPE I.
DEFINE MCR_SET_FIELD.
GS_FIELD-DSP = &2.
GS_FIELD-SUM = &3.
GS_FIELD-FLAG = &4.
GS_FIELD-NAME = &5.
GS_FIELD-TYPE = &6.
GS_FIELD-TEXT = &7.
CASE GS_FIELD-FLAG.
* 在值字段名后插入描述字段名
WHEN 'T'.
LV_NAME = GS_FIELD-NAME.
SHIFT LV_NAME RIGHT DELETING TRAILING SPACE.
SHIFT LV_NAME BY 1 PLACES RIGHT.
CONDENSE LV_NAME.
CLEAR LS_FIELD.
READ TABLE GT_FIELD INTO LS_FIELD
WITH KEY NAME = LV_NAME.
IF SY-SUBRC EQ 0.
GS_FIELD-SEQ = LS_FIELD-SEQ+0(1) && 1.
INSERT GS_FIELD INTO GT_FIELD INDEX SY-TABIX.
ENDIF.
WHEN 'H'.
GS_FIELD-SEQ = &1 && 0.
APPEND GS_FIELD TO GT_FIELD.
IF GS_FIELD-DSP IS NOT INITIAL.
GS_FIELD-NAME = GS_FIELD-NAME && 'X'.
GS_FIELD-FLAG = 'N'.
APPEND GS_FIELD TO GT_FIELD.
ENDIF.
WHEN OTHERS.
GS_FIELD-SEQ = &1 && 0.
APPEND GS_FIELD TO GT_FIELD.
ENDCASE.
* 统计计算字段名
IF GS_FIELD-TEXT IS INITIAL.
CASE GS_FIELD-NAME+0(3).
WHEN 'HSL'.
GS_FNHSL = GS_FIELD-NAME.
APPEND GS_FNHSL TO GT_FNHSL.
CLEAR GS_FNHSL.
WHEN 'MSL'.
GS_FNMSL = GS_FIELD-NAME.
APPEND GS_FNMSL TO GT_FNMSL.
CLEAR GS_FNMSL.
WHEN OTHERS.
ENDCASE.
ENDIF.
CLEAR: GS_FIELD, LV_NAME.
END-OF-DEFINITION.
* 只有选择不显示科目才能选择科目做汇总依据
* MCR_SET_FIELD: ' ' '01' ' ' 'H' 'RBUKRS' 'BUKRS' '公司代码'.
IF R_BX IS NOT INITIAL.
MCR_SET_FIELD: P_X P_X ' ' 'H' 'RACCT' 'RACCT' '科目号码'.
ELSE.
MCR_SET_FIELD: ' ' '02' ' ' 'H' 'RACCT' 'RACCT' '科目号码'.
ENDIF.
MCR_SET_FIELD: P_A P_A ' ' 'H' 'ZZLIFNR' 'LIFNR' '供应商',
P_B P_B ' ' 'H' 'ZZKUNNR' 'KUNNR' '客户',
P_C P_C ' ' 'H' 'ZZRSTGR' 'RSTGR' '付款原因代码',
P_D P_D ' ' 'H' 'RCNTR' 'KOSTL' '成本中心',
P_E P_E ' ' 'H' 'ZZAUFNR' 'AUFNR' '订单',
P_F P_F ' ' 'H' 'ZZCSTP' 'ZZCSTP' '费用类型',
P_G P_G ' ' 'H' 'ZZMTRTP' 'ZZMTRTP' '物料类型',
P_H P_H ' ' 'H' 'ZZIVTP' 'ZZIVTP' '发票类型',
P_I P_I ' ' 'H' 'ZZSTFCH' 'ZZSTFCH' '员工性质',
P_J P_J ' ' 'H' 'ZZHBKID' 'HBKID' '银行',
P_K P_K ' ' 'H' 'ZZHKTID' 'HKTID' '账户',
P_L P_L ' ' 'H' 'ZZPJTP' 'ZZPJTP' '统筹项目',
P_M P_M ' ' 'H' 'RBUSA' 'GSBER' '业务范围',
P_N P_N ' ' 'H' 'PRCTR' 'LTEXT' '利润中心',
P_O P_O ' ' 'H' 'RMVCT' 'RMVCT' '事务类型',
P_P P_P ' ' 'H' 'RFAREA' 'FKBER' '功能范围',
P_Q P_Q ' ' 'H' 'KOKRS' 'KOKRS' '控制范围'.
* 如果点选不显示科目检查必输汇总依据
IF R_BX IS NOT INITIAL.
LOOP AT GT_FIELD TRANSPORTING NO FIELDS
WHERE SEQ IS NOT INITIAL.
EXIT.
ENDLOOP.
IF SY-SUBRC NE 0.
MESSAGE '请选择汇总依据字段' TYPE 'S' DISPLAY LIKE 'E'.
LEAVE LIST-PROCESSING.
ENDIF.
ENDIF.
IF CK_MS IS NOT INITIAL.
* 只有选择不显示科目才能选择科目做汇总依据
IF R_BX IS NOT INITIAL.
MCR_SET_FIELD: P_X P_X ' ' 'T' 'RACCTT' 'TXT50_SKAT' '科目号码描述'. "SKAT
ELSE.
MCR_SET_FIELD: ' ' '03' ' ' 'T' 'RACCTT' 'TXT50_SKAT' '科目号码描述'. "SKAT
ENDIF.
MCR_SET_FIELD: ' ' P_A ' ' 'T' 'ZZLIFNRT' 'NAME1_GP' '供应商描述', "LFA1
' ' P_B ' ' 'T' 'ZZKUNNRT' 'NAME1_GP' '客户描述', "KNA1
' ' P_C ' ' 'T' 'ZZRSTGRT' 'TXT20_053' '原因代码描述', "T053S
' ' P_D ' ' 'T' 'RCNTRT' 'KTEXT' '成本中心描述', "CSKT
' ' P_E ' ' 'T' 'ZZAUFNRT' 'AUFTEXT' '订单描述', "AUFK
' ' P_F ' ' 'T' 'ZZCSTPT' 'ZFIE0004' '费用类型描述', "ZFIT0014
' ' P_G ' ' 'T' 'ZZMTRTPT' 'ZFIE0006' '物料类型描述', "ZFIT0016
' ' P_H ' ' 'T' 'ZZIVTPT' 'ZFIE0003' '发票类型描述', "ZFIT0013
' ' P_I ' ' 'T' 'ZZSTFCHT' 'ZFIE0005' '员工性质描述', "ZFIT0015
' ' P_J ' ' 'T' 'ZZHBKIDT' 'BANKA' '银行描述', "BNKA
' ' P_K ' ' 'T' 'ZZHKTIDT' 'FIBL_TXT50' '账户描述', "T012T
' ' P_L ' ' 'T' 'ZZPJTPT' 'ZFIE0007' '统筹项目描述', "ZFIT0017
' ' P_M ' ' 'T' 'RBUSAT' 'GTEXT' '业务范围描述', "TGSBT
' ' P_N ' ' 'T' 'PRCTRT' 'LTEXT' '利润中心描述', "CEPCT
' ' P_O ' ' 'T' 'RMVCTT' 'RMVCT_TXT' '事务类型描述', "T856T
' ' P_P ' ' 'T' 'RFAREAT' 'FKBTX' '功能范围描述', "TFKBT
' ' P_Q ' ' 'T' 'KOKRST' 'BEZEI' '控制范围描述'. "TKA01
ENDIF.
MCR_SET_FIELD: '9' '01' 'X' 'J' 'QCJE' 'HSLXX12' '期初余额',
'9' '02' 'X' 'J' 'BQJES' 'HSLXX12' '本期借方发生额',
'9' '03' 'X' 'J' 'BQJEH' 'HSLXX12' '本期贷方发生额',
'9' '04' 'X' 'J' 'LJJES' 'HSLXX12' '累计借方发生额',
'9' '05' 'X' 'J' 'LJJEH' 'HSLXX12' '累计贷方发生额',
'9' '06' 'X' 'J' 'QMJE' 'HSLXX12' '期末余额',
'9' '07' 'X' 'S' 'QCSL' 'MSLXX12' '期初数量',
'9' '08' 'X' 'S' 'BQSLS' 'MSLXX12' '本期借方数量',
'9' '09' 'X' 'S' 'BQSLH' 'MSLXX12' '本期贷方数量',
'9' '10' 'X' 'S' 'LJSLS' 'MSLXX12' '累计借方数量',
'9' '11' 'X' 'S' 'LJSLH' 'MSLXX12' '累计贷方数量',
'9' '12' 'X' 'S' 'QMSL' 'MSLXX12' '期末数量',
'9' '99' ' ' ' ' 'DRCRK' 'SHKZG' 'X',
'9' '99' ' ' ' ' 'HSLVT' 'HSLXX12' '',
'9' '99' ' ' ' ' 'HSL01' 'HSLXX12' '',
'9' '99' ' ' ' ' 'HSL02' 'HSLXX12' '',
'9' '99' ' ' ' ' 'HSL03' 'HSLXX12' '',
'9' '99' ' ' ' ' 'HSL04' 'HSLXX12' '',
'9' '99' ' ' ' ' 'HSL05' 'HSLXX12' '',
'9' '99' ' ' ' ' 'HSL06' 'HSLXX12' '',
'9' '99' ' ' ' ' 'HSL07' 'HSLXX12' '',
'9' '99' ' ' ' ' 'HSL08' 'HSLXX12' '',
'9' '99' ' ' ' ' 'HSL09' 'HSLXX12' '',
'9' '99' ' ' ' ' 'HSL10' 'HSLXX12' '',
'9' '99' ' ' ' ' 'HSL11' 'HSLXX12' '',
'9' '99' ' ' ' ' 'HSL12' 'HSLXX12' '',
'9' '99' ' ' ' ' 'HSL13' 'HSLXX12' '',
'9' '99' ' ' ' ' 'HSL14' 'HSLXX12' '',
'9' '99' ' ' ' ' 'HSL15' 'HSLXX12' '',
'9' '99' ' ' ' ' 'HSL16' 'HSLXX12' ''.
IF CK_SL IS NOT INITIAL.
MCR_SET_FIELD: '9' '99' ' ' ' ' 'MSLVT' 'MSLXX12' '',
'9' '99' ' ' ' ' 'MSL01' 'MSLXX12' '',
'9' '99' ' ' ' ' 'MSL02' 'MSLXX12' '',
'9' '99' ' ' ' ' 'MSL03' 'MSLXX12' '',
'9' '99' ' ' ' ' 'MSL04' 'MSLXX12' '',
'9' '99' ' ' ' ' 'MSL05' 'MSLXX12' '',
'9' '99' ' ' ' ' 'MSL06' 'MSLXX12' '',
'9' '99' ' ' ' ' 'MSL07' 'MSLXX12' '',
'9' '99' ' ' ' ' 'MSL08' 'MSLXX12' '',
'9' '99' ' ' ' ' 'MSL09' 'MSLXX12' '',
'9' '99' ' ' ' ' 'MSL10' 'MSLXX12' '',
'9' '99' ' ' ' ' 'MSL11' 'MSLXX12' '',
'9' '99' ' ' ' ' 'MSL12' 'MSLXX12' '',
'9' '99' ' ' ' ' 'MSL13' 'MSLXX12' '',
'9' '99' ' ' ' ' 'MSL14' 'MSLXX12' '',
'9' '99' ' ' ' ' 'MSL15' 'MSLXX12' '',
'9' '99' ' ' ' ' 'MSL16' 'MSLXX12' ''.
ENDIF.
SORT GT_FIELD BY SEQ ASCENDING DSP ASCENDING.
GT_FIELDX = GT_FIELD.
DELETE GT_FIELDX WHERE FLAG NE 'N'.
* 设置动态内表
LOOP AT GT_FIELD INTO GS_FIELD.
* 汇总依据字段排序设置
CASE GS_FIELD-FLAG.
WHEN 'H'.
IF GS_FIELD-DSP IS NOT INITIAL.
GS_SORTX-NAME = GS_FIELD-NAME.
APPEND GS_SORTX TO GT_SORTX.
CLEAR GS_SORTX.
ENDIF.
GV_FIELD = GS_FIELD-NAME.
WHEN 'N'.
LV_SPOS = LV_SPOS + 1.
GS_SORT-SPOS = LV_SPOS.
GS_SORT-FIELDNAME = GS_FIELD-NAME.
GS_SORT-SUBTOT = ABAP_TRUE.
GS_SORT-UP = ABAP_TRUE.
APPEND GS_SORT TO GT_SORT.
CLEAR GS_SORT.
WHEN OTHERS.
ENDCASE.
* 显示的字段生成动态内表
IF GS_FIELD-DSP IS NOT INITIAL.
LR_TYPEDESCR = CL_ABAP_ELEMDESCR=>DESCRIBE_BY_NAME( GS_FIELD-TYPE ).
LS_COMPONENT-NAME = GS_FIELD-NAME.
LS_COMPONENT-TYPE ?= LR_TYPEDESCR.
APPEND LS_COMPONENT TO LT_COMPONENT.
CLEAR LS_COMPONENT.
* 数量是否显示
CASE GS_FIELD-FLAG.
WHEN SPACE.
CLEAR GS_FIELD.
CONTINUE.
WHEN 'S'.
IF CK_SL IS NOT INITIAL.
PERFORM FRM_GET_FCAT.
ENDIF.
WHEN OTHERS.
PERFORM FRM_GET_FCAT.
ENDCASE.
ENDIF.
CLEAR GS_FIELD.
ENDLOOP.
LV_FIELD = GV_FIELD && 'X'.
GS_SORT-EXPA = ABAP_TRUE.
MODIFY GT_SORT FROM GS_SORT TRANSPORTING EXPA WHERE FIELDNAME EQ LV_FIELD.
LR_STRDESCR = CL_ABAP_STRUCTDESCR=>CREATE( P_COMPONENTS = LT_COMPONENT ).
CREATE DATA LR_DATA TYPE HANDLE LR_STRDESCR.
ASSIGN LR_DATA->* TO <FS_TEMPS>.
CREATE DATA LR_DATA TYPE HANDLE LR_STRDESCR.
ASSIGN LR_DATA->* TO <FS_LISTS>.
LR_TABDESCR = CL_ABAP_TABLEDESCR=>CREATE( LR_STRDESCR ).
CREATE DATA LR_DATA TYPE HANDLE LR_TABDESCR.
ASSIGN LR_DATA->* TO <FS_TEMPT>.
CREATE DATA LR_DATA TYPE HANDLE LR_TABDESCR.
ASSIGN LR_DATA->* TO <FS_LISTT>.
ENDFORM. " FRM_GET_FIELD
*&---------------------------------------------------------------------*
*& Form FRM_GET_DESC
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
FORM FRM_GET_DESC .
SELECT SAKNR
TXT20
INTO CORRESPONDING FIELDS OF TABLE GT_SKAT
FROM SKAT
WHERE KTOPL EQ 'SNJT'
AND SPRAS EQ SY-LANGU.
IF P_A IS NOT INITIAL.
SELECT LIFNR
NAME1
INTO CORRESPONDING FIELDS OF TABLE GT_LFA1
FROM LFA1.
ENDIF.
IF P_B IS NOT INITIAL.
SELECT KUNNR
NAME1
INTO CORRESPONDING FIELDS OF TABLE GT_KNA1
FROM KNA1.
ENDIF.
IF P_C IS NOT INITIAL.
SELECT BUKRS
RSTGR
TXT20
INTO CORRESPONDING FIELDS OF TABLE GT_T053S
FROM T053S
WHERE SPRAS EQ SY-LANGU
AND BUKRS IN S_BUKRS.
ENDIF.
IF P_D IS NOT INITIAL.
SELECT KOSTL
KTEXT
INTO CORRESPONDING FIELDS OF TABLE GT_CSKT
FROM CSKT
WHERE SPRAS EQ SY-LANGU
AND KOKRS EQ 'SNJT'.
ENDIF.
IF P_E IS NOT INITIAL.
SELECT AUFNR
KTEXT
INTO CORRESPONDING FIELDS OF TABLE GT_AUFK
FROM AUFK.
ENDIF.
IF P_F IS NOT INITIAL.
SELECT ZZCSTP
TXT50
INTO CORRESPONDING FIELDS OF TABLE GT_0014
FROM ZFIT0014.
ENDIF.
IF P_G IS NOT INITIAL.
SELECT ZZMTRTP
TXT20
INTO CORRESPONDING FIELDS OF TABLE GT_0016
FROM ZFIT0016.
ENDIF.
IF P_H IS NOT INITIAL.
SELECT ZZIVTP
TXT20
INTO CORRESPONDING FIELDS OF TABLE GT_0013
FROM ZFIT0013.
ENDIF.
IF P_I IS NOT INITIAL.
SELECT ZZSTFCH
TXT20
INTO CORRESPONDING FIELDS OF TABLE GT_0015
FROM ZFIT0015.
ENDIF.
IF P_J IS NOT INITIAL.
SELECT T012~BUKRS
T012~HBKID
BNKA~BANKA
INTO CORRESPONDING FIELDS OF TABLE GT_BNKA
FROM BNKA
JOIN T012 ON BNKA~BANKS EQ T012~BANKS
AND BNKA~BANKL EQ T012~BANKL
WHERE T012~BUKRS IN S_BUKRS.
ENDIF.
IF P_K IS NOT INITIAL.
SELECT BUKRS
HBKID
HKTID
TEXT1
INTO CORRESPONDING FIELDS OF TABLE GT_T012T
FROM T012T
WHERE BUKRS IN S_BUKRS
AND SPRAS EQ SY-LANGU.
ENDIF.
IF P_L IS NOT INITIAL.
SELECT ZZPJTP
TXT50
INTO CORRESPONDING FIELDS OF TABLE GT_0017
FROM ZFIT0017.
ENDIF.
IF P_M IS NOT INITIAL.
SELECT GSBER
GTEXT
INTO CORRESPONDING FIELDS OF TABLE GT_TGSBT
FROM TGSBT
WHERE SPRAS EQ SY-LANGU.
ENDIF.
IF P_N IS NOT INITIAL.
SELECT PRCTR
KTEXT
INTO CORRESPONDING FIELDS OF TABLE GT_CEPCT
FROM CEPCT
WHERE SPRAS EQ SY-LANGU
AND KOKRS EQ 'SNJT'.
ENDIF.
IF P_O IS NOT INITIAL.
SELECT TRTYP
TXT
INTO CORRESPONDING FIELDS OF TABLE GT_T856T
FROM T856T
WHERE LANGU EQ SY-LANGU.
ENDIF.
IF P_P IS NOT INITIAL.
SELECT FKBER
FKBTX
INTO CORRESPONDING FIELDS OF TABLE GT_TFKBT
FROM TFKBT
WHERE SPRAS EQ SY-LANGU.
ENDIF.
IF P_Q IS NOT INITIAL.
SELECT KOKRS
BEZEI
INTO CORRESPONDING FIELDS OF TABLE GT_TKA01
FROM TKA01.
ENDIF.
ENDFORM. " FRM_GET_DESC

复制代码

动态汇总alv与动态tree代码

相关帖子

Ta最近发表

快速回帖