设为首页收藏本站站点任务
请登陆 注册有礼
二维码
网站快捷导航

[ooalv] 可手工拖拽alv行记录的实例

Twilight发表于 2014-08-18 20:16Twilight 最后回复于 2015-04-23 11:00 [复制链接] 6897 2

程序代码：
  1. *Structure declaration for T016T
  2. TYPES : BEGIN OF ty_t016t,
  3.          brsch TYPE brsch,
  4.          brtxt TYPE text1_016t,
  5.          spras TYPE spras,
  6.          END OF ty_t016t.
  7. *Work area and internal table for  T016T
  8. DATA : it_t016t TYPE STANDARD TABLE OF ty_t016t,
  9.        wa_t016t TYPE ty_t016t.
  10. *class declaration
  11. CLASS lcl_objdragdropapp DEFINITION DEFERRED.
  12. *data declarations for ALV
  13. DATA:   c_dragdropapp TYPE REF TO lcl_objdragdropapp,
  14.         c_dockingcont TYPE REF TO cl_gui_docking_container,
  15.         c_alv TYPE REF TO cl_gui_alv_grid,
  16. * reference variable to CL_DRAGDROP:
  17.         c_dragdropalv TYPE REF TO cl_dragdrop,
  18.         it_layout TYPE lvc_s_layo,
  19.         it_fcat  TYPE lvc_t_fcat.            "Field catalogue
  20. *declarations for handle event
  21. DATA:   effect TYPE i,
  22.         handle_alv TYPE i.
  23. *initialization event
  24. INITIALIZATION.
  25. *start of selection event
  26. START-OF-SELECTION.
  27. *select data
  28.   PERFORM fetch_data.
  29. *ALV output
  30.   PERFORM alv_output.
  31. * Class definitions and method implementation for drag and drop
  32. CLASS lcl_dragdrop DEFINITION.
  33.   PUBLIC SECTION.
  34.     DATA: wa TYPE ty_t016t,
  35.           index TYPE i.   "Index of Line to be moved
  36. ENDCLASS.                    "LCL_DRAGDROP DEFINITION
  37. *Application class definition
  38. CLASS lcl_objdragdropapp DEFINITION.
  39.   PUBLIC SECTION.
  40.     METHODS:
  41. *Handling Event Drag
  42.       handle_alv_drag
  43.         FOR EVENT ondrag
  44.         OF cl_gui_alv_grid
  45.         IMPORTING e_row e_column e_dragdropobj,
  46. *Handling event DROP
  47.       handle_alv_drop
  48.         FOR EVENT ondrop
  49.         OF cl_gui_alv_grid
  50.         IMPORTING e_row e_column e_dragdropobj.
  51. ENDCLASS.                    "LCL_objdragdropapp DEFINITION
  52. *Application class implementation
  53. CLASS lcl_objdragdropapp IMPLEMENTATION.
  54. *  OnDrag event is used to 'fetch' information from the drag source.
  55.   METHOD handle_alv_drag.
  56.     DATA: dataobj TYPE REF TO lcl_dragdrop,
  57.           line TYPE ty_t016t.
  58. * Read dragged row
  59.     READ TABLE it_t016t INDEX e_row-index INTO line.
  60. * create and fill dataobject for events ONDROP
  61.     CREATE OBJECT dataobj.
  62. * Remembering row index to move a line
  63.     MOVE e_row-index TO dataobj->index.
  64. * store the dragged line.
  65.     READ TABLE it_t016t INTO dataobj->wa INDEX e_row-index.
  66. * Assigning data object to the refering event parameter
  67.     e_dragdropobj->object = dataobj.
  68.   ENDMETHOD.                    "HANDLE_ALV_DRAG
  69. *Event handler for event 'OnDrop'. This event is used
  70. *to use your dragged information in combination with your drop source.
  71.   METHOD handle_alv_drop.
  72.     DATA: dataobj TYPE REF TO lcl_dragdrop,
  73.           drop_index TYPE i,
  74.           stable TYPE lvc_s_stbl.
  75. * Refresh Alv Grid Control without scrolling
  76.     stable-row = 'X'.
  77.     stable-col = 'X'.

  79. * Catch-Statement to ensure the drag&drop-Operation is aborted properly.
  80.     CATCH SYSTEM-EXCEPTIONS move_cast_error = 1.
  81.       dataobj ?= e_dragdropobj->object.
  82.       DELETE it_t016t INDEX dataobj->index.
  83.       INSERT dataobj->wa INTO it_t016t INDEX e_row-index.
  84. *Refreshing the ALV
  85.       CALL METHOD c_alv->refresh_table_display
  86.         EXPORTING
  87.           i_soft_refresh = 'X'
  88.           is_stable      = stable.
  89.     ENDCATCH.
  90.     IF sy-subrc <> 0.
  91. * If anything went wrong aborting the drag and drop operation:
  92.       CALL METHOD e_dragdropobj->abort.
  93.     ENDIF.
  94.   ENDMETHOD.                    "HANDLE_ALV_DROP
  95. ENDCLASS.                    "LCL_objdragdropapp IMPLEMENTATION
  96. *&---------------------------------------------------------------------*
  97. *&      Form  alv_output
  98. *&---------------------------------------------------------------------*
  99. *       text
  100. *----------------------------------------------------------------------*
  101. *  -->  p1        text
  102. *  <--  p2        text
  103. *----------------------------------------------------------------------*
  104. FORM alv_output .
  105.   CALL SCREEN 600.

  107. ENDFORM.                    " alv_output
  108. ** Calling the ALV screen with custom container
  109. *On this statement double click  it takes you to the screen painter SE51.
  110. *Enter the attributes
  111. *Create a Custom container and name it CC_CONT and OK code as OK_CODE.
  112. *Save check and Activate the screen painter.
  113. *Now a normal screen with number 600 is created which holds the ALV grid.
  114. * PBO of the actual screen ,Here we can give a title and customized menus
  115. *&---------------------------------------------------------------------*
  116. *&      Module  STATUS_0600  OUTPUT
  117. *&---------------------------------------------------------------------*
  118. *       text
  119. *----------------------------------------------------------------------*
  120. MODULE status_0600 OUTPUT.
  121. *  SET PF-STATUS 'xxxxxxxx'.
  122. *  SET TITLEBAR 'xxx'.
  123.   IF c_alv IS INITIAL.
  124.     PERFORM alv_controls.
  125.   ENDIF.
  126. ENDMODULE.                 " STATUS_0600  OUTPUT
  127. *&---------------------------------------------------------------------*
  128. *&      Form  alv_CONTROLS
  129. *&---------------------------------------------------------------------*
  130. *       text
  131. *----------------------------------------------------------------------*
  132. *  -->  p1        text
  133. *  <--  p2        text
  134. *----------------------------------------------------------------------*
  135. FORM alv_controls.
  136. * create docking container for alv control
  137.   CREATE OBJECT c_dockingcont
  138.     EXPORTING
  139.         dynnr = '600'
  140.         extension = 300
  141.         side = cl_gui_docking_container=>dock_at_top.

  143. * create alv control
  144.   CREATE OBJECT c_alv
  145.      EXPORTING i_parent = c_dockingcont.
  146. * create the application object to handle the ABAP Objects Events
  147.   CREATE OBJECT c_dragdropapp.
  148. * Events alv control
  149. *For Dragging
  150.   SET HANDLER c_dragdropapp->handle_alv_drag FOR c_alv.
  151. *For Dropping
  152.   SET HANDLER c_dragdropapp->handle_alv_drop FOR c_alv.
  153. * build tree nodes for drag&drop
  154.   PERFORM build_handle.
  155. * Fieldcatalogue for ALV
  156.   PERFORM alv_build_fieldcat.
  157. * ALV attributes FOR LAYOUT
  158.   PERFORM alv_report_layout.
  159. * Call ALV GRID
  160.   CALL METHOD c_alv->set_table_for_first_display
  161.     EXPORTING
  162.       is_layout                     = it_layout
  163.     CHANGING
  164.       it_outtab                     = it_t016t
  165.       it_fieldcatalog               = it_fcat
  166.     EXCEPTIONS
  167.       invalid_parameter_combination = 1
  168.       program_error                 = 2
  169.       too_many_lines                = 3
  170.       OTHERS                        = 4.
  171.   IF sy-subrc <> 0.
  172.     MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
  173.                WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  174.   ENDIF.
  175. ENDFORM.                               "ALV_CONTROLS
  176. *&---------------------------------------------------------------------*
  177. *&      Form  build_handle
  178. *&---------------------------------------------------------------------*
  179. *       text
  180. *----------------------------------------------------------------------*
  181. *  -->  p1        text
  182. *  <--  p2        text
  183. *----------------------------------------------------------------------*
  184. FORM build_handle.

  186. * define a drag & Drop behaviour for the whole grid
  187.   CREATE OBJECT c_dragdropalv.
  188.   effect = cl_dragdrop=>move + cl_dragdrop=>copy.
  189.   CALL METHOD c_dragdropalv->add
  190.     EXPORTING
  191.       flavor     = 'Line'
  192.       dragsrc    = 'X'
  193.       droptarget = 'X'
  194.       effect     = effect.
  195. *getting the handle for drag and drop
  196.   CALL METHOD c_dragdropalv->get_handle
  197.     IMPORTING
  198.       handle = handle_alv.

  200. ENDFORM.                               " build_handle
  201. *&---------------------------------------------------------------------*
  202. *&      Form  fetch_data
  203. *&---------------------------------------------------------------------*
  204. *       text
  205. *----------------------------------------------------------------------*
  206. *  -->  p1        text
  207. *  <--  p2        text
  208. *----------------------------------------------------------------------*
  209. FORM fetch_data .
  210. * select and display data from t016
  211.   SELECT brtxt brsch spras FROM t016t INTO CORRESPONDING FIELDS OF TABLE it_t016t
  212.   WHERE spras = 'EN'.

  214. ENDFORM.                    " fetch_data
  215. *&---------------------------------------------------------------------*
  216. *&      Form  alv_report_layout
  217. *&---------------------------------------------------------------------*
  218. *       text
  219. *----------------------------------------------------------------------*
  220. *  -->  p1        text
  221. *  <--  p2        text
  222. *----------------------------------------------------------------------*
  223. FORM alv_report_layout .
  224.   it_layout-grid_title = 'ALV Drag Drop'.
  225. * provide handle to alv control to all rows for same drag & drop behaviour
  226.   it_layout-s_dragdrop-row_ddid = handle_alv.

  228. ENDFORM.                    " alv_report_layout
  229. *&---------------------------------------------------------------------*
  230. *&      Form  alv_build_fieldcat
  231. *&---------------------------------------------------------------------*
  232. *       text
  233. *----------------------------------------------------------------------*
  234. *  -->  p1        text
  235. *  <--  p2        text
  236. *----------------------------------------------------------------------*
  237. FORM alv_build_fieldcat .
  238.   DATA lv_fldcat TYPE lvc_s_fcat.
  239.   CLEAR lv_fldcat.
  240.   lv_fldcat-row_pos   = '1'.
  241.   lv_fldcat-col_pos   = '1'.
  242.   lv_fldcat-fieldname = 'BRSCH'.
  243.   lv_fldcat-tabname   = 'IT_T016T'.
  244.   lv_fldcat-outputlen = 8.
  245.   lv_fldcat-scrtext_m = 'Industry'.
  246.   APPEND lv_fldcat TO it_fcat.
  247.   CLEAR lv_fldcat.
  248.   lv_fldcat-row_pos   = '1'.
  249.   lv_fldcat-col_pos   = '2'.
  250.   lv_fldcat-fieldname = 'BRTXT'.
  251.   lv_fldcat-tabname   = 'IT_T016T'.
  252.   lv_fldcat-outputlen = 15.
  253.   lv_fldcat-scrtext_m = 'Description'.
  254.   APPEND lv_fldcat TO it_fcat.
  255.   CLEAR lv_fldcat.

  257. ENDFORM.                    " alv_build_fieldcat
  258. * PAI module of the screen created. In case we use an interactive ALV or
  259. *for additional functionalities we can create OK codes
  260. *and based on the user command we can do the coding.
  261. *&---------------------------------------------------------------------*
  262. *&      Module  USER_COMMAND_0600  INPUT
  263. *&---------------------------------------------------------------------*
  264. *       text
  265. *----------------------------------------------------------------------*
  266. MODULE user_command_0600 INPUT.
  267. ENDMODULE.                 " USER_COMMAND_0600  INPUT
复制代码

程序执行效果：
Output before drag and drop.png
alv行记录被拖拽之后的效果
Output after drag and drop.png
alv, 拖拽, 行记录

相关帖子
回复

使用道具 举报

小懒
www.sapabap.cn是什么？
回复 支持 反对

使用道具 举报

Twilight
小懒 发表于 2015-4-23 10:26
www.sapabap.cn是什么？


刚开始用的域名，备案没通过，废弃了
回复 支持 反对

使用道具 举报

Twilight

管理员

+发表新主题
  1. 846 主题
  2. 125 回帖
  3. 11239 积分
发消息

Ta最近发表

快速回帖

本版积分规则
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册有礼

小黑屋|手机版|SAP顾问圈 ( 沪ICP备18020878号 )

GMT+8, 2024-11-21 18:48 , Processed in 0.156139 second(s), 8 queries , Gzip On, Redis On.

© 2014-2017 SAPclubDesign by Twilight.Liu®X3.5

平台客服 1204767879 无客服码

快速回复 返回顶部 返回列表