设为首页收藏本站站点任务
请登陆 注册有礼
二维码
网站快捷导航

[fmalv] 在alv grid中使用subtotal小计数据

Twilight发表于 2014-08-13 10:28Twilight 最后回复于 2014-08-13 10:28 [复制链接] 4908 0

小计需要配置的地方：
1、fieldcate中指定需要do_sum合计的字段
2、sort中指定合计依据的需排序字段
3、event事件回调subtotal_text子过程，显示文本

程序代码：
  1. *&---------------------------------------------------------------------*
  2. *& Table declaration
  3. *&---------------------------------------------------------------------*
  4. TABLES: ekko.
  5. *&---------------------------------------------------------------------*
  6. *& Type pool declaration
  7. *&---------------------------------------------------------------------*
  8. TYPE-POOLS: slis. " Type pool for ALV
  9. *&---------------------------------------------------------------------*
  10. *& Selection screen
  11. *&---------------------------------------------------------------------*
  12. SELECT-OPTIONS: s_ebeln FOR ekko-ebeln.
  13. *&---------------------------------------------------------------------*
  14. *& Type declaration
  15. *&---------------------------------------------------------------------*
  16. * Type declaration for internal table to store EKPO data
  17. TYPES: BEGIN OF x_data,
  18.        ebeln  TYPE char30,  " Document no.
  19.        ebelp  TYPE ebelp,   " Item no
  20.        matnr  TYPE matnr,   " Material no
  21.        matnr1 TYPE matnr,   " Material no
  22.        werks  TYPE werks_d, " Plant
  23.        werks1 TYPE werks_d, " Plant
  24.        ntgew  TYPE entge,   " Net weight
  25.        gewe   TYPE egewe,   " Unit of weight                            
  26.        END OF x_data.
  27. *&---------------------------------------------------------------------*
  28. *& Internal table declaration
  29. *&---------------------------------------------------------------------*
  30. DATA:
  31. * Internal table to store EKPO data
  32.   i_ekpo TYPE STANDARD TABLE OF x_data INITIAL SIZE 0,
  33. * Internal table for storing field catalog information
  34.   i_fieldcat TYPE slis_t_fieldcat_alv,
  35. * Internal table for Top of Page info. in ALV Display
  36.   i_alv_top_of_page TYPE slis_t_listheader,
  37. * Internal table for ALV Display events
  38.   i_events TYPE slis_t_event,
  39. * Internal table for storing ALV sort information
  40.   i_sort TYPE  slis_t_sortinfo_alv,
  41.   i_event TYPE slis_t_event.
  42. *&---------------------------------------------------------------------*
  43. *& Work area declaration
  44. *&---------------------------------------------------------------------*
  45. DATA:
  46.   wa_ekko TYPE x_data,
  47.   wa_layout     TYPE slis_layout_alv,
  48.   wa_events         TYPE slis_alv_event,
  49.   wa_sort TYPE slis_sortinfo_alv.
  50. *&---------------------------------------------------------------------*
  51. *& Constant declaration
  52. *&---------------------------------------------------------------------*
  53. CONSTANTS:
  54.    c_header   TYPE char1
  55.               VALUE 'H',                    "Header in ALV
  56.    c_item     TYPE char1
  57.               VALUE 'S'.
  58. *&---------------------------------------------------------------------*
  59. *& Start-of-selection event
  60. *&---------------------------------------------------------------------*
  61. START-OF-SELECTION.
  62. * Select data from ekpo
  63.   SELECT ebeln " Doc no
  64.          ebelp " Item
  65.          matnr " Material
  66.          matnr " Material
  67.          werks " Plant
  68.          werks " Plant
  69.          ntgew " Quantity
  70.          gewei " Unit
  71.          FROM ekpo
  72.          INTO TABLE i_ekpo
  73.          WHERE ebeln IN s_ebeln
  74.          AND ntgew NE '0.00'.
  75.   IF sy-subrc = 0.
  76.     SORT i_ekpo BY ebeln ebelp matnr .
  77.   ENDIF.
  78. * To build the Page header
  79.   PERFORM sub_build_header.
  80. * To prepare field catalog
  81.   PERFORM sub_field_catalog.
  82. * Perform to populate the layout structure
  83.   PERFORM sub_populate_layout.
  84. * Perform to populate the sort table.
  85.   PERFORM sub_populate_sort.
  86. * Perform to populate ALV event
  87.   PERFORM sub_get_event.
  88. END-OF-SELECTION.
  89. * Perform to display ALV report
  90.   PERFORM sub_alv_report_display.

  92. *&---------------------------------------------------------------------*
  93. *&      Form  sub_build_header
  94. *&---------------------------------------------------------------------*
  95. *       To build the header
  96. *----------------------------------------------------------------------*
  97. *       No Parameter
  98. *----------------------------------------------------------------------*
  99. FORM sub_build_header .
  100. * Local data declaration
  101.   DATA: l_system     TYPE char10 ,          "System id
  102.         l_r_line     TYPE slis_listheader,  "Hold list header
  103.         l_date       TYPE char10,           "Date
  104.         l_time       TYPE char10,           "Time
  105.         l_success_records TYPE i,           "No of success records
  106.         l_title(300) TYPE c.                " Title

  108. * Title  Display
  109.   l_r_line-typ = c_header.               " header
  110.   l_title = 'Test report'(001).
  111.   l_r_line-info = l_title.
  112.   APPEND l_r_line TO i_alv_top_of_page.
  113.   CLEAR l_r_line.
  114. * Run date Display
  115.   CLEAR l_date.
  116.   l_r_line-typ  = c_item.                " Item
  117.   WRITE: sy-datum  TO l_date MM/DD/YYYY.
  118.   l_r_line-key = 'Run Date :'(002).
  119.   l_r_line-info = l_date.
  120.   APPEND l_r_line TO i_alv_top_of_page.
  121.   CLEAR: l_r_line,
  122.          l_date.
  123. ENDFORM.                    " sub_build_header

  125. *&---------------------------------------------------------------------*
  126. *&      Form  sub_field_catalog
  127. *&---------------------------------------------------------------------*
  128. *       Build Field Catalog
  129. *----------------------------------------------------------------------*
  130. *       No Parameter
  131. *----------------------------------------------------------------------*
  132. FORM sub_field_catalog .
  133. *  Build Field Catalog
  134.   PERFORM sub_fill_alv_field_catalog USING:
  135.      '01' '01' 'EBELN' 'I_EKPO' 'L'
  136.      'Doc No'(003) ' ' ' ' ' ' ' ',
  137.      '01' '02' 'EBELP' 'I_EKPO' 'L'
  138.      'Item No'(004) 'X' 'X' ' ' ' ',
  139.      '01' '03' 'MATNR' 'I_EKPO' 'L'
  140.      'Material No'(005) 'X' 'X' ' ' ' ',
  141.      '01' '03' 'MATNR1' 'I_EKPO' 'L'
  142.      'Material No'(005) ' ' ' ' ' ' ' ',

  144.      '01' '04' 'WERKS' 'I_EKPO' 'L'
  145.      'Plant'(006) 'X' 'X' ' ' ' ',
  146.      '01' '04' 'WERKS1' 'I_EKPO' 'L'
  147.      'Plant'(006) ' ' ' ' ' ' ' ',
  148.      '01' '05' 'NTGEW' 'I_EKPO' 'R'
  149.      'Net Weight'(007) ' ' ' ' 'GEWE' 'I_EKPO'.
  150. ENDFORM.                    " sub_field_catalog
  151. *&---------------------------------------------------------------------*
  152. *&     Form  sub_fill_alv_field_catalog
  153. *&---------------------------------------------------------------------*
  154. *&     For building Field Catalog
  155. *&---------------------------------------------------------------------*
  156. *&     p_rowpos   Row position
  157. *&     p_colpos   Col position
  158. *&     p_fldnam   Fldname
  159. *&     p_tabnam   Tabname
  160. *&     p_justif   Justification
  161. *&     p_seltext  Seltext
  162. *&     p_out      no out
  163. *&     p_tech     Technical field
  164. *&     p_qfield   Quantity field
  165. *&     p_qtab     Quantity table
  166. *&---------------------------------------------------------------------*
  167. FORM sub_fill_alv_field_catalog  USING  p_rowpos    TYPE sycurow
  168.                                         p_colpos    TYPE sycucol
  169.                                         p_fldnam    TYPE fieldname
  170.                                         p_tabnam    TYPE tabname
  171.                                         p_justif    TYPE char1
  172.                                         p_seltext   TYPE dd03p-scrtext_l
  173.                                         p_out       TYPE char1
  174.                                         p_tech      TYPE char1
  175.                                         p_qfield    TYPE slis_fieldname
  176.                                         p_qtab      TYPE slis_tabname.
  177. * Local declaration for field catalog
  178.   DATA: wa_lfl_fcat    TYPE  slis_fieldcat_alv.
  179.   wa_lfl_fcat-row_pos        =  p_rowpos.     "Row
  180.   wa_lfl_fcat-col_pos        =  p_colpos.     "Column
  181.   wa_lfl_fcat-fieldname      =  p_fldnam.     "Field Name
  182.   wa_lfl_fcat-tabname        =  p_tabnam.     "Internal Table Name
  183.   wa_lfl_fcat-just           =  p_justif.     "Screen Justified
  184.   wa_lfl_fcat-seltext_l      =  p_seltext.    "Field Text
  185.   wa_lfl_fcat-no_out         =  p_out.        "No output
  186.   wa_lfl_fcat-tech           =  p_tech.       "Technical field
  187.   wa_lfl_fcat-qfieldname     =  p_qfield.     "Quantity unit
  188.   wa_lfl_fcat-qtabname       =  p_qtab .      "Quantity table
  189.   IF p_fldnam = 'NTGEW'.
  190.     wa_lfl_fcat-do_sum  = 'X'.
  191.   ENDIF.
  192.   APPEND wa_lfl_fcat TO i_fieldcat.
  193.   CLEAR wa_lfl_fcat.
  194. ENDFORM.                    " sub_fill_alv_field_catalog
  195. *&---------------------------------------------------------------------*
  196. *&      Form  sub_populate_layout
  197. *&---------------------------------------------------------------------*
  198. *       Populate ALV layout
  199. *----------------------------------------------------------------------*
  200. *       No Parameter
  201. *----------------------------------------------------------------------*
  202. FORM sub_populate_layout .
  203.   CLEAR wa_layout.
  204.   wa_layout-colwidth_optimize = 'X'." Optimization of Col width
  205. ENDFORM.                    " sub_populate_layout
  206. *&---------------------------------------------------------------------*
  207. *&      Form  sub_populate_sort
  208. *&---------------------------------------------------------------------*
  209. *       Populate ALV sort table
  210. *----------------------------------------------------------------------*
  211. *       No Parameter
  212. *----------------------------------------------------------------------*
  213. FORM sub_populate_sort .
  214. * Sort on material
  215.   wa_sort-spos = '01' .
  216.   wa_sort-fieldname = 'MATNR'.
  217.   wa_sort-tabname = 'I_EKPO'.
  218.   wa_sort-up = 'X'.
  219.   wa_sort-subtot = 'X'.
  220.   APPEND wa_sort TO i_sort .
  221.   CLEAR wa_sort.
  222. * Sort on plant
  223.   wa_sort-spos = '02'.
  224.   wa_sort-fieldname = 'WERKS'.
  225.   wa_sort-tabname = 'I_EKPO'.
  226.   wa_sort-up = 'X'.
  227.   wa_sort-subtot = 'X'.
  228.   APPEND wa_sort TO i_sort .
  229.   CLEAR wa_sort.

  231. ENDFORM.                    " sub_populate_sort
  232. *&---------------------------------------------------------------------*
  233. *&      Form  sub_get_event
  234. *&---------------------------------------------------------------------*
  235. *       Get ALV grid event and pass the form name to subtotal_text
  236. *       event
  237. *----------------------------------------------------------------------*
  238. *       No Parameter
  239. *----------------------------------------------------------------------*
  240. FORM sub_get_event .
  241.   CONSTANTS : c_formname_subtotal_text TYPE slis_formname VALUE
  242. 'SUBTOTAL_TEXT'.
  243.   DATA: l_s_event TYPE slis_alv_event.

  245.   CALL FUNCTION 'REUSE_ALV_EVENTS_GET'
  246.     EXPORTING
  247.       i_list_type     = 4
  248.     IMPORTING
  249.       et_events       = i_event
  250.     EXCEPTIONS
  251.       list_type_wrong = 0
  252.       OTHERS          = 0.
  253. * Subtotal
  254.   READ TABLE i_event  INTO l_s_event
  255.                     WITH KEY name = slis_ev_subtotal_text."在类型池中默认的值为SUBTOTAL_TEXT
  256.   IF sy-subrc = 0.
  257.     MOVE c_formname_subtotal_text TO l_s_event-form.
  258.     MODIFY i_event FROM l_s_event INDEX sy-tabix.
  259.   ENDIF.
  260. ENDFORM.                    " sub_get_event
  261. *&---------------------------------------------------------------------*
  262. *&      Form  sub_alv_report_display
  263. *&---------------------------------------------------------------------*
  264. *       For ALV Report Display
  265. *----------------------------------------------------------------------*
  266. *       No Parameter
  267. *----------------------------------------------------------------------*
  268. FORM sub_alv_report_display .
  269.   DATA: l_repid TYPE syrepid .
  270.   l_repid = sy-repid .
  271. * This function module for displaying the ALV report
  272.   CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
  273.     EXPORTING
  274.       i_callback_program       = l_repid
  275.       i_callback_top_of_page   = 'SUB_ALV_TOP_OF_PAGE'
  276.       is_layout                = wa_layout
  277.       it_fieldcat              = i_fieldcat
  278.       it_sort = i_sort
  279.       it_events                = i_event
  280.       i_default                = 'X'
  281.       i_save                   = 'A'
  282.     TABLES
  283.       t_outtab                 = i_ekpo
  284.     EXCEPTIONS
  285.       program_error            = 1
  286.       OTHERS                   = 2.
  287.   IF sy-subrc <> 0.
  288. *    MESSAGE i000 WITH 'Error in ALV report display'(055).
  289.   ENDIF.
  290. ENDFORM.                    " sub_alv_report_display
  291. *&---------------------------------------------------------------------*
  292. *       FORM sub_alv_top_of_page
  293. *---------------------------------------------------------------------*
  294. *       Call ALV top of page
  295. *---------------------------------------------------------------------*
  296. *       No parameter
  297. *---------------------------------------------------------------------*
  298. FORM sub_alv_top_of_page.                                   "#EC CALLED
  299. * To write header for the ALV
  300.   CALL FUNCTION 'REUSE_ALV_COMMENTARY_WRITE'
  301.     EXPORTING
  302.       it_list_commentary = i_alv_top_of_page.

  304. ENDFORM.                    "alv_top_of_page
  305. *&---------------------------------------------------------------------*
  306. *&      Form  subtotal_text
  307. *&---------------------------------------------------------------------*
  308. *       Build subtotal text
  309. *----------------------------------------------------------------------*
  310. *       P_total  Total
  311. *       p_subtot_text Subtotal text info
  312. *----------------------------------------------------------------------*
  313. FORM subtotal_text CHANGING
  314.                p_total TYPE any
  315.                p_subtot_text TYPE slis_subtot_text.

  317. * Material level sub total
  318.   IF p_subtot_text-criteria = 'MATNR'.
  319.     p_subtot_text-display_text_for_subtotal
  320.     = 'Material level total'(009).
  321.   ENDIF.
  322. * Plant level sub total
  323.   IF p_subtot_text-criteria = 'WERKS'.
  324.     p_subtot_text-display_text_for_subtotal = 'Plant level total'(010).
  325.   ENDIF.

  327. ENDFORM.                    "subtotal_text
复制代码


输出效果：
subtotal.png
subtotal, 小计, alv

相关帖子
回复

使用道具 举报

Twilight

管理员

+发表新主题
  1. 846 主题
  2. 125 回帖
  3. 11241 积分
发消息

Ta最近发表

快速回帖

本版积分规则
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册有礼

小黑屋|手机版|SAP顾问圈 ( 沪ICP备18020878号 )

GMT+8, 2024-11-23 16:06 , Processed in 0.050144 second(s), 6 queries , Gzip On, Redis On.

© 2014-2017 SAPclubDesign by Twilight.Liu®X3.5

平台客服 1204767879 无客服码

快速回复 返回顶部 返回列表