alv list 实现alv多表头或自定义表头（一）

ALV具有强大的数据显示功能，不过其表头形式较为单一，难以适合于一些要求较复杂的报表需求，本例将介绍如何实现ALV表头的自定义格式。

ALV表头的修改首先需要定义表头所需要的具体字段数，然后修改各字段属性，包括名称，横竖线的绘制等。需要注意的是，实现该功能要求ALV必须设置为LIST显示模式，且所生成的报表不适用于排序或Layout的修改；为了使ALV表格与自定义表头对齐，一般建议在设置Fieldcat时指定各字段宽度。

本节主要介绍在一些特别需求中自定义ALV表头的方法，对一些商务应用中的正式报表建议还是采用ScriptForm或SmartForm方式。

程序中所需使用函数及ABAP Report处理事件如下：

REUSE_ALV_LIST_DISPLAY：显示List格式ALV，该例需要设置其IT_EVENTS属性；

REUSE_ALV_EVENTS_GET：获取ALV执行事件，在表头中增加指定行数数据需要调用其"TOP_OF_PAGE"事件。

TYPE-POOLS: SLIS.
TABLES: SPFLI.
DATA: FIELDCAT TYPE SLIS_T_FIELDCAT_ALV WITH HEADER LINE,
LAYOUT TYPE SLIS_LAYOUT_ALV,
W_REPID LIKE SY-REPID,
L_EVENTS TYPE SLIS_T_EVENT, "定义ALV事件类型
EVENTCAT TYPE SLIS_T_EVENT WITH HEADER LINE. "定义事件数据保存内表
DATA: LS_SPFLI TYPE SPFLI. "定义查询数据相关内表
DATA: LSPFLI LIKE STANDARD TABLE OF LS_SPFLI WITH HEADER LINE.
START-OF-SELECTION.
PERFORM EVENTTAB_BUILD CHANGING L_EVENTS.
PERFORM GETDATA.
PERFORM CATALOG.
PERFORM ALVSHOW.
*---------------------------------------------------------------------*
* FORM GetData From DataBase
*---------------------------------------------------------------------*
FORM GETDATA. "抓取十条数据作为参考例子
SELECT * FROM SPFLI UP TO 10 ROWS
INTO CORRESPONDING FIELDS OF TABLE LSPFLI.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form CATALOG
*&---------------------------------------------------------------------*
FORM CATALOG.
W_REPID = SY-REPID.
CLEAR FIELDCAT.
* 通过宏来设置ALV Fieldcat属性，包括字段名、长度、对齐方式等
DEFINE FIELDCATSET.
FIELDCAT-REF_TABNAME = 'LSPFLI'.
FIELDCAT-FIELDNAME = &1.
FIELDCAT-SELTEXT_L = &1.
FIELDCAT-COL_POS = &2.
FIELDCAT-JUST = 'C'.
FIELDCAT-OUTPUTLEN = &3.
APPEND FIELDCAT.
END-OF-DEFINITION.
* 调用宏设置Fieldcat
CLEAR SY-TABIX.
FIELDCATSET 'CARRID' SY-TABIX 6.
FIELDCATSET 'COUNTRYFR' SY-TABIX 9.
FIELDCATSET 'CITYFROM' SY-TABIX 8.
FIELDCATSET 'COUNTRYTO' SY-TABIX 10.
FIELDCATSET 'AIRPFROM' SY-TABIX 8.
FIELDCATSET 'AIRPTO' SY-TABIX 7.
FIELDCATSET 'DEPTIME' SY-TABIX 10.
FIELDCATSET 'DISTANCE' SY-TABIX 10.
FIELDCATSET 'DISTID' SY-TABIX 6.
FIELDCATSET 'FLTYPE' SY-TABIX 6.
FIELDCATSET 'PERIOD' SY-TABIX 6.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form ALVSHOW
*&---------------------------------------------------------------------*
FORM ALVSHOW.
LAYOUT-ZEBRA = 'X' . "加上间隔条纹美化ALV显示
CALL FUNCTION 'REUSE_ALV_LIST_DISPLAY'
EXPORTING
I_CALLBACK_PROGRAM = W_REPID
IS_LAYOUT = LAYOUT
IT_FIELDCAT = FIELDCAT[]
IT_EVENTS = EVENTCAT[] "加入处理事件
TABLES
T_OUTTAB = LSPFLI
EXCEPTIONS
PROGRAM_ERROR = 1
OTHERS = 2.
IF SY-SUBRC <> 0.
MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
ENDFORM.
*&--------------------------------------------------------------------------------*
*& Form EVENTTAB_BUILD 获取ALV执行事件
*&--------------------------------------------------------------------------------*
FORM EVENTTAB_BUILD CHANGING P_EVENTS TYPE SLIS_T_EVENT.
DATA L_EVENT TYPE LINE OF SLIS_T_EVENT.
CALL FUNCTION 'REUSE_ALV_EVENTS_GET'
EXPORTING
I_LIST_TYPE = 0
IMPORTING
ET_EVENTS = P_EVENTS
EXCEPTIONS
LIST_TYPE_WRONG = 1
OTHERS = 2.
* 定义页面首行输出事件
READ TABLE P_EVENTS INTO L_EVENT WITH KEY NAME = 'TOP_OF_PAGE'.
EVENTCAT-NAME = L_EVENT-NAME.
EVENTCAT-FORM = 'F_TOP_OF_PAGE'.
APPEND EVENTCAT.
* 定义List输出后事件
READ TABLE P_EVENTS INTO L_EVENT WITH KEY NAME = 'END_OF_LIST'.
EVENTCAT-NAME = L_EVENT-NAME.
EVENTCAT-FORM = 'F_END_OF_PAGE'.
APPEND EVENTCAT.
ENDFORM. " EVENTTAB_BUILD
*&--------------------------------------------------------------------*
*& Form F_TOP_OF_PAGE 绘制ALV表头
*&--------------------------------------------------------------------*
FORM F_TOP_OF_PAGE.
DATA: L_LINE(398) TYPE C.
WRITE: / SY-ULINE.
WRITE SY-VLINE TO L_LINE+0.
WRITE 'Flight Information Report' TO L_LINE+33 .
WRITE SY-VLINE TO L_LINE+97.
WRITE: / L_LINE.
WRITE: / SY-ULINE+7.
CLEAR L_LINE.
WRITE SY-VLINE TO L_LINE+0.
WRITE SY-VLINE TO L_LINE+7.
WRITE 'Country Information' TO L_LINE+12.
WRITE SY-VLINE TO L_LINE+37.
WRITE 'Flight detail' TO L_LINE+50.
WRITE SY-VLINE TO L_LINE+97.
WRITE: / L_LINE.
ENDFORM. "F_TOP_OF_PAGE
*&--------------------------------------------------------------------*
*& Form F_TOP_OF_PAGE 在ALV表最后加入描述
*&--------------------------------------------------------------------*
FORM F_END_OF_PAGE.
DATA: L_LINE(398) TYPE C.
* 重新绘制表头自定义表格和ALV List衔接部分
WRITE: / SY-ULINE.
WRITE SY-VLINE TO L_LINE+0.
WRITE 'Flight Information Report' TO L_LINE+33 .
WRITE SY-VLINE TO L_LINE+97.
WRITE: / L_LINE.
WRITE: / SY-ULINE+7.
WRITE SY-VLINE TO L_LINE+0.
WRITE 'Total QTY:10' TO L_LINE+40.
WRITE SY-VLINE TO L_LINE+97.
WRITE L_LINE.
WRITE : / SY-ULINE.
ENDFORM. "F_END_OF_PAGE

复制代码

执行效果：

[fmalv] alv list 实现alv多表头或自定义表头（一）

相关帖子

Ta最近发表

快速回帖